package RPS::Import::WMG::WarnerWirelessAGG;

use strict;


use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Util;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::WMG::Util;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

use constant FIELD_PROVIDER  => 0;
use constant FIELD_PERIOD    => 1;
use constant FIELD_ACCT      => 2;
use constant FIELD_ARTIST    => 3;
use constant FIELD_LABEL     => 4;
use constant FIELD_TRACK     => 5;
use constant FIELD_UNITS     => 6;
use constant FIELD_PRICE     => 7;
use constant FIELD_PPD_CONV  => 10;
use constant FIELD_PPD_UNIT  => 11;
use constant FIELD_PVDR_TYPE => 12;
use constant FIELD_PAY_TYPE  => 13;
use constant FIELD_ISRC      => 21;

#
# public methods
#

sub _importLines
{
    my $self = shift;
    my %args = @_;
    my $lines = $args{lines};

    return undef unless ($lines);

    my $linenum = 1;

    foreach my $line (@$lines)
    {
        my ($dateBegin, $dateEnd) = _get_dates($line->[FIELD_PERIOD], $line->[FIELD_ACCT]);

        unless ($dateBegin && $dateEnd)
        {
            if ($linenum == 1)
            {
                $linenum++;
                next;
            }
            $self->errstr("couldn't get dates");
            print STDERR " $linenum period: ". $line->[FIELD_PERIOD] .' '. $line->[FIELD_ACCT]."\n";
            return undef;
        }

        my ($price) = $line->[FIELD_PRICE] =~ m/^(\d*\.?\d+)$/;
        my $ppdUnit = $line->[FIELD_PPD_UNIT];
        my $ppdConv =
            $line->[FIELD_PPD_CONV] ? $line->[FIELD_PPD_CONV] :
            $price ? $ppdUnit / $price : 1;
        $ppdConv /= 100 if ($ppdConv =~ s/%//);
        unless ($ppdConv)
        {
            print STDERR join(', ', 'invalid ppd info', $line->[FIELD_PPD_CONV], $ppdUnit);
            $linenum++;
            next;
        }

        my $providerID;
        unless ($providerID = $self->getServiceID($line->[FIELD_PROVIDER]))
        {
            $self->errstr('unknown service');
            print STDERR 'service: '. $line->[FIELD_PROVIDER] . "\n";
            return undef;
        }
        my $format = RPS::Import::WMG::Util::getWirelessFormatTypeID($line->[FIELD_PVDR_TYPE]);
        my $priceType = RPS::Import::WMG::Util::getPriceType($line->[FIELD_PVDR_TYPE]);
        unless ($format && $priceType)
        {
            $self->errstr('unknown format');
            print STDERR "format: $line->[FIELD_PVDR_TYPE]\n";
            return undef;
        }

        my $prodtype  = RPS::File::Sale::TYPE_TRACK;

        my $artist   = $line->[FIELD_ARTIST];
        my $label    = $line->[FIELD_LABEL];
        my $track    = $line->[FIELD_TRACK];
        my ($units)  = $line->[FIELD_UNITS] =~ m/^(\d+)$/;
        my $payType  = $line->[FIELD_PAY_TYPE];
        my $isrc     = $line->[FIELD_ISRC];
        $isrc =~ s/WMG\s//;

        if ($artist && $units && $price >= 0)
        {
            my $sale = RPS::Import::SaleRec->new();

            $sale->serviceID($providerID);
            $sale->productType($prodtype);
            $sale->formatType($format);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->isrc($isrc);
            $sale->artistName($artist);
            $sale->trackName($track);
            $sale->labelName($label);
            $sale->units($units);
            $sale->price($ppdUnit);
            $sale->wholesaleRate($ppdConv);
            $sale->retail($price);
            $sale->payoutType($payType);
            $sale->priceType($priceType);
            $sale->lineNum($linenum);

            #$args{dumper}($sale); ## for cmd-line testing
            $self->_insertSale(sale => $sale);
        }
        #else { print STDERR "skip:". join(',', @$line) . "\n"; }
        $linenum++;
    }

    # set the atomic flag
    my $fileObj = $args{file};
    $fileObj->Atomic(1);
    $fileObj->Save();

    return $linenum;
}

#
# Private methods
#

sub _get_dates
{
    my ($period, $cycle) = @_;

    return unless ($period =~ m/^(\d\d)\D(\d\d)\D(\d{4})$/);
    my ($month, $day, $year) = ($1, $2, $3);

    return (
        sprintf("%04d-%02d-01", $year, $month), 
        sprintf("%04d-%02d-%02d", $year, $month, Days_in_Month($year, $month))
    ) if (lc($cycle) eq 'monthly');
    
    return Common::Util::get_quarter_begin_end($month, $year);

}

###
1;# Play nicely.
###