#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------
package RPS::Import::Universal::v20;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

sub _fieldMap {
    my $self = shift;
    my $version = $self->_version;

    my %field_map = (
        20 => {
            dateBegin        => 'Q', # header

            albumName        => 'D',
            artistName       => 'C',
            labelName        => 'A',
            productType      => 'H',
            priceLevel       => 'J',
            upc              => 'E',
            sales            => 'K', # Sales units
            returns          => 'L', # Return units
            totalRevenue     => 'Q', # Net revenue

            salesRevenue     => 'N', # Gross Before Discount
            returnsRevenue   => 'O', # Returns Before Discount
        },
        23 => {
            dateBegin        => 'Q', # header

            albumName        => 'D',
            artistName       => 'C',
            labelName        => 'B',
            productType      => 'H',
            priceLevel       => 'J',
            upc              => 'E',
            sales            => 'K', # Sales units
            returns          => 'L', # Return units
            totalRevenue     => 'Q', # Net revenue

            salesRevenue     => 'N', # Gross Before Discount
            returnsRevenue   => 'O', # Returns Before Discount
        },
    );
    return $field_map{$version};
}

sub _unverifiedFieldMap {
    {
        discountAmount => 'P'
    }
}

sub _headerIdentifier { ( upc => 'UPC' ) }

sub currencyCode { 'USD' }

sub countryCode {
    my $self = shift;
    if( !exists $self->{_countryCode} )
    {
        if( $self->filename =~ /US_/i )
        {
            $self->{_countryCode} = 'US';
        }
        elsif( $self->filename =~ /CA_/i )
        {
            $self->{_countryCode} = 'CA';
        }
        else
        {
            $self->fail("Unable to determine country code from ". $self->filename);
        }
    }
    return $self->{_countryCode};
}

sub physical { 1 };

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');

    return RPS::File::Sale::TYPE_CD if( $type =~ /^compact disc$/i );
    return RPS::File::Sale::TYPE_LP if( $type =~ /^album$/i );

    $self->fail( "Could not parse product type from '$type'" );
}

sub channel { RPS::File::Sale::CHANNEL_RETAIL }

sub priceLevel {
    my $self = shift;
    my $level = $self->_getByFieldName('priceLevel');

    if( $level =~ /^f$/i || $level =~ /^REGULAR FRONTLINE$/i )
    {
        return RPS::File::Sale::PLEVEL_FULL;
    }
    elsif( $level =~ /^m$/i || $level =~ /^MIDLINE$/i )
    {
        return RPS::File::Sale::PLEVEL_MID;
    }
    elsif( $level =~ /^b$/i )
    {
        return RPS::File::Sale::PLEVEL_BUDGET;
    }
    $self->fail( "Could not parse price level from '$level'" );
}

sub upc {
    my $self = shift;
    my $upc = $self->_getByFieldName('upc');
    return Common::Util::normalize_upc($upc);
}

sub artistName {
    my $self = shift;
    my $name = $self->_getByFieldName('artistName');
    if( $name =~ /(\w*),\s*(\w*)/ )  # Lastname, Firstname
    {
        $name = $2 . ' ' . $1; # Firstname Lastname
    }
    return $name;
}

sub _processLine
{
    my $self = shift;

    my $discount       = $self->_getByFieldName('discountAmount');
    my $salesRevenue   = $self->_getByFieldName('salesRevenue');
    my $returnsRevenue = $self->_getByFieldName('returnsRevenue');


    # Reset before we start processing the line
    #
    $self->{_discount} = 0;

    # Calculate the discount percentage
    #
    if( $discount )
    {
        $self->{_discount} = $discount/($salesRevenue + $returnsRevenue);
    }

    return $self->SUPER::_processLine(@_);
}

sub sales {
    my $self = shift;
    my $sales        = $self->_getByFieldName('sales'); 
    return $sales;
}

sub salesRevenue {
    my $self = shift;

    my $salesRevenue = $self->_getByFieldName('salesRevenue');

    # Apply the discount
    #
    $salesRevenue -= ($salesRevenue * $self->{_discount});

    # Note: if the revenue is negative, it will be included in the returns revenue
    #
    return ($salesRevenue > 0) ? $salesRevenue : 0;
}

sub returns {
    my $self = shift;
    my $returns      = $self->_getByFieldName('returns'); 
    return abs($returns);
}

sub returnsRevenue {
    my $self = shift;

    # If there is any negative sales revenue, include this in the returns revenue
    #
    my $salesRevenue   = $self->_getByFieldName('salesRevenue');
    my $returnsRevenue = $self->_getByFieldName('returnsRevenue');

    my $revenue = ($salesRevenue < 0) ? ($salesRevenue + $returnsRevenue) : $returnsRevenue;

    # Apply the discount
    #
    return abs($revenue - ($revenue * $self->{_discount}));
}

sub _isValidSaleRecord {
    my $self = shift;

    # The line is valid if it has units or revenue, and also has an identifier.
    #
    return ( ($self->sales != 0 || $self->returns != 0 || $self->totalRevenue != 0) && 
             ($self->albumName || $self->artistName || $self->upc) );
}

sub saleDates {
    my $self = shift;

    return( $self->{_dateBegin}, $self->{_dateEnd} );
}

sub _processSheet {
    my $self     = shift;
    my $sheet    = shift;
    my $sheetnum = shift;

    if( $self->{sheetname} =~ /^Physical/i )
    {
        return $self->SUPER::_processSheet( $sheet, $sheetnum );
    }
}

sub _processHeader {
    my $self = shift;
    my %args = @_;
    my $dt = $self->_getByFieldName('dateBegin');

    if( $dt =~ /financial net sales umg \w{2,3} \d{2} \((\w{3})(?:\s)?(\d{2})\)/i )
    {
        my $_month = lc $1;
        my $year   = $2;

        my %months = (jan => 1, feb => 2, mar => 3, apr => 4, may => 5, jun => 6,
                      jul => 7, aug => 8, sep => 9, oct => 10, nov => 11, dec => 12);
        my $month = $months{$_month};
        $year += 2000;

        my $sdate = sprintf("%04d-%02d-01", $year, $month);
        my $edate = sprintf("%04d-%02d-%02d", $year, $month, Days_in_Month($year, $month));

        $self->{_dateBegin} = $sdate;
        $self->{_dateEnd}   = $edate;
    }
}

###
1;# Play nicely.
###