package RPS::Import::WMG::VerizonOldEMD;
use strict;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Util;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/sale_import/lib';
use RPS::File::Sale;
use base 'RPS::Import::Importer';
use RPS::Import::WMG::Util;

my %field_map = (
    90 => {
        clientID    => 1,
        country     => 5,
        units       => 6,
        price       => 7,
        artist      => 9,
        title       => 10,
        currency    => 11,
        prodID      => 13, # upc or isrc (value)
        prodType    => 14, # 'upc' or 'isrc'
        priceType   => 16,
        retail      => 17
    },
    91 => {
        clientID    => 1,
        country     => 5,
        units       => 6,
        price       => 7,
        artist      => 9,
        title       => 10,
        currency    => 11,
        prodID      => 14, # upc or isrc (value)
        prodType    => 15, # 'upc' or 'isrc'
        priceType   => 17,
        retail      => 18
    },
);

#public methods

sub _importLines
{
    my $self = shift;
    my %args = @_;

    my $lines = $args{lines};
    my $fileObj = $args{file};
    my $fileName = $fileObj->OrigFileName();
    my $version = $fileObj->VersionNum();
    # for cmd-line testing
    #my $fileName = $args{OrigFileName};
    #my $version = $args{version};

    return 0 unless $lines;
    my $offsets = $field_map{$version} || return undef;
    my ($dateBegin, $dateEnd) = $self->_getDates($fileName);

    unless ($dateBegin && $dateEnd)
    {
        $self->errstr("couldn't get dates");
        print STDERR "filename: $fileName\n";
        return 0;
    }

    my @billTo = RPS::Import::WMG::Util::getWirelessBillto($self->{fileServiceID});
    if ($billTo[0])
    {
        unless (RPS::Import::WMG::Util::getWirelessSellto($self->{fileServiceID}, $billTo[0]))
        {
            $self->warning();
            print STDERR "unknown sellto mapping: $billTo[0]\n";
        }
    }
    else
    {
        $self->warning();
        print STDERR "unknown billto mapping: $self->{fileServiceID}\n";
    }

    $fileObj->Atomic(1);
    $fileObj->Save();

    my $linenum = 1;
    my %errors = ();
    foreach my $line(@$lines)
    {
        my ($isrc, $upc, $track, $album);
        my $prodType = lc($line->[$offsets->{prodType}]);
        if ($prodType eq 'isrc')
        {
            $prodType = RPS::File::Sale::TYPE_TRACK;
            $isrc = Common::Util::normalize_isrc($line->[$offsets->{prodID}]);
            $isrc = $line->[$offsets->{prodID}];
            $track = $line->[$offsets->{title}];
        }
        elsif ($prodType eq 'upc')
        {
            $prodType = RPS::File::Sale::TYPE_ALBUM;
            $upc = Common::Util::normalize_upc($line->[$offsets->{prodID}]);
            $album = $line->[$offsets->{title}];
        }
        else
        {
            $self->warning();
            print STDERR "invalid product-type: ($prodType) line $linenum";
            $linenum++;
            next;
        }

        my $clientProdID= $line->[$offsets->{clientID}];
        my $country     = $line->[$offsets->{country}];
        my $currency    = $line->[$offsets->{currency}];
        my $artist      = $line->[$offsets->{artist}];
        my ($units)     = $line->[$offsets->{units}] =~ m/^(-?\d+)$/;
        my ($price)     = $line->[$offsets->{price}] =~ m/^(-?\d*\.?\d+)$/;
        my $retail      = $line->[$offsets->{retail}];

        if (($track || $album) && $artist && $units && $retail && $price)
        {
            my $formatID = RPS::File::Sale::FORMAT_DUALDOWNLOAD;
            my $priceType = $line->[$offsets->{priceType}] || 'Standard';
            my $wRate = $retail > 0 ? $price / $retail : 0;

            my $sale = RPS::Import::SaleRec->new();

            $sale->productType($prodType);
            $sale->formatType($formatID);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->clientProductID($clientProdID);
            $sale->artistName($artist);
            $sale->albumName($album);
            $sale->trackName($track);
            $sale->isrc($isrc);
            $sale->upc($upc);
            $sale->units($units);
            $sale->price($price);
            $sale->retail($retail);
            $sale->wholesaleRate($wRate);
            $sale->currencyCode($currency);
            $sale->countryCode($country);
            $sale->lineNum($linenum);
            $sale->priceType($priceType);

            #$args{dumper}($sale);
            $self->_insertSale(sale => $sale);
        }else { print STDERR "skip t: $track a: $artist u: $units r: $retail p: $price ($linenum)\n" }
        $linenum++;
    }

    return $linenum;
}

#
# Private methods
#

sub _getDates
{
    my $self = shift;
    my $fileName = shift;

    $fileName =~ m/\D(\d\d\d\d)\D(\d\d)/;
    my ($year, $month) = ($1, $2);

    return undef unless ($month && $year);
    return (
        sprintf("%04d-%02d-01", $year, $month),
        sprintf("%04d-%02d-%02d", $year, $month, Days_in_Month($year, $month))
    );
}

###
1;# Play nicely.
###