#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Universal::v32;

use strict;

use lib '/app/tools/common/lib';
use Common::Assert;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

sub _fieldMap {
    my $self = shift;
    my %field_map = (
        32 => {
            labelName        => 'C',
            artistName       => 'E',
            upc              => 'F',
            albumName        => 'G',
            totalRevenue     => 'Q',
            configuration    => 'J',
        },
        44 => {
            dateBegin        => 'A',
            labelName        => 'B',
            artistName       => 'D',
            upc              => 'E',
            albumName        => 'F',
            totalRevenue     => 'P',
            configuration    => 'I',
        }
    );
    return $field_map{$self->_version};
}

sub _unverifiedFieldMap {
    my $self = shift;
    my %field_map = (
        32 => {
            month       => 'B',
            year        => 'A',
            netQuantity => 'T',
        },
        44 => {
            netQuantity => 'S',
        },
    );
    return $field_map{$self->_version};
}

sub _headerIdentifier { ( upc => qr/(CPRS new UPC code|UPC)/ ) }

sub currencyCode { 'CAD' }
sub countryCode  { 'CA' }
sub channel      { RPS::File::Sale::CHANNEL_RETAIL }
sub priceLevel   { RPS::File::Sale::PLEVEL_UNKNOWN }
sub physical     { 1 }

sub productType  {
    my $self = shift;
    my $cfg = $self->_getByFieldName('configuration') || return;

    if( $cfg =~ /^cd album$/i )
    {
        return RPS::File::Sale::TYPE_CD;
    }
    elsif( $cfg =~ /^dvd video album pal$/i )
    {
        return RPS::File::Sale::TYPE_DVD;
    }
    elsif( $cfg =~ /^vinyl album 12" 33 rpm$/i )
    {
        return RPS::File::Sale::TYPE_LP;
    }
    $self->fail("Unknown config '$cfg'");
}

sub sales {
    my $self = shift;
    my $sales = $self->_getByFieldName('netQuantity');
    my $salesRevenue = $self->_getByFieldName('totalRevenue');
    return ( $sales > 0 && $salesRevenue > 0 ) ? $sales : 0;
}

sub salesRevenue {
    my $self = shift;
    my $sales        = $self->_getByFieldName('netQuantity');
    my $salesRevenue = $self->_getByFieldName('totalRevenue');

    return ( $sales > 0 && $salesRevenue > 0 ) ? $salesRevenue : 0;
}

sub returns {
    my $self = shift;
    my $sales        = $self->_getByFieldName('netQuantity');
    my $salesRevenue = $self->_getByFieldName('totalRevenue');
    return ( $sales < 0 || $salesRevenue < 0 ) ? abs($sales) : 0;
}

sub returnsRevenue {
    my $self = shift;
    my $sales        = $self->_getByFieldName('netQuantity');
    my $salesRevenue = $self->_getByFieldName('totalRevenue');

    return ( $sales < 0 || $salesRevenue < 0 ) ? abs($salesRevenue) : 0;
}

sub totalRevenue {
    my $self = shift;
    my $sales        = $self->_getByFieldName('netQuantity');
    my $salesRevenue = $self->_getByFieldName('totalRevenue') || return;
    return $salesRevenue if( $sales != 0 );
    $self->fail("Revenue " . $salesRevenue . " found with zero units");
}

sub saleDates {
    my $self = shift;

    my $startDate;

    if( exists $self->_fieldMap->{'dateBegin'} )
    {
        $startDate = $self->_getByFieldName('dateBegin');
    }
    else
    {
        my $month = $self->_getByFieldName('month') || return;  
        my $year  = $self->_getByFieldName('year');
        $startDate = "$month $year";
    }

    my( $dateBegin, $dateEnd ) = $self->_getDates( date_begin => $startDate );

    return ($dateBegin, $dateEnd);
}

sub _isValidSaleRecord {
    my $self = shift;
    my $albumName  = $self->_getByFieldName('albumName');

    return ( $albumName && $self->totalRevenue && $self->sales ne 'Gross Sales Units' && $self->dateBegin );
}

###
1;# Play nicely.
###