package BookPub::Tracker::Command::EditPeriod;
use strict;
use warnings;

use lib '/app/tools/common/lib';
use RSApache::Response::XSLT;
use Common::Assert;
use RSApache::Message;

use lib '/app/tools/bookpub/lib';
use BookPub::DB::Item::Period;
use BookPub::Tracker::Period;
use BookPub::Tracker::Command::Main;
use base 'BookPub::Command';

sub cmd      { return "edit_period"; }
sub area     { return "tracker"; }
sub pageName { return 'Edit Period Name'; }

use constant kTemplate => '/app/tools/bookpub/templates/tracker/edit_period.xsl';

sub execute {
    my ($self) = @_;

    # Give any inherited methods the first crack at this.
    # (This checks for login and basic access permissions).
    #
    my $response = $self->SUPER::execute();
    return $response if $response;

    my $page       = $self->getParam('page');
    my $redirect   = $self->getParam('redirect');
    my $periodID   = $self->getParam('period');
    my $periodName = $self->getParam('period_name');
    my $period     = BookPub::Tracker::Period->new( periodID => $periodID );
    assert($period);

    if ( 'update' eq $self->getParam('sub_cmd') && $periodName ) {

        # Limit period name change to current period
        assert( $periodID == 0, "Only current period can be updated" );

        # Now we need to make sure that the name is unique.
        my $periodWithSameName = BookPub::DB::Item::Period->Lookup( name => $periodName );
        if ( $periodWithSameName && $periodWithSameName->period_id != $periodID ) {
            $self->addMessageXML( type => 'error', code => 'invalid_name' );
        } else {
            $period->Name( $self->getParam('period_name') );
            $period->save();

            # Redirect back to the main page with a success message
            # unless a redirect was specified.
            #
            my $url;
            if ($redirect) {
                $url = $redirect;
            } else {
                my $successMessage = RSApache::Message->new( type => "success", code => 'period_edited' );
                my %showParams = (
                    period => $periodID,
                    page   => $page,
                    msg    => $successMessage->toString(),
                );
                my $command = BookPub::Tracker::Command::Main->new(%showParams);
                $url = $command->getRedirect();
            }

            return RSApache::Response::Redirect->new($url);
        }
    }

    $self->{xml}{Report}{Period} = $period;
    $response = RSApache::Response::XSLT->new( $self->{xml}, kTemplate );

    return $response;
}

1;