package RPS::Import::WMG::XRinger;
use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Util;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';
use RPS::File::Sale;
use RPS::Import::WMG::Util;

use constant SVC_PRODID => 0;
use constant TRACK      => 1;
use constant ARTIST     => 2;
use constant GRID       => 3;
use constant RETAIL     => 4;
use constant UNITS      => 6;
use constant PRICE      => 7;
use constant PRICE_TYPE => 8;

#public methods

sub _importLines
{
    my $self = shift;
    my %args = @_;
    my $fileObj = $args{file};
    my $sheets = $args{sheets};

    my $prodType = RPS::File::Sale::TYPE_TRACK;
    my $formatID = RPS::File::Sale::FORMAT_WALLPAPER;

    my @billTo = RPS::Import::WMG::Util::getWirelessBillto($self->{fileServiceID});
    if ($billTo[0])
    {
        unless (RPS::Import::WMG::Util::getWirelessSellto($self->{fileServiceID}, $billTo[0]))
        {
            $self->warning();
            print STDERR "unknown sellto mapping: $billTo[0]\n";
        }
    }
    else
    {
        $self->warning();
        print STDERR "unknown billto mapping: $self->{fileServiceID}\n";
    }

    $fileObj->Atomic(1);
    $fileObj->Save();

    my $linenum;
    my $i = 0;
    foreach my $sheet(@$sheets)
    {
        my ($dateBegin, $dateEnd) = $self->_getDates($args{sheet_names}->[$i]);

        unless ($dateBegin && $dateEnd)
        {
            $self->errstr("couldn't get dates");
            print STDERR "sheetname: $args{sheet_names}->[$i]\n";
            return 0;
        }

        $linenum = 1 + ($i+1) * 1000;
        foreach my $line(@$sheet)
        {
            my $svcProdID   = $line->[SVC_PRODID];
            my $track       = $line->[TRACK];
            my $artist      = $line->[ARTIST];
            my $grid        = $line->[GRID];
            my $retail      = $line->[RETAIL];
            my $units       = $self->numeric($line->[UNITS]);
            my $price       = $self->numeric($line->[PRICE]);
            my $priceType   = $line->[PRICE_TYPE];

            if ($track && $artist && $units && $retail && $price)
            {
                $price /= $units;
                my $wRate = $price / $retail;

                my $sale = RPS::Import::SaleRec->new();

                $sale->artistName($artist);
                $sale->clientProductID($grid);
                $sale->dateBegin($dateBegin);
                $sale->dateEnd($dateEnd);
                $sale->formatType($formatID);
                $sale->lineNum($linenum);
                $sale->price($price);
                $sale->productType($prodType);
                $sale->retail($retail);
                $sale->priceType($priceType);
                $sale->serviceProductID($svcProdID);
                $sale->trackName($track);
                $sale->units($units);
                $sale->wholesaleRate($wRate);

                #$args{dumper}($sale);
                $self->_insertSale(sale => $sale);
            }#else { print STDERR "skip t: $track a: $artist u: $units r: $retail p: $price\n" }
            $linenum++;
        }
        $i++;
    }
    return $linenum;
}

#
# Private methods
#

sub _getDates
{
    my $self = shift;
    my $sheetName = lc $_[0];

    # WMG_4Q06
    return undef unless ($sheetName =~ m/\D(\d)q(\d\d)/);
    my ($month, $year) = ($1 * 3, 2000 + $2);

    return (
        sprintf("%04d-%02d-01", $year, $month-2),
        sprintf("%04d-%02d-%02d", $year, $month, Days_in_Month($year, $month))
    );
}

###
1;# Play nicely.
###