package AppUser::User::Profile;

use strict;
use warnings;

use lib '/app/tools/appuser/lib';
use AppUser::DB::Item::User;
use AppUser::User::Address;

use lib '/app/tools/common/lib';
use Common::RSApp;
use Common::Assert;

use lib '/app/tools/rps/lib';
use Common::FormObject;
use base 'Common::FormObject';

sub _init {
    my ( $self, %args ) = @_;

    $self->SUPER::_init(%args);

    my %properties;

    if ( $args{_dbItem} ) {
        $self->_propertiesFromDBItem( \%properties, $args{_dbItem} );
    } elsif ( $args{userID} ) {
        $self->_propertiesFromDB( \%properties, $args{userID} );
    } else {

        # $self->_propertiesFromDefaults(\%properties);
    }

    $self->_initProperties( \%properties );
    $self->_initSubs( \%properties );

    return $self;
}

sub _propertiesFromDB {
    my ( $self, $hrProperties, $userID ) = @_;

    my $dbItem = AppUser::DB::Item::User->Lookup( user_id => $userID );
    $self->_propertiesFromDBItem( $hrProperties, $dbItem );
}

sub _propertiesFromDBItem {
    my ( $self, $hrProperties, $dbItem ) = @_;

    $hrProperties->{user_id}    = $dbItem->user_id;
    $hrProperties->{email}      = $dbItem->email;
    $hrProperties->{first_name} = $dbItem->first_name;
    $hrProperties->{last_name}  = $dbItem->last_name;
    $hrProperties->{address_id} = $dbItem->address_id;
    $hrProperties->{phone1}     = $dbItem->phone1;
    $hrProperties->{phone2}     = $dbItem->phone2;
    $hrProperties->{phone3}     = $dbItem->phone3;
}

sub _initProperties {
    my ( $self, $props ) = @_;

    $self->{UserID} = Common::FormObject::Scalar->new( value => $props->{user_id}, readOnly => 1 );
    $self->{Email} = Common::FormObject::Scalar::EmailAddress->new( value => $props->{email}, required => 1 );
    $self->{FirstName} = Common::FormObject::Scalar::String->new( value => $props->{first_name}, required => 1 );
    $self->{LastName}  = Common::FormObject::Scalar::String->new( value => $props->{last_name},  required => 1 );
    $self->{AddressID} = Common::FormObject::Scalar->new( value => $props->{address_id} );
    $self->{Phone1} = Common::FormObject::Scalar::String->new( value => $props->{phone1}, required => 1 );
    $self->{Phone2} = Common::FormObject::Scalar::String->new( value => $props->{phone2} );
    $self->{Phone3} = Common::FormObject::Scalar::String->new( value => $props->{phone3} );
}

sub _initSubs {
    my ( $self, $props ) = @_;

    # subclasses
    #
    if ( $self->loadSubs() ) {
        if ( $props->{address_id} ) {
            $self->{Address} = AppUser::User::Address->new( addressID => $props->{address_id} );
        } else {
            $self->{Address} = AppUser::User::Address->new();
        }
    }
}

sub validate {
    my ($self) = @_;

    my $valid = $self->SUPER::validate();

    if ( !$self->Email() ) {
        $self->{Email}->setError(Common::FormObject::kErrFieldBlank);
        $valid = 0;
    } else {

        # is this email in use?
        #
        my $tmpUser = AppUser::DB::Item::User->Lookup( email => $self->Email() );

        # if this email is in use then we need to verify
        # it's ok to be using it here
        #
        if ( $tmpUser && $tmpUser->user_id ) {

            # is this a new user trying to use this email?
            # OR
            # is the owner of this email NOT the same as the user we're updating?
            #
            if ( !$self->UserID() || ( $self->UserID() != $tmpUser->user_id ) ) {

                # sorry, this email is in use
                #
                $self->{Email}->setError(Common::FormObject::kErrEmailNotAvailable);
                $valid = 0;
            }
        }
    }

    return $valid;
}

sub save {
    my ($self) = @_;

    # -------------------------------
    # Save myself FIRST
    # -------------------------------
    #
    assert( $self->UserID() );
    my $dbItem = AppUser::DB::Item::User->Lookup( user_id => $self->UserID() );

    $dbItem->email( $self->Email() );
    $dbItem->first_name( $self->FirstName() );
    $dbItem->last_name( $self->LastName() );
    $dbItem->phone1( $self->Phone1() );
    $dbItem->phone2( $self->Phone2() );
    $dbItem->phone3( $self->Phone3() );

    $dbItem->save();

    # -------------------------------
    # Save sub objects
    # -------------------------------
    #
    $self->{Address}->UserID( $dbItem->user_id );
    $self->{Address}->save();

    if ( !$dbItem->address_id ) {
        $dbItem->address_id( $self->{Address}->AddressID() );
        $dbItem->save();
    }

    # reload object
    #
    $self->_init( _dbItem => $dbItem );
}

###
1;    # Play nicely.
###