package BookPub::Import::Importer::EBook::Version16;

use strict;

use Data::Dumper;
use POSIX;

use lib '/app/tools/common/lib';
use Common::Consts qw(%CURRENCY_TO_COUNTRY);

use lib '/app/tools/bookpub/lib';
use base 'BookPub::Import::Importer';

sub _headerIdentifier { ( rTitle => 'Title' ) }

sub productType { BookPub::DB::Item::Sale::kProductTypeEBook }
sub priceType   { 'rrp' }

sub _fieldMap {
    {
        purchaseType       => 'H',
        rTitle             => 'D',
        rIsbn13            => 'G',
        rImprint           => 'C',
        serviceProductID   => 'E',
        rUnits             => 'L',
        rListPrice         => 'N',
        rListPriceCurrency => 'M',
        rDiscount          => 'R',
        rRevenue           => 'S',
        currencyCode       => 'M',
        rModel             => 'I',
    };
}

sub countryCode {
    my $self = shift;

    $self->{countryCode} = $CURRENCY_TO_COUNTRY{ $self->sheetname };

    return $self->{countryCode};
}

sub purchaseType {
    my $self         = shift;
    my $purchaseType = $self->_getByFieldName('purchaseType');

    if ( lc($purchaseType) eq 'stl' ) {
        return BookPub::DB::Item::Sale::kPurchaseTypeLoan;
    } elsif ( lc($purchaseType) eq 'ebook' ) {
        return BookPub::DB::Item::Sale::kPurchaseTypeDownload;
    } elsif ( lc($purchaseType) =~ 'autopurch' ) {
        return BookPub::DB::Item::Sale::kPurchaseTypeDownload;
    } elsif ($purchaseType) {
        $self->fail("Unknown purchase type '$purchaseType'");
    }
}

sub _dateFormat { [ 'numerical', 'quarter', 'iso' ] }

sub _getDateBegin {
    my $self = shift;
    $self->{_dateBegin} || $self->_setDates;
    return $self->{_dateBegin};
}

sub _getDateEnd {
    my $self = shift;
    $self->{_dateEnd} || $self->_setDates;
    return $self->{_dateEnd};
}

sub _setDates {
    my $self     = shift;
    my $filename = $self->filename;
    my ( $begin, $end );

    if ( $filename =~ m/(\d{4}-\d{2}-\d{2})-(\d{4}-\d{2}-\d{2})/ ) {
        ( $begin, $end ) = ( $1, $2 );
    } elsif ( $filename =~ m/^(\d{4}_Q\d)_/ ) {
        my $get = $1;
        $get =~ s/_/ /;
        ( $begin, $end ) = $self->_getDates( date_begin => $get, type => 'quarter' );
    } elsif ( $filename =~ m/(\d{4}Q\d)/ ) {
        my $get = $1;
        $get =~ s/Q/ Q/;
        ( $begin, $end ) = $self->_getDates( date_begin => $get, type => 'quarter' );
    }

    unless ( $begin && $end ) {
        die "Unable to determine date range from filename $filename";
    }

    $self->{_dateBegin} = $begin;
    $self->{_dateEnd}   = $end;
}

sub isFree {
    my $self  = shift;
    my $price = $self->_getByFieldName('rListPrice');

    return $price eq 0 ? 'Y' : 'N';
}

sub units {
    my $self    = shift;
    my $revenue = $self->_getByFieldName('rRevenue');
    my $units   = $self->_getByFieldName('rUnits');

    # Need to round up any fractional units now.
    $units = ceil($units);

    if ( $revenue < 0 && $units > 0 ) {
        $units *= -1;
    }
    return $units;
}

sub _isValidSaleRecord {
    my $self    = shift;
    my $rIsbn13 = $self->_getByFieldName('rIsbn13');

    return $self->rTitle && ( $rIsbn13 || $self->rRevenue ) && $self->dateBegin;
}

1;