package RPS::Import::eMusicThirdParty;

#### NOTE -- these files do not have dates in them and we have to set them manually
#### in the db after the file is imported.

use strict;


use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Util;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

my %field_map = (
                 15 => {
                        'upc'    => 0,
                        'track'  => 1,
                        'album'  => 2,
                        'artist' => 3,
                        'label'  => 4,
                        'units'  => 5,
                        'price'  => 6,
                        },
                );

sub _importLines
{
    my $self = shift;
    my %args = @_;

    my $lines = $args{lines};

    my $fileObj = $args{file};
    ##my $version = $args{version}; # for cmd-line testing
    my $version = $fileObj->VersionNum;

    return undef unless ($lines && $version);
    my $offsets = $field_map{$version};

    my ($rate) = $self->_getRate($lines);

    unless (defined $rate)
    {
        $self->errstr("missing percentage rate");
        return undef;
    }

    my $header = 1;  # flag

    my $linenum = 1;
    foreach my $line(@$lines)
    {
        ## skip header
        if ($header && $line->[0] !~ m/upc/i) {
            $linenum++;
            next;
        }
        $header = 0;

        ## skip empty lines
        if ($line->[0] eq '') {
            $linenum++;
            next;
        }

        my $format   = RPS::File::Sale::FORMAT_VPD;
        my $prodtype = RPS::File::Sale::TYPE_TRACK;
        my $upc      = Common::Util::normalize_upc($line->[$offsets->{'upc'}]);
        my $artist   = $line->[$offsets->{'artist'}];
        my $album    = $line->[$offsets->{'album'}];
        my $track    = $line->[$offsets->{'track'}];
        my $label    = $line->[$offsets->{'label'}];
        my ($units)  = $line->[$offsets->{'units'}] =~ m/^(\d+)$/;
        my ($price)  = $line->[$offsets->{'price'}] =~ m/^(\d+(\.\d+)?)$/;
        my $netPrice = $price * $rate;

        if ($upc && $artist && $track && $units && $price)
            {

            my $sale = RPS::Import::SaleRec->new();

            $sale->productType($prodtype);
            $sale->formatType($format);
            #$sale->dateBegin($dateBegin);
            #$sale->dateEnd($dateEnd);
            $sale->upc($upc);
            $sale->trackName($track);
            $sale->artistName($artist);
            $sale->albumName($album);
            $sale->labelName($label);
            $sale->units($units);
            $sale->price($netPrice);
            $sale->lineNum($linenum);

            ##$args{dumper}($sale);  ## for cmd-line testing
            $self->_insertSale(sale => $sale);
        }
        $linenum++;
    }
    return $linenum;
}


#
# Private methods
#

sub _getRate
{
    my $self = shift;
    my $lines = shift;

    foreach my $line (@$lines) {
        if ($line->[4] =~ m/royalty earned/i) {
            if ($line->[6] =~ m/^(\d+\.\d+)$/) { 
                return $1;
            }
        }
    }
    return undef;
}

###
1;# Play nicely.
###