package RPS::Import::Verve;

use strict;

use lib '/app/tools/common/lib';
use Common::Util;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use base 'RPS::Import::Importer';

use constant FIELD_SVC_PROD_ID      => 0;
use constant FIELD_UNITS            => 1;
use constant FIELD_UPC              => 2;
use constant FIELD_ALBUM            => 3;
use constant FIELD_ARTIST           => 4;
use constant FIELD_ISRC             => 5;
use constant FIELD_TRACK            => 6;

#public methods

sub _importLines
{
    my $self = shift;
    my %args = @_;

    my $fileObj = $args{file};
    my $fileName = $fileObj->OrigFileName;
    #my $fileName = $args{OrigFileName};

    my $lines = $args{lines};
    return 0 unless ($lines);

    my ($dateBegin, $dateEnd) = $self->_getDates($fileName);
    unless ($dateBegin && $dateEnd)
    {
        $self->errstr("couldn't get dates");
        print STDERR "fname: $fileName\n";
        return undef;
    }
    my $prodtype = RPS::File::Sale::TYPE_TRACK;
    my $format = RPS::File::Sale::FORMAT_DOWNLOAD;

    my $linenum = 1;
    foreach my $line(@$lines)
    {
        my $svcProd     = $line->[FIELD_SVC_PROD_ID];
        my $artist      = $line->[FIELD_ARTIST];
        my $album       = $line->[FIELD_ALBUM];
        my $track       = $line->[FIELD_TRACK];
        my $upc         = Common::Util::normalize_upc($line->[FIELD_UPC]);
        my $isrc        = Common::Util::normalize_isrc($line->[FIELD_ISRC]);
        my ($units)     = $line->[FIELD_UNITS] =~ m/^(\d+)$/;

        if ($units && $artist && $track)
        {
            my $sale = RPS::Import::SaleRec->new();

            $sale->productType($prodtype);
            $sale->formatType($format);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->serviceProductID($svcProd);
            $sale->upc($upc);
            $sale->isrc($isrc);
            $sale->albumName($album);
            $sale->artistName($artist);
            $sale->trackName($track);
            $sale->units($units);
            $sale->lineNum($linenum);
            $sale->countryCode("US");
    
            #$args{dumper}($sale);  ## for cmd-line testing
            $self->_insertSale(sale => $sale);
        }
        $linenum++;
    }
    return $linenum;
}

#
# Private methods
#

sub _getDates
{
    my $self = shift;
    my $fName = shift;

    return undef unless ($fName =~ m/\D(\d\d\d\d)\D/);
    my $year = $1;

    # annual report
    return (
        Common::Util::normalize_date(join('-', $year, 1, 1)),
        Common::Util::normalize_date(join('-', $year, 12, 31)),
   );
}

###
1;# Play nicely.
###