package BookPub::Import::Importer::PlayAway::Version1;

use strict;

use lib '/app/tools/common/lib';
use Common::Log;

use lib '/app/tools/bookpub/lib';
use BookPub::DB::Item::Sale;
use BookPub::Import::SaleRec;
use base 'BookPub::Import::Importer';

my %fieldMap = (
    date    => [ 2, 0 ],
    title   => 2,
    isbn13  => 3,
    units   => 4,
    revenue => 5,
);

#public methods

sub _importLines {
    my $self = shift;
    my %args = @_;

    my $lines = $args{lines};
    my $saleCount;

    my $dateStr = $lines->[ $fieldMap{date}[0] ][ $fieldMap{date}[1] ];
    my ( $dateBegin, $dateEnd ) = $self->_getDates( date_begin => $dateStr );
    unless ( $dateBegin and $dateEnd ) {
        $self->errstr('invalid date');
        Common::Log::Print("invalid date string: '$dateStr'");
        return undef;
    }

    for ( my $i = 0 ; $i < scalar @$lines ; $i++ ) {
        my $title  = $lines->[$i][ $fieldMap{title} ];
        my $isbn13 = $lines->[$i][ $fieldMap{isbn13} ];
        unless ( ( $title and $title !~ m/^MTR: Title/ and length($title) > 1 )
            or ( $isbn13 and $isbn13 =~ m/^\d+$/ ) ) {
            Common::Log::Print("skip line $i - title: '$title', isbn: '$isbn13'");
            next;
        }

        my $units   = $lines->[$i][ $fieldMap{units} ];
        my $revenue = $lines->[$i][ $fieldMap{revenue} ];

        my $saleRec = BookPub::Import::SaleRec->new();

        # defaults
        $saleRec->currencyCode('USD');
        $saleRec->countryCode('US');
        $saleRec->productType(BookPub::DB::Item::Sale::kProductTypeAudioBook);
        $saleRec->formatType(BookPub::DB::Item::Sale::kFormatTypeAudioUnknown);
        $saleRec->purchaseType(BookPub::DB::Item::Sale::kPurchaseTypePhysicalRetail);

        $saleRec->lineNum( $i + 1 );
        $saleRec->dateBegin($dateBegin);
        $saleRec->dateEnd($dateEnd);
        $saleRec->units($units);
        $saleRec->unitPrice( $units != 0 ? abs( $revenue / $units ) : 0 );
        $saleRec->revenue($revenue);

        $saleRec->rIsbn13($isbn13);
        $saleRec->rTitle($title);
        $saleRec->rUnits($units);
        $saleRec->rRevenue($revenue);

        #$args{dumper}($saleRec);
        $self->_insertSale( sale => $saleRec );
        $saleCount++;
    }

    return $saleCount;
}

###
1;    # Play nicely.
###