#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------
package RPS::Import::Universal::v36;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use base 'RPS::Import::MapFaceBase';
use base 'RPS::Import::Importer';

sub _fieldMap {
    my $self = shift;
    my $version = $self->_version;
    my %fieldMap = (
        36 => {
            dateBegin     => 'A',
            countryCode   => 'K',
            units         => 'Q',
            price         => 'AA',
            productType   => 'H', # Carrier Type
            formatType    => 'O', # Sale Description
            serviceID     => 'N',
        },
        51 => {
            dateBegin     => 'A',
            countryCode   => 'L',
            units         => 'R',
            price         => 'AB',
            productType   => 'I', # Carrier Type
            formatType    => 'P', # Sale Description
            serviceID     => 'O',
        },
        53 => {
            dateBegin     => 'A',
            countryCode   => 'N',
            units         => 'T',
            price         => 'AD',
            productType   => 'H', # Carrier Type
            formatType    => 'R', # Sale Description
            serviceID     => 'Q',
        },
    );
    return $fieldMap{$version};
}

sub _unverifiedFieldMap {
    my $self = shift;
    my $version = $self->_version;
    my %fieldMap = (
        36 => {
            articleNumber => 'L', # upc or isrc
            itemTitle     => 'G', # album or track title
        },
        51 => {
            articleNumber => 'M', # upc or isrc
            itemTitle     => 'G', # album or track title
        },
        53 => {
            articleNumber => 'O', # upc or isrc
            itemTitle     => 'G', # album or track title
        },
    );
    return $fieldMap{$version};
}

sub _headerIdentifier { ( dateBegin => 'Processing Period' ) }

sub currencyCode {
    my $self = shift;
    return $self->{_currencyCode}; # See _processHeader
}

sub countryCode {
    my $self = shift;

    my $ccode;
    my $cname = $self->_getByFieldName('countryCode');

    $cname = "Czech Republic" if( $cname =~ /^CZECH$/i );
    $cname = "TT" if( $cname =~ /^TRINIDAD & TOBAGO$/i );
    $cname = "BN" if( $cname =~ /^BRUNEI$/i ); # Brunei Darussalam

    if( $cname =~ /^(\w{2,3})$/ ) # 2 or 3 character 
    {
        $ccode = $cname;
    }
    else
    {
        my $o = Common::Country->Get($cname);
        if( !$o )
        {
            $self->handleError("Unknown country: $cname", RPS::DB::Item::SaleImportError::kErrorCountry );
            return $cname;
        }
        $ccode = $o->alpha2();
    }
    return $ccode;
}

sub serviceID {
    my $self = shift;
    my $service = $self->_getByFieldName('serviceID');
    my $serviceID = $self->getServiceID(lc ($service)) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };
    return $serviceID if( $serviceID );

    return $self->handleError("Unknown service: $service", RPS::DB::Item::SaleImportError::kErrorService);
}

sub saleDates {
    my $self = shift;
    my $dt = $self->_getByFieldName('dateBegin');

    my $startDate;
    my $endDate;

    if( $dt =~ /^(\d{4})(\d{2})$/ )
    {
        my($year, $month) = ($1, $2);
        $startDate = sprintf("%04d-%02d-01", $year, $month);
        $endDate = sprintf("%04d-%02d-%02d", $year, $month, Days_in_Month($year, $month));
    }

    return( $startDate, $endDate );
}

sub productType {
    my $self = shift;
    my $code = $self->_getByFieldName('productType') || return;

    if( $code =~ /^(B1|B4)$/i )
    {
        return RPS::File::Sale::TYPE_ALBUM;
    } 
    elsif( $code =~ /^(ID|IV|B2)$/i )
    {
        return RPS::File::Sale::TYPE_TRACK;
    } 
    return $self->handleError("Unknown product type: $code", RPS::DB::Item::SaleImportError::kErrorProductType);
}

sub formatType {
    my $self = shift;
    my $desc = $self->_getByFieldName('formatType') || return;
    if( $desc =~ /PERMD  PERMANENT DOWNLOAD/i ||
        $desc =~ /MOBFT  FULL TRACK D.LOAD MOBIL/i ||
        $desc =~ /MOBPE  MOBILE PERMANENT DOWNL/i ||
        $desc =~ /TIMED  TIMED OUT DOWNLOAD/i ||
        $desc =~ /MOBVC  MOBILE MUSIC VIDEO CLIP/i ||
        $desc =~ /MOBSA  MOBILE SERVICE ACTIVATI/i )
    {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    }
    elsif( $desc =~ /MOBMT  MESSAGE MIXED SOUND/i ||
           $desc =~ /MOBMT  MOBILE MASTER TONES/i ||
           $desc =~ /RINGB  U-MOBILE CALL RING REAL/i ||
           $desc =~ /RINGB  RING-BACK TONES/i )
    {
        return RPS::File::Sale::FORMAT_RINGTONE;
    }
    elsif( $desc =~ /PORTD  DOWNLOAD PORTABLE DEVIC/i ||
           $desc =~ /PERMD  DIGITAL ALLOCATIONS/i )
    {
        return RPS::File::Sale::FORMAT_TETHERED;
    }
    elsif( $desc =~ /STREA  STREAMING/i ||
           $desc =~ /TVCLI  TVCLIP VIDEO/i ||
           $desc =~ /WEBCA  WEBCASTING\/SIMULCASTIN/i ||
           $desc =~ /SUBSC  STREAMING\/SUBSCRIPTION/i )
    {
        return RPS::File::Sale::FORMAT_STREAM;
    }
    $self->handleError("Unknown format: $desc", RPS::DB::Item::SaleImportError::kErrorFormatType);
}

sub mediaType {
    my $self = shift;
    my $code = $self->_getByFieldName('productType') || return;
    
    if( $code =~ /^(B1|ID|B2)$/i )
    {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    } 
    elsif( $code =~ /^(IV|B4)$/i )
    {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    } 
    return $self->handleError("Unknown media type: $code", RPS::DB::Item::SaleImportError::kErrorMediaType);
}

sub upc {
    my $self = shift;
    my $upc = $self->_getByFieldName('articleNumber');
    if( !$self->productType )
    {
        # If we don't have a product type, see if the UPC looks like a UPC or an ISRC
        #
        return ( $upc =~ /^[a-z]{2}.+/i ) ?  undef  : $upc;
    }
    return ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) ? $upc : undef;
}

sub isrc {
    my $self = shift;
    my $isrc = $self->_getByFieldName('articleNumber');
    if( !$self->productType )
    {
        # If we don't have a product type, see if the ISRC looks like an ISRC or UPC
        #
        return ( $isrc =~ /^[a-z]{2}.+/i ) ? $isrc : undef;
    }
    return ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) ? $isrc : undef;
}

sub albumName {
    my $self = shift;
    my $name = $self->_getByFieldName('itemTitle');
    if( !$self->productType )
    {
        # If we don't have a product type, peek at the UPC/ISRC field and make a best guess
        #
        return ( $self->SUPER::isrc =~ /^[a-z]{2}.+/i ) ?  undef  : $name;
    }
    return ($self->productType eq RPS::File::Sale::TYPE_ALBUM) ? $name : undef;
}

sub trackName {
    my $self = shift;
    my $name = $self->_getByFieldName('itemTitle');
    if( !$self->productType )
    {
        # If we don't have a product type, peek at the UPC/ISRC field and make a best guess
        #
        return ( $self->SUPER::isrc =~ /^[a-z]{2}.+/i ) ?  $name  : undef;
    }
    return ($self->productType eq RPS::File::Sale::TYPE_TRACK) ? $name : undef;
}

sub _processSheet {
    my $self     = shift;
    my $sheet    = shift;
    my $sheetnum = shift;

    return $self->SUPER::_processSheet( $sheet, $sheetnum ) if( $self->_version == 53 );

    if( $self->{sheetname} =~ /^Report$/i )
    {
        return $self->SUPER::_processSheet( $sheet, $sheetnum );
    }
}

sub _processHeader {
    my $self = shift;

    # Note: _processHeader is called for every line until we actually find
    # the header (assuming _headerIdentifier() is setup correctly).  We
    # only want to look at the header line itself.
    #
    return if( !defined $self->{_headerFound} );

    my $c = $self->_getByFieldName('price');
    if( $c =~ /Net Royalty Amount \((\w{2,3})\)/i )
    {
        $self->{_currencyCode} = $1;
    }
    else
    {
        return $self->handleError( "Missing currency code", RPS::DB::Item::SaleImportError::kErrorNonqualifying );
    }

    return $self->SUPER::_processHeader(@_);
}

#####    MapFace    #####
#

sub _mapFaceCompatibleVersions {
    return( 36, 51, 53 );
}

sub _mapFaceServiceID {
    return('serviceID');
}

sub _mapFaceCountryCode {
    return('countryCode');
}

sub _mapFaceProductType {
    return('productType');
}

sub _mapFaceFormatType {
    return('formatType');
}

sub _mapFaceMediaType {
    return('productType');
}


###
1;# Play nicely.
###