#------------------------------------------------------------
# Copyright (C) 2006 RoyaltyShare, Inc.   All Rights Reserved
# $Id$
#------------------------------------------------------------
package RPS::Alert;

use strict;
use warnings;

use lib '/app/tools/common/lib';
use Common::FormObject;
use base 'Common::FormObject';

use lib '/app/tools/rps/lib';
use RPS::DB::Item::Alert;

# !!! Provide a 'static' method to get the current, active Alert
#
sub GetCurrentAlert {
    my $currentAlert = RPS::DB::Item::Alert->GetCurrentAlert();
    if ($currentAlert) {
        return RPS::Alert->new( _dbItem => $currentAlert );
    } else {
        return RPS::Alert->new();
    }
}

sub _init {
    my ( $self, %args ) = @_;

    $self->SUPER::_init(%args);

    my %properties;
    if ( $args{_dbItem} ) {
        $self->_propertiesFromDBItem( \%properties, $args{_dbItem} );
    } elsif ( $args{alertID} ) {
        $self->_propertiesFromDB( \%properties, $args{alertID} );
    } else {
        $self->_propertiesFromDefaults( \%properties );
    }

    my $rval = $self->_initProperties( \%properties );

    return $rval;
}

sub _propertiesFromDB {
    my ( $self, $hrProperties, $alertID ) = @_;

    my $dbItem = RPS::DB::Item::Alert->Lookup( alert_id => $alertID );
    $self->_propertiesFromDBItem( $hrProperties, $dbItem );
}

sub _propertiesFromDBItem {
    my ( $self, $hrProperties, $dbItem ) = @_;

    $hrProperties->{alert_id}    = $dbItem->alert_id;
    $hrProperties->{message}     = $dbItem->message;
    $hrProperties->{alert_level} = $dbItem->alert_level;

    $hrProperties->{date_created}  = $dbItem->date_created;
    $hrProperties->{date_modified} = $dbItem->date_modified;
}

sub _propertiesFromDefaults {
    my ( $self, $hrProperties ) = @_;
    $hrProperties->{alert_level} = RPS::DB::Item::Alert::kAlertLevelInfo;
}

sub _initProperties {
    my ( $self, $props ) = @_;

    $self->{AlertID} = Common::FormObject::Scalar::Integer->new( value => $props->{alert_id}, readOnly => 1 );
    $self->{Message} = Common::FormObject::Scalar::String->new( value => $props->{message} );
    $self->{AlertLevel} = Common::FormObject::Scalar::Integer->new( value => $props->{alert_level} );

    $self->{CreatedDate}  = Common::FormObject::Scalar::DateTime->new( value => $props->{date_created},  readOnly => 1 );
    $self->{ModifiedDate} = Common::FormObject::Scalar::DateTime->new( value => $props->{date_modified}, readOnly => 1 );

    return $self;
}

sub save {
    my ($self) = @_;

    my $dbObj;
    if ( $self->AlertID() ) {
        $dbObj = RPS::DB::Item::Alert->Lookup( alert_id => $self->AlertID() );
    } else {
        $dbObj = RPS::DB::Item::Alert->Create();
    }

    $dbObj->message( $self->Message() );
    $dbObj->alert_level( $self->AlertLevel() );

    $dbObj->save();
    $self->_init( _dbItem => $dbObj );

    return 1;
}

sub delete {
    my ($self) = @_;

    my $dbItem;
    if ( $self->AlertID() ) {
        $dbItem = RPS::DB::Item::Alert->Lookup( alert_id => $self->AlertID() );
    }
    if ($dbItem) {
        $dbItem->delete();
    }

    return 1;
}

1;