package RPS::Import::WMG::SprintMultiTab;

use strict;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Util qw(normalize_isrc);

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::WMG::Util;
use base 'RPS::Import::WMG::SprintBase';

my %field_map =
(
    3 => {
        rate_adjust => 1,
        units_adjust=> 1,
        cli_prod_id => 0,
        description => 3,
        svc_prod_id => 4,
        isrc        => 5,
        units       => 7,
        retail      => 8,
        rate        => 10,
        price       => 11,
    },
    4 => { # demos
        rate_adjust => 0.01,
        units_adjust=> -1,
        cli_prod_id => 1,
        svc_prod_id => 3,
        description => 7,
        units       => 8,
        retail      => 9,
        rate        => 12,
        price       => 13,
    },
    5 => {
        rate_adjust => 1,
        units_adjust=> 1,
        cli_prod_id => 0,
        description => 3,
        svc_prod_id => 4,
        isrc        => 6,
        units       => 7,
        retail      => 8,
        rate        => 10,
        price       => 11,
    },
    6 => { # demos
        rate_adjust => 1,
        units_adjust=> -1,
        cli_prod_id => 3,
        svc_prod_id => 4,
        description => 5,
        units       => 8,
        retail      => 9,
        rate        => 10,
        price       => 11,
    },
    7 => { # demos - similar to ver 4 above but has a blank col in the middle to screw up the offsets
        rate_adjust => 1,
        units_adjust=> -1,
        cli_prod_id => 1,
        svc_prod_id => 3,
        description => 7,
        units       => 8,
        retail      => 10,
        price       => 13,
    },
    8 => { # demos
        rate_adjust => 1,
        units_adjust=> -1,
        cli_prod_id => 3,
        description => 4,
        svc_prod_id => 5,
        units       => 8,
        retail      => 9,
        price       => 10,
    },
);

sub _importLines
{
    my $self = shift;
    my %args = @_;

    my $sheets = $args{sheets};
    my $fileObj = $args{file};
    my $version = $self->_version;
    my $fileName = $fileObj->OrigFileName;
    #my $fileName = $args{OrigFileName}; # for cmd-line testing

    my ($dateBegin, $dateEnd) = $self->_getDates($fileName);
    unless ($dateBegin && $dateEnd)
    {
        $self->errstr("couldn't get dates");
        print STDERR "fileName: $fileName\n";
        return undef;
    }

    my ($billTo, $sellTo) = RPS::Import::WMG::Util::getWirelessInfo($self->{fileServiceID});
    unless ($billTo && $sellTo)
    {
        $self->warning();
        print STDERR "unknown billto/sellto mapping: $self->{fileServiceID}\n";
    }

    $fileObj->Atomic(1);
    $fileObj->Save();

    my $offsets = $field_map{$version};
    my $prodType = RPS::File::Sale::TYPE_TRACK;
    my %errors;
    my $i = 0;

    foreach my $sheet(@$sheets)
    {
        if ($version == 7) # let's change formats within the same report (friggin sprint)
        {
            $offsets = $field_map{8} unless (length $sheet->[0][ $field_map{7}{price} ]);
        }
        my $formatName  = $self->_decodeSprintFormatID($args{sheet_names}->[$i]);
        my $format = RPS::Import::WMG::Util::getWirelessFormatTypeID($formatName);
        unless ($formatName && $format)
        {
            print STDERR "unknown format for $args{sheet_names}->[$i]\n";
            $i++;
            next;
        }
        #print STDERR "using format: $formatName ($format)\n";
        my ($formatMatch) = $formatName =~ /^(\w)/;
        my $priceType = '';

        unless ($priceType = RPS::Import::WMG::Util::getWirelessPriceType($formatName))
        {
            unless ($errors{$formatName})
            {
                $self->warning();
                print STDERR "unknown format mapping: $formatName\n";
                $errors{$formatName} = 1;
            }
        }

        my $linenum = 100000 * ($i + 1); # keeps linenum unique for each sheet

        foreach my $line(@$sheet)
        {
            my ($track, $artist) = $self->_parseDescription($line->[$offsets->{description}], $formatMatch);
            my $cliProdID   = $line->[$offsets->{cli_prod_id}];
            my $svcProdID   = $line->[$offsets->{svc_prod_id}];
            next if ($svcProdID =~ m/\s+Total$/);
            my $isrc        = defined $offsets->{isrc} ? normalize_isrc($line->[$offsets->{isrc}]) : '';
            my ($units)     = $line->[$offsets->{units}] =~ m/^(-?\d+)$/;
            my ($retail)    = $line->[$offsets->{retail}] =~ m/^(-?\d*\.?\d*)$/;
            my ($ppdRate)   = $line->[$offsets->{rate}] =~ m/^(0?\.?\d+)$/;
            my ($price)     = $line->[$offsets->{price}] =~ m/^(\d*\.?\d*)$/;

            if ($track && $units && $price =~ m/\d/)
            {
                $retail /= $units if ($version =~ /^(4|6|7|8)$/);
                $price /= $units unless ($version =~ /^(7|8)$/);
                $units *= $offsets->{units_adjust};
                if ($version =~ m/^(7|8)$/)
                {
                    $ppdRate = $retail ? $price / $retail : 1;
                }
                else
                {
                    $ppdRate *= $offsets->{rate_adjust};
                }

                my $sale = RPS::Import::SaleRec->new();

                $sale->productType($prodType);
                $sale->formatType($format);
                $sale->dateBegin($dateBegin);
                $sale->dateEnd($dateEnd);
                $sale->serviceProductID($svcProdID);
                $sale->clientProductID($cliProdID);
                $sale->artistName($artist);
                $sale->trackName($track);
                $sale->isrc($isrc);
                $sale->units($units);
                $sale->price($price);
                $sale->retail($retail);
                $sale->wholesaleRate($ppdRate);
                $sale->priceType($priceType);
                $sale->lineNum($linenum);

                #$args{dumper}($sale); # for cmd-line testing
                $self->_insertSale(sale => $sale);
            }#else { print STDERR "skip u: $units p: $price t: $track a: $artist ($linenum)\n" }
            $linenum++;
        }
        $i++;
    }

    return $i - 1;
}

#
# Private methods
#


sub _getDates
{
    my $self = shift;
    my $fileName = shift;

    my ($qtr, $year);
    if ($fileName =~ m/\D(\d)\w\w.*?qtr\D*?(\d{4})\D/)
    {
        ($qtr, $year) = ($1, $2);
    }
    elsif ($fileName =~ m/Q(\d)\D(\d{4})\D/)
    {
        ($qtr, $year) = ($1, $2);
    }
    elsif ($fileName =~ m/Q(\d)\D+(\d{4})\D/)
    {
        ($qtr, $year) = ($1, $2);
    }

    return unless ($qtr && $year);

    my $monthEnd = $qtr * 3;

    return (
        sprintf("%04d-%02d-01", $year, $monthEnd - 2),
        sprintf("%04d-%02d-%02d", $year, $monthEnd, Days_in_Month($year, $monthEnd))
    );
}

###
1;# Play nicely.
###