#------------------------------------------------------------
# Copyright (C) 2006 RoyaltyShare, Inc.   All Rights Reserved
# $Id$
#------------------------------------------------------------
package Raptor::SaleReport::LabelsSummaryReport;
use strict;
use warnings;

use lib '/app/tools/common/lib';
use RSApache::Response::XSLT;
use Common::Assert;
use Common::XMLObject;
use Common::RSApp;
use Common::Client;

use lib '/app/tools/data_classes/lib';
use Client::Service;
use Client::Label;
use Period::QuarterPeriod;
use Period::MonthPeriod;
use Period::YearPeriod;

use lib '/app/tools/raptor/lib';
use Raptor::SaleReport::BaseReport;
use SaleReport::ReportLib;    # for pie charts

use lib '/app/tools/stats/lib';
use Stats::Sales;

use constant kDisplayLimit => 200;

use base 'Raptor::SaleReport::BaseReport';

sub _init {
    my ( $self, %args ) = @_;

    $self->SUPER::_init(%args);

    my $stats_obj = $self->{_stats};
    return $self unless ($stats_obj);

    # --------------------------
    # grand total data
    # --------------------------
    my $total_metric = {};
    $total_metric              = $stats_obj->GetTotalMetric( %{ $self->{_statParams} } );
    $self->{Totals}->{Revenue} = Common::Client::Current()->Locale()->formatMoney( $total_metric->Revenue );
    $self->{Totals}->{Units}   = Common::Client::Current()->Locale()->formatNumber( $total_metric->Units );

    # --------------------------
    # build the pie and table data at the same time
    # --------------------------
    my $pie_count      = 0;
    my $base_image_url = '';
    my $pie_data       = {};
    my $table_data     = [];
    my $data_labels    = [];

    my $label_info    = Client::Label::GetAllLabels();
    my $labels        = $stats_obj->GetTopRanking( category => 'label' );
    my $labels_prev   = $stats_obj->GetTopRanking( category => 'label', prev_rank => 1 );
    my $top_services  = $stats_obj->GetTopRanking( category => 'service', ignore => 'label', limit => 5 );
    my $service_names = Client::Service->GetAllServiceNames();
    my @metric_list   = map { $_->ID } @$top_services;
    my $total_revenue = $args{labelID} ? Raptor::SaleReport::BaseReport::_sumRevenue($labels) : $total_metric->Revenue;

    my $c             = 1;
    my $other_revenue = 0;
    my %seen          = ();

    foreach my $label_ref (@$labels) {
        my $label_id = $label_ref->ID;

        if ( $c++ <= 10 and ( $total_revenue and $label_ref->Revenue / $total_revenue ) >= 0.01 ) {
            next if ( $label_ref->Revenue <= 0 );

            push @{ $pie_data->{labels} }, $label_info->{$label_id}{label_name};
            push @{ $pie_data->{ids} },    $label_id;
            push @{ $pie_data->{data} },   $label_ref->Revenue;
        } else {
            $other_revenue += $label_ref->Revenue;
        }

        my $row_data = {
            Rank     => $label_ref->Rank,
            Units    => Common::Client::Current()->Locale()->formatNumber( $label_ref->Units ),
            Revenue  => Common::Client::Current()->Locale()->formatMoney( $label_ref->Revenue ),
            PrevRank => $labels_prev->{$label_id},
        };

        $row_data->{ProductInfo}->{LabelName} = $label_info->{$label_id}{label_name};
        $row_data->{ProductInfo}->{LabelID}   = $label_id;
        $seen{$label_id}                      = 1;

        my @extra_data     = ();
        my $summary_metric = $stats_obj->GetSummaryMetric(
            category    => 'service',
            metric_list => \@metric_list,
            label_id    => $label_id,
        );

        foreach my $service_ref (@$top_services) {
            push @extra_data, $summary_metric->{ $service_ref->ID } || 0;
            push @$data_labels, $service_names->{ $service_ref->ID };
        }
        $row_data->{Data} = \@extra_data;

        push @$table_data, $row_data;
    }

    # add any labels not yet seen above
    foreach my $label_id ( sort { lc( $label_info->{$a}->{label_name} ) cmp lc( $label_info->{$b}->{label_name} ) } keys %$label_info ) {
        next if ( $seen{$label_id} );
        my @place_holders = ();
        map { push @place_holders, 0 } @$top_services;
        push @$table_data,
          {
            Units       => 0,
            Revenue     => 0,
            Rank        => '--',
            PrevRank    => '--',
            ProductInfo => {
                LabelName => $label_info->{$label_id}{label_name},
                LabelID   => $label_id
            },
            Data => \@place_holders,
          };
    }

    # Limit label display to 200 records. case 14701.
    my @tmp;
    for ( my $i = 0 ; $i < @$table_data ; $i++ ) {
        push( @tmp, $table_data->[$i] ) if ( $i < kDisplayLimit );
    }
    $table_data = \@tmp;

    my $xml_href = {};

    if ( $pie_data && defined $pie_data->{data} ) {
        if ($other_revenue) {
            push @{ $pie_data->{labels} }, 'Other';
            push @{ $pie_data->{data} },   $other_revenue;
        }

        my $image_link = $args{commandObj}->getParamsAsString( c => 1, label => 1 );
        $image_link .= '&' if ( length $image_link );
        $image_link .= 'c=m&label=';

        #        my $q = $self->GetPartialQueryString(view => 1, label => 1);
        #        substr($q,0,0) = '&' if $q;
        #        my $image_link = "view=m$q&label=";
        my $pie_href = GetPieChart(
            labels         => $pie_data->{labels},
            data           => $pie_data->{data},
            image_map_link => $image_link,
            label_ids      => $pie_data->{ids},
        );
        $xml_href->{PieName}        = 'label_revenue';
        $xml_href->{ImageSrc}       = $pie_href->{image_src};
        $xml_href->{ImageMap}       = $pie_href->{image_map};
        $xml_href->{Legend}->{Item} = $pie_href->{legend_xml};
    }

    my @tables = ();

    if ( $table_data && ( scalar @$table_data >= 1 ) ) {
        my $table_href = CreateTableXML( data => $table_data, labels => $data_labels );

        if ($table_href) {
            $table_href->{TableName} = 'top_labels';
            push @tables, $table_href;
        }
    }

    $self->{Pies}->{Pie} = [$xml_href] if ( keys %$xml_href );
    $self->{Tables}->{Table} = \@tables;

    return $self;
}

sub _initStatsParams {
    my ( $self, %args ) = @_;

    my $offset = $self->_getPageOffset( $args{pageNum} );

    # This hash of parameters gets re-used several times.
    # !!! Why, I don't really understand.  That needs to be fixed.
    #
    my %params = (
        period_id    => $self->{_period}->PeriodID,
        period_type  => $self->{_period}->PeriodType,
        client_id    => Common::RSApp::GetClientID(),
        label_id     => $args{labelID},
        country_code => $args{countryCode},

        #product_type => $args{productType},
        offset => $offset,
    );

    return \%params;
}

1;