#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2011 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------
package BookPub::RDAS::Form::ProductMonitor::ProductMonitorAlert::Available;
use strict;
use warnings;

use lib '/app/tools/common/lib';
use lib '/app/tools/bookpub/lib';
use BookPub::RDAS::Form::ProductMonitor::ProductMonitorItem::Availability;
use BookPub::DB::Item::ProductMonitorAlertAvailable;
use Common::RSApp;
use Common::Util;
use Common::Assert;
use Common::FormObject;

use base 'BookPub::RDAS::Form::ProductMonitor::ProductMonitorAlert';

sub _getDBItemClass { 'BookPub::DB::Item::ProductMonitorAlertAvailable' }
sub _objectType     { 'available_too_soon' }

sub _propertiesFromDB {
    my ( $self, $hrProperties, $id ) = @_;

    my $parent = BookPub::DB::Item::ProductMonitorAlert->Lookup( product_monitor_alert_id => $id );
    $self->SUPER::_propertiesFromDBItem( $hrProperties, $parent );

    my $dbItem = $self->_getDBItemClass()->Lookup( product_monitor_alert_id => $id );
    $self->_propertiesFromDBItem( $hrProperties, $dbItem );
}

sub _propertiesFromDBItem {
    my ( $self, $hrProperties, $dbItem ) = @_;

    $hrProperties->{release_date} = $dbItem->catalog_release_date;
}

sub _initProperties {
    my ( $self, $props ) = @_;

    $self->SUPER::_initProperties($props);

    $self->{ReleaseDate} = $props->{release_date};

    return $self;
}

sub create {
    my $self      = shift;
    my $data      = shift || die "data required";
    my $serviceID = $data->{service_id} || die "Service ID required";
    my $productID = $data->{product_id} || die "Product ID required";
    my %args      = @_;

    Log->info(" -- Create an alert");

    my $productMonitorItem =
      new BookPub::RDAS::Form::ProductMonitor::ProductMonitorItem::Availability( productID => $productID, serviceID => $serviceID );
    assert( $productMonitorItem->ProductMonitorItemID );

    my $id = $self->SUPER::create( $data, %args, productMonitorItemID => $productMonitorItem->ProductMonitorItemID ) || return;

    my $dbItem = $self->_getDBItemClass()->Create(
        product_monitor_alert_id => $id,
        catalog_release_date     => $data->{release_date},
    );

    $dbItem->save();

    return $dbItem->product_monitor_alert_id;
}

sub set {
    my $self      = shift;
    my %args      = @_;
    my $serviceID = $args{serviceID} || die "Service ID required";
    my $productID = $args{productID} || die "Product ID required";
    my $available = $args{available} || die "Availability required";

    Log->notice(" + Begin Alert Process for early release");

    my $product = new BookPub::Catalog::Product::Book( productID => $productID );

    if ( $self->_isAlert( @_, releaseDate => $product->ReleaseDate ) ) {
        $self->_generateAlert( @_, releaseDate => $product->ReleaseDate );
    } else {
        Log->info(" No alert generated.  Resolving any open alerts");
        $self->_resolveAlerts( serviceID => $serviceID, productID => $productID, type => $self->_objectType() );
    }
}

sub _isAlert {
    my $self        = shift;
    my %args        = @_;
    my $serviceID   = $args{serviceID} || die "Service ID required";
    my $productID   = $args{productID} || die "Product ID required";
    my $available   = $args{available};
    my $releaseDate = $args{releaseDate};
    my $price       = $args{price} || 0;

    Log->info(" -- Determine if alert is required, release: $releaseDate, availabe: $available");

    unless ( defined($releaseDate) ) {
        Log->notice("*** No catalog release date found, ignoring alert ***");
        return;
    }

    my $today = Common::Date->today();
    if ( $releaseDate && $releaseDate gt $today && $available eq 'available' ) {
        Log->info( " ALERT: " . $releaseDate );
        return 1;
    }

    return;
}

sub _generateAlert {
    my $self        = shift;
    my %args        = @_;
    my $serviceID   = $args{serviceID} || die "Service ID required";
    my $productID   = $args{productID} || die "Product ID required";
    my $releaseDate = $args{releaseDate} || die "Release date required";

    Log->info(" --Start the alert generation process");

    if ( $self->_requireAlertUpdate( @_, releaseDate => $releaseDate ) ) {
        Log->info(" -- An alert update is required.");
        $self->_resolveAlerts( serviceID => $serviceID, productID => $productID, type => $self->_objectType() );
        $self->create( { service_id => $serviceID, product_id => $productID, release_date => $releaseDate } );
    } else {
        Log->info(" -- No alert update required");
    }

}

sub _requireAlertUpdate {
    my $self = shift;
    my %args = @_;

    my $serviceID = $args{serviceID} || die "Service ID required";
    my $productID = $args{productID} || die "Product ID required";
    my $releaseDate = $args{releaseDate};

    return $self->_getDBItemClass()->requireUpdate(
        service_id   => $serviceID,
        product_id   => $productID,
        release_date => $releaseDate
    );

}

###
1;    #
###