#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2009 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------
package BookPub::RDAS::Form::ProductMonitor::ProductMonitorItem;
use strict;
use warnings;
use Carp;

use lib '/app/tools/common/lib';
use lib '/app/tools/bookpub/lib';
use BookPub::DB::Item::ProductMonitorItem;
use BookPub::Catalog::Product::Book;
use Common::RSApp;
use Common::Util;
use Common::Assert;
use Common::FormObject;

use base 'Common::FormObject';

sub _init {
    my ( $self, %args ) = @_;

    $self->SUPER::_init(%args);

    my %properties;
    if ( $args{dbItem} ) {
        $self->_propertiesFromDBItem( \%properties, $args{dbItem} );
    } elsif ( $args{productMonitorItemID} ) {
        $self->_propertiesFromDB( \%properties, $args{productMonitorItemID} );
    } elsif ( $args{serviceID} && $args{productID} ) {
        $self->{_serviceID} = $args{serviceID};
        $self->{_productID} = $args{productID};

        $self->_propertiesFromServiceID( \%properties, $args{serviceID}, $args{productID} );
    } else {
        $self->_propertiesFromDefaults( \%properties );
    }

    $self->_initProperties( \%properties );

    return $self;
}

sub _proertiesFromServiceID { die "Must be overloaded" }

sub _propertiesFromDB {
    my ( $self, $hrProperties, $id ) = @_;

    my $dbItem = BookPub::DB::Item::ProductMonitorItem->Lookup( product_monitor_item_id => $id );

    $self->_propertiesFromDBItem( $hrProperties, $dbItem );
}

sub _propertiesFromDBItem {
    my ( $self, $hrProperties, $dbItem ) = @_;

    $hrProperties->{product_monitor_item_id} = $dbItem->product_monitor_item_id;
    $hrProperties->{product_id}              = $dbItem->product_id;
    $hrProperties->{service_id}              = $dbItem->service_id;
    $hrProperties->{last_verified}           = $dbItem->last_verified;
    $hrProperties->{status}                  = $dbItem->status;
    $hrProperties->{type}                    = $dbItem->type;
    $hrProperties->{date_created}            = $dbItem->date_created;
}

sub _propertiesFromDefaults {
    my ( $self, $hrProperties ) = @_;
}

sub _initProperties {
    my ( $self, $props ) = @_;

    $self->{ProductMonitorItemID} = $props->{product_monitor_item_id};
    $self->{PublisherID}          = $props->{product_id};
    $self->{ServiceID}            = $props->{service_id};
    $self->{Status}               = $props->{status};
    $self->{type}                 = $props->{type};

    $self->{CreatedDate}  = Common::FormObject::Scalar::DateTime->new( value => $props->{date_created},  readOnly => 1 );
    $self->{LastVerified} = Common::FormObject::Scalar::DateTime->new( value => $props->{last_verified}, readOnly => 1 );
}

sub _getDBItemClass { die "Must be overloaded" }

sub requiresUpdate {
    my $self = shift;
    my $data = shift || confess "data required";
    my %args = @_;

    my $productID = $args{productID} || $self->{_productID};
    my $serviceID = $args{serviceID} || $self->{_serviceID};

    assert($productID);
    assert($serviceID);

    return $self->_getDBItemClass()->RequiresUpdate( %$data, product_id => $productID, service_id => $serviceID );
}

sub create {
    my $self = shift;
    my $data = shift || die "data required";
    my %args = @_;

    my $productID = $args{productID} || $self->{_productID};
    my $serviceID = $args{serviceID} || $self->{_serviceID};

    assert($productID);
    assert($serviceID);

    # Mark the previous current as old
    $self->invalidate(%args);

    my $pmItem = BookPub::DB::Item::ProductMonitorItem->Create(
        status        => 'current',
        type          => $self->_objectType(),
        product_id    => $productID,
        service_id    => $serviceID,
        last_verified => Common::DB::Item::kDateTimeNow,
    );
    $pmItem->save();

    return $pmItem->product_monitor_item_id;
}

sub invalidate {
    my $self = shift;

    my %args = @_;

    my $productID = $args{productID} || $self->{_productID};
    my $serviceID = $args{serviceID} || $self->{_serviceID};

    assert($productID);
    assert($serviceID);

    my $product = new BookPub::Catalog::Product::Book( productID => $productID );

    if ( $product->isEBook() ) {
        BookPub::DB::Item::ProductMonitorItem->InvalidateOtherEbookProducts(
            service_id => $serviceID,
            product_id => $productID,
            book_id    => $product->BookID
        );
    }

    # Mark the previous current as old
    $self->_getDBItemClass()->InvalidateRecords( product_id => $productID, service_id => $serviceID );
}

sub updateTimestamp {
    my $self = shift;
    my %args = @_;

    my $productID = $args{productID} || $self->{_productID};
    my $serviceID = $args{serviceID} || $self->{_serviceID};

    assert($productID);
    assert($serviceID);

    $self->_getDBItemClass()->UpdateValidationDate( product_id => $productID, service_id => $serviceID );

}

sub LastUpdated {
    my $self      = shift;
    my %args      = @_;
    my $serviceID = $args{serviceID};

    return BookPub::DB::Item::ProductMonitorItem->LastUpdated( service_id => $serviceID );
}

###
1;    #
###