package BookPub::Import::Importer::SimplyAudio::Version1;

use strict;

use lib '/app/tools/common/lib';
use Common::Log;

use lib '/app/tools/bookpub/lib';
use BookPub::DB::Item::Sale;
use BookPub::Import::SaleRec;
use base 'BookPub::Import::Importer';

my %fieldMap = (
    dateSheet    => 0,
    dateCell     => 0,
    dataSheet    => 1,
    isbn13       => 0,
    title        => 1,
    listPrice    => 3,
    unitsALC     => 5,
    discountALC  => 6,
    revenueALC   => 7,
    unitsClub    => 8,
    discountClub => 9,
    revenueClub  => 10,
);

#public methods

sub _importLines {
    my $self = shift;
    my %args = @_;
    my $saleCount;

    # scan the summary sheet to find the date range for this file
    my $dateStr;
    foreach my $line ( @{ $args{sheets}[ $fieldMap{dateSheet} ] } ) {
        if ( $line->[ $fieldMap{dateCell} ] =~ m#\d+\W\d+\W\d+\s*-\s*\d+\W+\d+\W+\d+# ) {
            $dateStr = $line->[ $fieldMap{dateCell} ];
            last;
        }
    }
    unless ($dateStr) {
        $self->errstr('failed to find date');
        return undef;
    }

    my ( $dateBegin, $dateEnd ) = $self->_getDates( date_begin => $dateStr );
    unless ( $dateBegin and $dateEnd ) {
        $self->errstr('invalid date');
        Common::Log::Print("invalid date string: '$dateStr'");
        return undef;
    }

    my $lines = $args{sheets}[ $fieldMap{dataSheet} ];
    for ( my $i = 2 ; $i < scalar @$lines ; $i++ ) {
        my $title  = $lines->[$i][ $fieldMap{title} ];
        my $isbn13 = $lines->[$i][ $fieldMap{isbn13} ];
        unless ( $title or $isbn13 ) {
            Common::Log::Print("skip line $i - title: '$title', isbn: '$isbn13'");
            next;
        }
        my $subtitle;
        ( $title, $subtitle ) = BookPub::Import::Importer::ParseTitleAndSubtitle($title);

        my $listPrice    = $lines->[$i][ $fieldMap{listPrice} ];
        my $unitsALC     = $lines->[$i][ $fieldMap{unitsALC} ];
        my $discountALC  = $lines->[$i][ $fieldMap{discountALC} ];
        my $revenueALC   = $lines->[$i][ $fieldMap{revenueALC} ];
        my $unitsClub    = $lines->[$i][ $fieldMap{unitsClub} ];
        my $discountClub = $lines->[$i][ $fieldMap{discountClub} ];
        my $revenueClub  = $lines->[$i][ $fieldMap{revenueClub} ];

        my $saleRec = BookPub::Import::SaleRec->new();

        # defaults
        $saleRec->countryCode('US');
        $saleRec->currencyCode('USD');
        $saleRec->productType(BookPub::DB::Item::Sale::kProductTypeAudioBook);
        $saleRec->purchaseType(BookPub::DB::Item::Sale::kPurchaseTypeDownload);
        $saleRec->formatType(BookPub::DB::Item::Sale::kFormatTypeAudioMP3);
        $saleRec->lineNum( $i + 1 );

        $saleRec->dateBegin($dateBegin);
        $saleRec->dateEnd($dateEnd);

        $saleRec->listPrice($listPrice);
        $saleRec->rIsbn13($isbn13);
        $saleRec->rTitle($title);
        $saleRec->rSubtitle($subtitle) if $subtitle;
        $saleRec->rListPrice($listPrice);

        if ($unitsALC) {
            my $unitPrice = $revenueALC / $unitsALC;
            $saleRec->units($unitsALC);
            $saleRec->discount( BookPub::Import::Importer::CalculateDiscount( $unitPrice, $listPrice ) );
            $saleRec->unitPrice($unitPrice);
            $saleRec->revenue($revenueALC);

            $saleRec->rUnits($unitsALC);
            $saleRec->rDiscount($discountALC);
            $saleRec->rRevenue($revenueALC);

            #$args{dumper}($saleRec);
            $self->_insertSale( sale => $saleRec );
            $saleCount++;
        }

        if ($unitsClub) {
            my $unitPrice = $revenueClub / $unitsClub;
            $saleRec->units($unitsClub);
            $saleRec->discount( 1 - $unitPrice / $listPrice );
            $saleRec->unitPrice($unitPrice);
            $saleRec->revenue($revenueClub);

            $saleRec->rUnits($unitsClub);
            $saleRec->rDiscount($discountClub);
            $saleRec->rRevenue($revenueClub);

            #$args{dumper}($saleRec);
            $self->_insertSale( sale => $saleRec );
            $saleCount++;
        }
    }

    return $saleCount;
}

###
1;    # Play nicely.
###