package BookPub::Import::Importer::Storytel;

use strict;
use Date::Calc qw(Days_in_Month);

use lib '/app/tools/bookpub/lib';
use base 'BookPub::Import::Importer';

sub _headerIdentifier { ( rIsbn13 => 'ISBN' ) }

# map version num to the field order
sub _fieldMap {
    my $self = shift;

    my $sheet = lc( $self->sheetname ) || return {};
    return {} if ( $sheet =~ /(invoice)/i );

    my %fieldMap = (
        1 => {
            rAuthor                => 'A',
            rTitle                 => 'B',
            rIsbn13                => 'C',
            rUnits                 => 'D',
            rListPrice             => 'C1',
            rListPriceCurrency     => 'D1',
            rPurchasePrice         => 'E1',
            rPurchasePriceCurrency => 'F1',
            rDiscount              => 'C2',
            rRevenue               => 'F',
            currencyCode           => 'D1',
        },
    );

    return $fieldMap{ $self->_version() };
}

sub _useIsSaleRec              { 1 }
sub _autoParseTitleAndSubtitle { 1 }
sub priceType                  { 'rrp' }
sub purchaseType               { BookPub::DB::Item::Sale::kPurchaseTypeStream }
sub productType                { BookPub::DB::Item::Sale::kProductTypeAudioBook }

# RSD-3933
sub rServiceName  {
    return BookPub::Tracker::Service::GetDefaultServiceName( service_id => shift->serviceID );
}

sub countryCode {
    my $self  = shift;
    my $sheet = $self->sheetname;
    if ( $sheet =~ / (\w{2})$/i ) {
        return $1;
    } else {
        $self->fail( "Couldn't determine country code from " . $sheet );
    }
}

sub _getDateBegin {
    return shift->{_dateBegin};
}

sub _getDateEnd {
    return shift->{_dateEnd};
}

sub _preProcess {
    my $self = shift;
    my %args = @_;

    Log->info("Starting _preProcess");
    $self->SUPER::_preProcess(%args);

    my $sheetnum = 0;
    foreach my $sheet ( @{ $args{sheets} } ) {
        my $sheetname = $args{sheet_names}->[$sheetnum];
        $sheetnum++;

        if ( $sheetname =~ /invoice/i ) {
            foreach my $line (@$sheet) {

                # Since we're at the preProcess stage, it seems we have to reference rows by number.
                my $dateCell = $line->[4];
                if ( $dateCell =~ /(\d{4}-\d{2}-\d{2}) to (\d{4}-\d{2}-\d{2})/i ) {
                    $self->{_dateBegin} = $1;
                    $self->{_dateEnd}   = $2;
                    last;
                }
            }
        }
    }
}

sub _isSaleRec {
    my $self = shift;

    my $author = $self->_getByFieldName('rAuthor');
    my $units  = $self->_getByFieldName('rUnits');
    my $isbn13 = $self->_getByFieldName('rIsbn13');
    my $title  = $self->_getByFieldName('rTitle');

    # We're going to skip the subtotal line, which is blank for these fields
    if ( !$author && !$units && !$isbn13 && !$title ) {
        return 0;
    }

    return $self->SUPER::_isSaleRec();
}

1;