package BookPub::Import::Importer::Amazon::Version13;

use strict;

use lib '/app/tools/common/lib';
use Common::Country;

use lib '/app/tools/bookpub/lib';
use base 'BookPub::Import::Importer';

use Date::Calc qw( Add_Delta_YM );

sub _headerIdentifier { ( rTitle => 'title_18628' ) }

sub _fieldMap {
    {
        serviceProductID   => 'B',
        currencyCode       => 'U',
        dateBegin          => 'A',
        rFormat            => 'I',
        isbn               => 'E',
        rTitle             => 'F',
        rAuthor            => 'G',
        rImprint           => 'H',
        rUnits             => 'L',
        rSales             => 'J',
        rReturns           => 'K',
        rAdjustments       => 'N',
        rPurchasePrice     => 'O',
        rListPrice         => 'Q',
        rListPriceCurrency => 'R',
        rDiscount          => 'S',
        rRevenue           => 'T',
    };
}

sub priceType    { 'rrp' }
sub purchaseType { BookPub::DB::Item::Sale::kPurchaseTypeDownload }
sub productType  { BookPub::DB::Item::Sale::kProductTypeEBook }

sub countryCode {
    my $self = shift;

    my $filename = $self->filename();

    $self->fail("Country code missing from filename")
      unless ( $filename =~ /(?:_(\w{2})_|_(\w{2})\.)/ );

    my $cc = $1 || $2;

    my $obj = Common::Country->Get($cc);

    if ($obj) {
        return $obj->alpha2;
    } else {
        $self->fail("Invalid country code: $cc");
    }
}

sub rListPrice {
    my $price = shift->SUPER::rListPrice() || return;
    $price =~ s/,/./;

    return $price;
}

sub rRevenue {
    my $price = shift->SUPER::rRevenue() || return;
    $price =~ s/,/./;

    return $price;
}

sub _getDateBegin {
    my $self = shift;
    my $date = $self->_getByFieldName('dateBegin') || return;

    if ( $date && $date =~ /(\d{1,2})\/(\d{1,2})\/(\d{4})/ ) {
        my ( $year, $month, $day ) = Add_Delta_YM( $3, $2, $1, 0, -1 );

        return sprintf( "%04d-%02d-%02d", $year, $month, $day );
    }
}

sub deriveDateFormat { 1 }

sub _derivedDateMonthHint {
    my $date = shift->_getByFieldName('dateBegin') || return;

    if ( $date =~ /^01\/(\d+)/ ) {
        return $1;
    } elsif ( $date =~ /^(\d+)\/01/ ) {
        return $1;
    } elsif ( $date =~ /^\d{4}-(\d+)/ ) {
        return $1;
    }

    return;
}

sub _dateNormalization { 'month' }

sub _isValidSaleRecord {
    my $self = shift;

    return ( $self->rTitle || $self->rAuthor || $self->rIsbn13 ) && $self->dateBegin;
}

1;