#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2011 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------
package BookPub::Sale::Feed::SaleFeedService;

use strict;
use warnings;

use Carp;

use lib '/app/tools/common/lib';
use lib '/app/tools/bookpub/lib';

use BookPub::DB::Item::SaleFeedFile;
use BookPub::DB::Item::SaleFeedService;
use BookPub::RDAS::Request::SaleFeedAuthCheck;
use BookPub::Sale::Feed::SaleFeedFileList;
use BookPub::Sale::Feed::SaleFeedHash;
use Common::RSApp;
use Common::Date;
use Common::Util;
use Common::Assert;
use Common::FormObject;

use base 'Common::FormObject';

sub _init {
    my ( $self, %args ) = @_;

    $self->SUPER::_init(%args);

    my %properties;
    if ( $args{dbItem} ) {
        $self->_propertiesFromDBItem( \%properties, $args{dbItem} );
    } elsif ( $args{saleFeedServiceID} ) {
        $self->_propertiesFromDB( \%properties, $args{saleFeedServiceID} );
    } elsif ( $args{saleFeedID} ) {
        $self->_propertiesFromSaleFeedID( \%properties, $args{saleFeedID} );
    } elsif ( $args{serviceID} ) {
        $self->{_serviceID} = $args{serviceID};

        $self->_propertiesFromServiceID( \%properties, $args{serviceID} );
    } else {
        $self->_propertiesFromDefaults( \%properties );
    }

    $self->_initProperties( \%properties );

    return $self;
}

sub _propertiesFromServiceID {
    my ( $self, $hrProperties, $id ) = @_;

    my $dbItem = BookPub::DB::Item::SaleFeedService->Lookup( service_id => $id );

    $self->_propertiesFromDBItem( $hrProperties, $dbItem );
}

sub _propertiesFromSaleFeedID {
    my ( $self, $hrProperties, $id ) = @_;

    my $dbItem = BookPub::DB::Item::SaleFeedService->LookupBySaleFeedID($id);

    $self->_propertiesFromDBItem( $hrProperties, $dbItem );
}

sub _propertiesFromDB {
    my ( $self, $hrProperties, $id ) = @_;

    my $dbItem = BookPub::DB::Item::SaleFeedService->Lookup( sale_feed_service_id => $id );

    $self->_propertiesFromDBItem( $hrProperties, $dbItem );
}

sub _propertiesFromDBItem {
    my ( $self, $hrProperties, $dbItem ) = @_;

    $hrProperties->{sale_feed_service_id} = $dbItem->sale_feed_service_id;
    $hrProperties->{service_id}           = $dbItem->service_id;
    $hrProperties->{verified}             = $dbItem->verified;
    $hrProperties->{username}             = $dbItem->username;
    $hrProperties->{password}             = $dbItem->password;
    $hrProperties->{start_date}           = $dbItem->start_date;
    $hrProperties->{country_code}         = $dbItem->country_code;
    $hrProperties->{date_created}         = $dbItem->date_created;
    $hrProperties->{date_modified}        = $dbItem->date_modified;
}

sub _propertiesFromDefaults {
    my ( $self, $hrProperties ) = @_;
}

sub _initProperties {
    my ( $self, $props ) = @_;

    $self->{SaleFeedServiceID} = $props->{sale_feed_service_id};
    $self->{ServiceID}         = $props->{service_id};
    $self->{Verified}          = $props->{verified};
    $self->{Username}          = $props->{username};
    $self->{Password}          = $props->{password};
    $self->{StartDate}         = Common::FormObject::Scalar::Date->new( value => $props->{start_date} );
    $self->{CountryCode}       = $props->{country_code};
    $self->{DateCreated}       = Common::FormObject::Scalar::Date->new( value => $props->{date_created} );
    $self->{DateModified}      = Common::FormObject::Scalar::Date->new( value => $props->{date_modified} );

    if ( $props->{sale_feed_service_id} ) {
        $self->{SaleFeedList} = BookPub::Sale::Feed::SaleFeedHash->new( saleFeedServiceID => $props->{sale_feed_service_id} );
    }
}

sub DownloadStartDate {
    my $self = shift;
    my %args = @_;

    assert( $self->{SaleFeedServiceID}, "uninitialized object: " . Dumper $self );

    die "Start date not set for sale feed"
      if ( !$self->StartDate || $self->StartDate eq '0000-00-00' );

    my $startDate = new Common::Date( $self->StartDate );

    my $lastMissed = BookPub::DB::Item::SaleFeedFile->lastMissedDate( sale_feed_service_id => $self->SaleFeedServiceID );
    my $lastMissedDate = new Common::Date($lastMissed) if ($lastMissed);
    my $firstDownload = BookPub::DB::Item::SaleFeedFile->getFirstDownloadDate( sale_feed_service_id => $self->SaleFeedServiceID );
    my $firstDownloadDate = new Common::Date($firstDownload) if ($firstDownload);
    my $lastDownload = BookPub::DB::Item::SaleFeedFile->getLastDownloadDate( sale_feed_service_id => $self->SaleFeedServiceID );
    my $lastDownloadDate = new Common::Date($lastDownload) if ($lastDownload);

    if ( $firstDownloadDate && $startDate < $firstDownloadDate ) {
        Log->notice(" Using start date ($startDate), first download date: $firstDownloadDate ");
        return "$startDate";
    } elsif ( $lastMissedDate && $startDate < $lastMissedDate ) {
        Log->notice(" Using last missed date ($lastMissedDate), start date: $startDate ");
        return "$lastMissedDate";
    } elsif ( $lastDownloadDate && $startDate < $lastDownloadDate ) {
        Log->notice(" No missing files.  Using last download date ($lastDownloadDate)");
        return $lastDownloadDate->addDays(1)->asString;
    } elsif ($lastMissed) {
        Log->notice(" Using start date ($startDate), last missed date: $lastMissedDate ");
        return "$startDate";
    } else {
        Log->notice(" Using start date ($startDate) because we couldn't determine last found");
        return "$startDate";
    }

    die;
}

sub save {
    my ($self) = @_;

    my $dbObj = $self->_saveSaleFeedService();
    $self->_init( dbItem => $dbObj );
}

sub _saveSaleFeedService {
    my ($self) = @_;

    my $dbObj;

    if ( $self->SaleFeedServiceID() ) {
        $dbObj = BookPub::DB::Item::SaleFeedService->Lookup( sale_feed_service_id => $self->SaleFeedServiceID() );
    }

    if ( !$dbObj ) {
        $dbObj = BookPub::DB::Item::SaleFeedService->Create();
    }

    $dbObj->username( $self->Username() );
    $dbObj->password( $self->Password() );
    $dbObj->start_date( $self->StartDate() );
    $dbObj->country_code( $self->CountryCode() );
    $dbObj->service_id( $self->ServiceID() );
    $dbObj->save();

    # Now we need to verify the credentials.
    # We need the sale_feed_service_id, so that's why we had to save first.
    #
    my $saleFeedServiceID = $dbObj->sale_feed_service_id;

    my $auth = BookPub::RDAS::Request::SaleFeedAuthCheck->GetRequestObject( $self->ServiceID(), saleFeedServiceID => $saleFeedServiceID );

    if ( $auth->run ) {
        $dbObj->verified(1);
    } else {
        $dbObj->verified(0);
    }

    $dbObj->save();

    return $dbObj;

}

###
1;    #
###