#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2009 RoyaltyShare, Inc.      All Rights Reserved
#---------------------------------------------------------------
package Job::HostClass;

use strict;
use lib '/app/tools/common/lib';
use Common::XMLObject;
use Common::Assert;

use lib '/app/tools/job/lib';
use Job::DB::Item::JobHostClass;

use base 'Common::FormObject';

sub _init {
    my ( $self, %args ) = @_;

    $self->SUPER::_init(%args);
    if ( defined $args{jobHostClassID} ) {
        return $self->_initFromID( $args{jobRunRuleID} );
    } elsif ( ref( $args{hash} ) ) {
        return $self->_initFromHashref( $args{hash} );
    } elsif ( $args{dbItem} ) {
        return $self->_initFromDBItem( $args{dbItem} );
    } else {
        return $self->_initFromDefaults();
    }

    return $self;
}

sub _initFromDefaults {
    my ($self) = @_;
    return $self->_initFromHashref( {} );
}

sub _initFromID {
    my ( $self, $id ) = @_;
    assert($id);

    return $self->_initFromDBItem( Job::DB::Item::JobHostClass->Lookup( job_host_class_id => $id ) );
}

sub _initFromDBItem {
    my ( $self, $dbItem ) = @_;

    $self->{_inDB} = 1;

    return $self->_initFromHashref( {
            job_host_class_id => $dbItem->job_host_class_id,
            hostname          => $dbItem->hostname,
            class             => $dbItem->class,
        }
    );
}

sub _initFromHashref {
    my ( $self, $hashref ) = @_;

    $self->{JobHostClassID} = Common::FormObject::Scalar->new( value => $hashref->{job_host_class_id} );

    $self->{Hostname} = Common::FormObject::Scalar::String->new( value => $hashref->{hostname}, required => 1 );
    $self->{Class}    = Common::FormObject::Scalar::String->new( value => $hashref->{class},    required => 1 );

    $self->{Delete} = Common::FormObject::Scalar::Boolean->new();

    return $self;
}

sub validate {
    my ($self) = @_;

    if ( $self->Delete() ) {
        return 1;
    }

    foreach my $field (qw(Hostname Class)) {
        if ( $self->$field() ) {
            $self->{_hasData} = 1;
        }
    }

    if ( $self->{_hasData} ) {
        my $valid = $self->SUPER::validate();

        return $valid;
    } else {
        return 1;
    }
}

sub save {
    my ($self) = @_;

    if ( $self->Delete() ) {
        $self->delete();
        return;
    }

    return unless $self->{_hasData};

    my $dbObj;
    if ( $self->JobHostClassID() ) {
        $dbObj = Job::DB::Item::JobHostClass->Lookup( job_host_class_id => $self->JobHostClassID() );
    } else {
        $dbObj = Job::DB::Item::JobHostClass->Create();
    }

    $dbObj->hostname( $self->Hostname() );
    $dbObj->class( $self->Class() );

    # save db item
    #
    $dbObj->save();

    # reload object
    #
    $self->_init( dbItem => $dbObj );

}

sub delete {
    my $self = shift;

    if ( $self->{_inDB} ) {
        my $myDBObj = Job::DB::Item::JobHostClass->Lookup( job_host_class_id => $self->JobHostClassID() );
        $myDBObj->delete();
    }
    return 1;
}

1;