package BookPub::Import::Importer::EBook::Version2;

use strict;

use lib '/app/tools/common/lib';
use Common::Log;

use lib '/app/tools/bookpub/lib';
use BookPub::DB::Item::Sale;
use BookPub::Import::SaleRec;
use base 'BookPub::Import::Importer';

my %fieldMap = (
    date      => [ 10, 1 ],
    title     => 0,
    format    => 1,
    isbn13    => 2,
    units     => 3,
    listPrice => 4,
    discount  => 6,
    revenue   => 7,
);

#public methods

sub _importLines {
    my $self = shift;
    my %args = @_;

    my $lines = $args{lines};
    my ($dateStr) = $lines->[ $fieldMap{date}[0] ][ $fieldMap{date}[1] ] =~ /\s(\w+\s\d+)$/;
    my ( $dateBegin, $dateEnd ) = $self->_getDates( date_begin => $dateStr );
    unless ( $dateBegin and $dateEnd ) {
        $self->errstr('invalid date');
        Common::Log::Print("invalid date string: '$dateStr'");
        return undef;
    }

    my $saleCount;
    my %errorMsg  = ();
    my $lineStart = $fieldMap{date}[0] + 2;

    for ( my $i = $lineStart ; $i < scalar @$lines ; $i++ ) {
        my $units  = $lines->[$i][ $fieldMap{units} ];
        my $title  = $lines->[$i][ $fieldMap{title} ];
        my $isbn13 = $lines->[$i][ $fieldMap{isbn13} ];
        unless ( $units && ( $title || ( $isbn13 and $isbn13 =~ m/^\d+$/ ) ) ) {
            Common::Log::Print("skip line $i - title: '$title', isbn: '$isbn13'");
            next;
        }

        my $listPrice = $lines->[$i][ $fieldMap{listPrice} ];
        my $discount  = $lines->[$i][ $fieldMap{discount} ];
        my $revenue   = $lines->[$i][ $fieldMap{revenue} ];
        my $format    = $lines->[$i][ $fieldMap{format} ];

        my $formatType = $self->_parseFormat($format);
        unless ($formatType) {
            $self->errstr("unknown format: $format");
            unless ( $errorMsg{$format} ) {
                Common::Log::Print("unknown format '$format' ($i)");
                $errorMsg{$format} = 1;
            }
        }

        my $unitPrice = abs( $revenue / $units );

        my $saleRec = BookPub::Import::SaleRec->new();

        # defaults
        $saleRec->currencyCode('USD');
        $saleRec->countryCode('US');
        $saleRec->productType(BookPub::DB::Item::Sale::kProductTypeEBook);
        $saleRec->purchaseType(BookPub::DB::Item::Sale::kPurchaseTypeDownload);

        $saleRec->lineNum( $i + 1 );
        $saleRec->dateBegin($dateBegin);
        $saleRec->dateEnd($dateEnd);

        $saleRec->formatType( $formatType || BookPub::DB::Item::Sale::kFormatTypeAudioUnknown );
        $saleRec->units($units);
        $saleRec->listPrice($listPrice);
        $saleRec->discount( BookPub::Import::Importer::CalculateDiscount( $unitPrice, $listPrice ) );
        $saleRec->unitPrice($unitPrice);
        $saleRec->revenue($revenue);

        $saleRec->rFormat($format);
        $saleRec->rIsbn13($isbn13);
        $saleRec->rTitle($title);
        $saleRec->rUnits($units);
        $saleRec->rListPrice($listPrice);
        $saleRec->rDiscount($discount);
        $saleRec->rRevenue($revenue);

        #$args{dumper}($saleRec);
        $self->_insertSale( sale => $saleRec );
        $saleCount++;
    }

    return $saleCount;
}

###
1;    # Play nicely.
###