#------------------------------------------------------------
# Copyright (C) 2006 RoyaltyShare, Inc.   All Rights Reserved
# $Id$
#------------------------------------------------------------
package Raptor::Tracker::Command::SplitFileDelete;
use strict;
use warnings;

use lib '/app/tools/common/lib';
use RSApache::Response::XSLT;
use Common::Assert;

use lib '/app/tools/rps/lib';
use RPS::File::File;
use RPS::Message;
use lib '/app/tools/raptor/lib';
use Raptor::Tracker::Command::Main;

use Raptor::Command;
use base 'Raptor::Tracker::Command::Base';

sub cmd  { return "delete_split"; }
sub area { return "tracker"; }

use constant kTemplate => '/app/tools/raptor/templates/tracker.xsl';

sub execute {
    my ($self) = @_;

    # Give any inherited methods the first crack at this.
    # (This checks for login and basic access permissions).
    #
    my $response = $self->SUPER::execute();
    return $response if $response;

    my $period      = new Period::RoyaltyPeriod();
    my $periodParam = $self->getParam('period');
    if ( !$periodParam ) {
        $period->LoadCurrent();
    } else {
        $period->Load( period_id => $periodParam );
    }

    my $fileID = $self->getParam('file');
    my $file = RPS::File::File->new( file_id => $fileID );

    # Split files can be deleted (by RS Admins) as long as they don't have a related file in a closed period.
    my $relatedFileClosed;

    # If all goes well, we'll delete the related files later so might as well store the IDs.
    my @relatedFileIDs;

    # First, check the kids.
    my $childObj = $file->GetChildObj;
    while ($childObj) {
        if ( $childObj->PeriodID != 0 ) {
            $relatedFileClosed = 1;
            last;
        } else {
            push @relatedFileIDs, $childObj->FileID;
            $childObj = $childObj->GetChildObj;
        }
    }

    # Now check the parents (if we need to)
    if ( !$relatedFileClosed ) {
        my $parentObj = $file->GetParentObj;
        while ($parentObj) {
            if ( $parentObj->PeriodID != 0 ) {
                $relatedFileClosed = 1;
                last;
            } else {
                push @relatedFileIDs, $parentObj->FileID;
                $parentObj = $parentObj->GetParentObj;
            }
        }
    }

    if ( $file && $file->FileStatus != File::File::STATUS_CLOSED() ) {
        my $msg;

        # If this split file has a related file in a closed period, don't allow it to be deleted.
        if ($relatedFileClosed) {
            $msg = RPS::Message->new( type => 'error', code => 'file_not_deleted' );
        } elsif ( $file->Delete() ) {
            $self->deleteRelatedFiles(@relatedFileIDs);
            $msg = RPS::Message->new( type => 'success', code => 'file_deleted' );
        } else {
            $msg = RPS::Message->new( type => 'error', code => 'file_not_deleted' );
        }

        my $command = Raptor::Tracker::Command::Main->new( msg => $msg->toString() );
        return RSApache::Response::Redirect->new( $command->getRedirect() );
    }

    $self->doFileListing($period);
    $self->{xml}{Report}{Period} = $period->GetObjectXML();
    $self->setExceptionsFileStatus();

    $response = RSApache::Response::XSLT->new( $self->{xml}, kTemplate );

    return $response;
}

sub deleteRelatedFiles {
    my ($self, @relatedFileIDs) = @_;
    foreach my $fileID (@relatedFileIDs) {
        my $file = RPS::File::File->new( file_id => $fileID );
        $file->Delete();
    }
}

1;