package RPS::Import::iBuyMusic;

use strict;


use lib '/app/tools/common/lib';
use Common::Util qw(normalize_date normalize_upc normalize_isrc);
use Common::Consts;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

use constant FIELD_DATE_BEGIN  => 0;
use constant FIELD_DATE_END    => 1;
use constant FIELD_UPC         => 2;
use constant FIELD_ISRC        => 3;
use constant FIELD_UNITS       => 4;
use constant FIELD_PRICE       => 5;
use constant FIELD_CURRENCY    => 7;
use constant FIELD_SALE_RETURN => 8;
use constant FIELD_ARTIST      => 9;
use constant FIELD_TITLE       => 10;
use constant FIELD_LABEL       => 11;
use constant FIELD_TYPE        => 12;
use constant FIELD_COUNTRY     => 13;

#public methods

sub _importLines
{
    my $self = shift;
    my %args = @_;

    my $lines = $args{lines} || return undef;
    my $retval = undef;
    my $linenum = 1;

    foreach my $line(@$lines)
    {
        my ($dateBegin) = $line->[FIELD_DATE_BEGIN] =~ m/^(\S+)/;
        my ($dateEnd)   = $line->[FIELD_DATE_END] =~ m/^(\S+)/;
        $dateBegin      = normalize_date($dateBegin);
        $dateEnd        = normalize_date($dateEnd);

        my $upc         = normalize_upc($line->[FIELD_UPC]);
        my $isrc        = normalize_isrc($line->[FIELD_ISRC]);
        my $artist      = $line->[FIELD_ARTIST];
        my $title       = $line->[FIELD_TITLE];
        my $label       = $line->[FIELD_LABEL];

        my ($price)     = $line->[FIELD_PRICE] =~ m/^(\d*\.?\d*)$/;
        my $countryCode = $Common::Consts::COUNTRY_CODE{lc $line->[FIELD_COUNTRY]};
        my $currCode    = 'USD'; # hard-coded for now

        my ($units) = $line->[FIELD_UNITS] =~ m/^(-?\d+)$/;
        $units *= -1 if ($units > 0 && uc $line->[FIELD_SALE_RETURN] ne 'S');

        my ($prodType, $album, $track);
        if (uc $line->[FIELD_TYPE] eq 'P')
        {
            $prodType = RPS::File::Sale::TYPE_ALBUM;
            $album    = $line->[FIELD_TITLE];
        }
        elsif (uc $line->[FIELD_TYPE] eq 'S')
        {
            $prodType = RPS::File::Sale::TYPE_TRACK;
            $track    = $line->[FIELD_TITLE];
        }
        else
        {
            print STDERR "unknown type: $line->[FIELD_TYPE]\n";
            next;
        }
        my $format = RPS::File::Sale::FORMAT_DOWNLOAD;


        if ($units && $price && $artist && $title)
        {
            my $sale = RPS::Import::SaleRec->new();

            $sale->productType($prodType);
            $sale->formatType($format);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->upc($upc);
            $sale->isrc($isrc);
            $sale->artistName($artist);
            $sale->albumName($album);
            $sale->trackName($track);
            $sale->labelName($label);
            $sale->units($units);
            $sale->price($price);
            $sale->currencyCode($currCode);
            $sale->countryCode($countryCode);
            $sale->lineNum($linenum);

            #$args{dumper}($sale);
            $self->_insertSale(sale => $sale);
        }
        $linenum++;
    }
    $retval = $linenum;

    return $retval;
}

#
# Private methods
#

###
1;# Play nicely.
###