#------------------------------------------------------------
# Copyright (C) 2008 RoyaltyShare, Inc.   All Rights Reserved
#------------------------------------------------------------
package Job::RunRule;

use Data::Dumper;

use strict;
use lib '/app/tools/common/lib';
use Common::XMLObject;
use Common::Assert;

use lib '/app/tools/job/lib';
use Job::DB::Item::JobRunRule;

use base 'Common::FormObject';

sub _init {
    my ( $self, %args ) = @_;

    $self->SUPER::_init(%args);
    if ( defined $args{jobRunRuleID} ) {
        return $self->_initFromID( $args{jobRunRuleID} );
    } elsif ( ref( $args{hash} ) ) {
        return $self->_initFromHashref( $args{hash} );
    } elsif ( $args{dbItem} ) {
        return $self->_initFromDBItem( $args{dbItem} );
    } else {
        return $self->_initFromDefaults();
    }

    return $self;
}

sub _initFromDefaults {
    my ($self) = @_;
    return $self->_initFromHashref( {} );
}

sub _initFromID {
    my ( $self, $id ) = @_;
    assert($id);

    return $self->_initFromDBItem( Job::DB::Item::JobRunRule->Lookup( job_run_rule_id => $id ) );
}

sub _initFromDBItem {
    my ( $self, $dbItem ) = @_;

    $self->{_inDB} = 1;

    return $self->_initFromHashref( {
            job_run_rule_id => $dbItem->job_run_rule_id,
            hostname        => $dbItem->hostname,
            client_id       => $dbItem->client_id,
            class           => $dbItem->class,
            subclass        => $dbItem->subclass,
            global_max      => $dbItem->global_max,
            local_max       => $dbItem->local_max,
            client_max      => $dbItem->client_max,
            load_balanced   => $dbItem->load_balanced,
        }
    );
}

sub _initFromHashref {
    my ( $self, $hashref ) = @_;

    # !!! There really is no reason to bless the ID into the scalar class...
    #
    $self->{JobRunRuleID} = Common::FormObject::Scalar->new( value => $hashref->{job_run_rule_id} );

    $self->{Hostname} = Common::FormObject::Scalar::String->new( value => $hashref->{hostname}, required => 1 );
    $self->{ClientID} = Common::FormObject::Scalar::Integer->new( value => $hashref->{client_id} );
    $self->{Class}    = Common::FormObject::Scalar::String->new( value => $hashref->{class} );
    $self->{Subclass} = Common::FormObject::Scalar::String->new( value => $hashref->{subclass} );
    $self->{GlobalMax} = Common::FormObject::Scalar::Integer->new( value => $hashref->{global_max} );
    $self->{LocalMax}  = Common::FormObject::Scalar::Integer->new( value => $hashref->{local_max} );
    $self->{ClientMax} = Common::FormObject::Scalar::Integer->new( value => $hashref->{client_max} );

    $self->{LoadBalanced} = Common::FormObject::Scalar::Boolean->new( value => $hashref->{load_balanced} );

    $self->{Delete} = Common::FormObject::Scalar::Boolean->new();

    return $self;
}

sub validate {
    my ($self) = @_;

    if ( $self->Delete() ) {
        return 1;
    }

    foreach my $field (qw(Hostname ClientID Class Subclass GlobalMax LocalMax)) {
        if ( $self->$field() ) {
            $self->{_hasData} = 1;
        }
    }

    if ( $self->{_hasData} ) {
        my $valid = $self->SUPER::validate();

        return $valid;
    } else {
        return 1;
    }
}

sub save {
    my ($self) = @_;

    if ( $self->Delete() ) {
        $self->delete();
        return;
    }

    return unless $self->{_hasData};

    my $dbObj;
    if ( $self->JobRunRuleID() ) {
        $dbObj = Job::DB::Item::JobRunRule->Lookup( job_run_rule_id => $self->JobRunRuleID() );
    } else {
        $dbObj = Job::DB::Item::JobRunRule->Create();
    }

    # set fields here
    #
    if ( $self->ClientID() ) {
        $dbObj->client_id( $self->ClientID() );
    } else {
        $dbObj->client_id(undef);
    }
    $dbObj->hostname( $self->Hostname() );
    $dbObj->class( $self->Class() );
    $dbObj->subclass( $self->Subclass() );

    if ( $self->LocalMax() ) {
        $dbObj->local_max( $self->LocalMax() );
    } else {
        $dbObj->local_max(undef);
    }

    if ( $self->GlobalMax() ) {
        $dbObj->global_max( $self->GlobalMax() );
    } else {
        $dbObj->global_max(undef);
    }

    if ( $self->ClientMax() ) {
        $dbObj->client_max( $self->ClientMax() );
    } else {
        $dbObj->client_max(undef);
    }

    $dbObj->load_balanced( $self->LoadBalanced() ? 1 : 0 );

    # save db item
    #
    $dbObj->save();

    # reload object
    #
    $self->_init( dbItem => $dbObj );

}

sub delete {
    my $self = shift;

    if ( $self->{_inDB} ) {
        my $myDBObj = Job::DB::Item::JobRunRule->Lookup( job_run_rule_id => $self->JobRunRuleID() );
        $myDBObj->delete();
    }
    return 1;
}

sub addException {
    my $self      = shift;
    my $exception = shift;

    assert( $exception && ref($exception) eq 'HASH', 'Exception hash required' );

    push( @{ $self->{Exceptions} }, $exception );
}

sub Exceptions { shift->{Exceptions} }

sub clearMaxedClientIDs {
    my ($self) = @_;

    $self->{MaxedClientIDs} = [];
}

sub addMaxedClientID {
    my ( $self, $clientID ) = @_;
    assert($clientID);

    push @{ $self->{MaxedClientIDs} }, $clientID;
}

sub MaxedClientIDs { shift->{MaxedClientIDs} }

sub logRule {
    my $self = shift;
    my $pre = shift || "Job Detail";

    my $hostname = $self->Hostname;
    my $clientID = $self->ClientID;
    my $class    = $self->Class;
    my $subclass = $self->Subclass;

    Common::Log::Debug(
        sprintf(
            "$pre => Host: %s, Client: %s, Class: %s, Subclass: %s",
            defined($hostname) ? $hostname : '<undef>',
            defined($clientID) ? $clientID : '<undef>',
            defined($class)    ? $class    : '<undef>',
            defined($subclass) ? $subclass : '<undef>',
        )
    );

}

1;