#------------------------------------------------------------
# Copyright (C) 2008 RoyaltyShare, Inc.   All Rights Reserved
#------------------------------------------------------------
package Job::SkipRule;

use strict;
use lib '/app/tools/common/lib';
use Common::XMLObject;
use Common::Assert;

use lib '/app/tools/job/lib';
use Job::DB::Item::JobSkipRule;

use base 'Common::FormObject';

sub _init {
    my ( $self, %args ) = @_;

    $self->SUPER::_init(%args);
    if ( defined $args{jobSkipRuleID} ) {
        return $self->_initFromID( $args{jobSkipRuleID} );
    } elsif ( ref( $args{hash} ) ) {
        return $self->_initFromHashref( $args{hash} );
    } elsif ( $args{dbItem} ) {
        return $self->_initFromDBItem( $args{dbItem} );
    } else {
        return $self->_initFromDefaults();
    }

    return $self;
}

sub _initFromDefaults {
    my ($self) = @_;
    return $self->_initFromHashref( {} );
}

sub _initFromID {
    my ( $self, $id ) = @_;
    assert($id);

    return $self->_initFromDBItem( Job::DB::Item::JobSkipRule->Lookup( job_skip_rule_id => $id ) );
}

sub _initFromDBItem {
    my ( $self, $dbItem ) = @_;

    $self->{_inDB} = 1;

    return $self->_initFromHashref( {
            job_skip_rule_id => $dbItem->job_skip_rule_id,
            client_id        => $dbItem->client_id,
            class            => $dbItem->class,
            subclass         => $dbItem->subclass,
        }
    );
}

sub _initFromHashref {
    my ( $self, $hashref ) = @_;

    # !!! There really is no reason to bless the ID into the scalar class...
    #
    $self->{JobSkipRuleID} = Common::FormObject::Scalar->new( value => $hashref->{job_skip_rule_id} );

    $self->{ClientID} = Common::FormObject::Scalar::Integer->new( value => $hashref->{client_id} );
    $self->{Class}    = Common::FormObject::Scalar::String->new( value => $hashref->{class} );
    $self->{Subclass} = Common::FormObject::Scalar::String->new( value => $hashref->{subclass} );

    $self->{Delete} = Common::FormObject::Scalar::Boolean->new();

    return $self;
}

sub validate {
    my ($self) = @_;

    if ( $self->Delete() ) {
        return 1;
    }

    foreach my $field (qw(ClientID Class Subclass)) {
        if ( $self->$field() ) {
            $self->{_hasData} = 1;
        }
    }

    if ( $self->{_hasData} ) {
        my $valid = $self->SUPER::validate();

        return $valid;
    } else {
        return 1;
    }
}

sub save {
    my ($self) = @_;

    if ( $self->Delete() ) {
        $self->delete();
        return;
    }

    return unless $self->{_hasData};

    my $dbObj;
    if ( $self->JobSkipRuleID() ) {
        $dbObj = Job::DB::Item::JobSkipRule->Lookup( job_skip_rule_id => $self->JobSkipRuleID() );
    } else {
        $dbObj = Job::DB::Item::JobSkipRule->Create();
    }

    # set fields here
    #
    if ( $self->ClientID() ) {
        $dbObj->client_id( $self->ClientID() );
    } else {
        $dbObj->client_id(undef);
    }
    $dbObj->class( $self->Class() );
    $dbObj->subclass( $self->Subclass() );

    # save db item
    #
    $dbObj->save();

    # reload object
    #
    $self->_init( dbItem => $dbObj );

}

sub delete {
    my $self = shift;

    if ( $self->{_inDB} ) {
        my $myDBObj = Job::DB::Item::JobSkipRule->Lookup( job_skip_rule_id => $self->JobSkipRuleID() );
        $myDBObj->delete();
    }
    return 1;
}

1;