#------------------------------------------------------------
# Copyright (C) 2006 RoyaltyShare, Inc.   All Rights Reserved
# $Id$
#------------------------------------------------------------
package RPS::ArtistContract::ArtistContractLicenseIncome;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::DB::Item::ArtistContractLicenseIncome;
use RPS::DB::Item::LicenseIncome;
use RPS::DB::Item::LicenseIncomeType;
use Common::FormObject;
use base 'Common::FormObject';

sub _init {
    my ( $self, %args ) = @_;

    $self->SUPER::_init(%args);

    my %properties;
    if ( $args{_dbItem} ) {
        $self->_propertiesFromDBItem( \%properties, $args{_dbItem} );
    } elsif ( $args{artistContractLicenseIncomeID} ) {
        $self->_propertiesFromDB( \%properties, $args{artistContractLicenseIncomeID} );
    } elsif ( $args{artistContractID} ) {
        $self->_propertiesFromDefaults( \%properties, $args{artistContractID} );
    } else {

        # we need something!
        confess("we need some init parameter for ArtistContractLicenseIncome.");
    }

    $self->_initProperties( \%properties );

    return $self;
}

sub _propertiesFromDB {
    my ( $self, $hrProperties, $id ) = @_;

    my $dbItem = RPS::DB::Item::ArtistContractLicenseIncome->Lookup( artist_contract_license_income_id => $id );
    $self->_propertiesFromDBItem( $hrProperties, $dbItem );
}

sub _propertiesFromDBItem {
    my ( $self, $hrProperties, $dbItem ) = @_;

    $self->{_inDB} = 1;

    $hrProperties->{artist_contract_license_income_id} = $dbItem->artist_contract_license_income_id;
    $hrProperties->{artist_contract_id}                = $dbItem->artist_contract_id;
    $hrProperties->{license_income_type_id}            = $dbItem->license_income_type_id;
    $hrProperties->{percent}                           = $dbItem->percent;
    $hrProperties->{inactive}                          = $dbItem->inactive;
}

sub _initProperties {
    my ( $self, $props ) = @_;

    $self->{ArtistContractLicenseIncomeID} =
      Common::FormObject::Scalar->new( value => $props->{artist_contract_license_income_id}, readOnly => 1 );
    $self->{ArtistContractID} = Common::FormObject::Scalar->new( value => $props->{artist_contract_id}, required => 1 );
    $self->{LicenseIncomeTypeID} = Common::FormObject::Scalar->new( value => $props->{license_income_type_id} );
    $self->{Percent} = Common::FormObject::Scalar::Percent->new( value => $props->{percent}, required => 1 );
    $self->{Inactive} = Common::FormObject::Scalar::Boolean->new( value => $props->{inactive} );

    # We need to fetch the license income name, given the id
    #
    my $licenseIncomeType;
    if ( $props->{license_income_type_id} ) {
        my $dbItem = RPS::DB::Item::LicenseIncomeType->Lookup( license_income_type_id => $props->{license_income_type_id} );
        if ($dbItem) {
            $licenseIncomeType = $dbItem->name;
        }
    }
    $self->{LicenseIncomeType} = Common::FormObject::Scalar::String->new( value => $licenseIncomeType );
    $self->{NewLicenseIncomeType} = Common::FormObject::Scalar::String->new( skipXML => 1 );

    # for deleting
    $self->{Delete} = Common::FormObject::Scalar->new();
}

sub _initSubs {
    my ( $self, $dbItem ) = @_;
}

sub _propertiesFromDefaults {
    my ( $self, $hrProperties, $contractID ) = @_;

    $hrProperties->{artist_contract_id} = $contractID;
}

sub validate {
    my ($self) = @_;

    if ( $self->Delete() || $self->Inactive() ) {
        return 1;
    }

    my $valid = 1;

    if ( $self->NewLicenseIncomeType() && $self->LicenseIncomeTypeID() ) {
        $valid = 0;
        $self->{LicenseIncomeTypeID}->setError(Common::FormObject::kErrFieldInvalid);
        $self->{NewLicenseIncomeType}->skipXML(0);
    }

    # was something entered?
    #
    if ( $self->Percent() || $self->LicenseIncomeTypeID() || $self->NewLicenseIncomeType() ) {
        $valid = $self->SUPER::validate();

        if ( !$self->LicenseIncomeTypeID() && !$self->NewLicenseIncomeType() ) {
            $self->{LicenseIncomeTypeID}->setError(Common::FormObject::kErrFieldBlank);
            $valid = 0;
        }
        if ( $self->Percent() <= 0 ) {
            $self->{Percent}->setError(Common::FormObject::kErrFieldInvalid);
            $valid = 0;
        }
        # We already have this item
        if ( $self->NewLicenseIncomeType && RPS::DB::Item::LicenseIncomeType->Lookup( name => $self->NewLicenseIncomeType ) ) {
            $self->{NewLicenseIncomeType}->setError(Common::FormObject::kErrDuplicate);
            $valid = 0;
        }
    }
    return $valid;
}

sub save {
    my ($self) = @_;

    if ( $self->Delete() ) {
        $self->delete();
        return;
    }

    # -------------------------------
    # Save or create the license income name
    # -------------------------------
    #
    my $licenseIncomeTypeObj;
    if ( $self->LicenseIncomeTypeID() ) {
        $licenseIncomeTypeObj = RPS::DB::Item::LicenseIncomeType->Lookup( license_income_type_id => $self->LicenseIncomeTypeID() );
    } elsif ( $self->NewLicenseIncomeType() ) {

        # Create a new license income name.
        $licenseIncomeTypeObj = RPS::DB::Item::LicenseIncomeType->Create( name => $self->NewLicenseIncomeType() );
        $licenseIncomeTypeObj->save();
    }

    my $dbObj;
    my $oldPercent;
    if ( $self->ArtistContractLicenseIncomeID() ) {
        $dbObj =
          RPS::DB::Item::ArtistContractLicenseIncome->Lookup( artist_contract_license_income_id => $self->ArtistContractLicenseIncomeID() );
        $oldPercent = $dbObj->percent();
    } else {
        $dbObj = RPS::DB::Item::ArtistContractLicenseIncome->Create();
    }

    # set fields here
    #
    $dbObj->artist_contract_id( $self->ArtistContractID() );
    $dbObj->license_income_type_id( $licenseIncomeTypeObj->license_income_type_id() );
    $dbObj->percent( $self->Percent() );

    # save db item
    #
    $dbObj->save();

    ## Do we still need to do this?
    # reload object
    #
    $self->_init( _dbItem => $dbObj );

}

sub delete {
    my $self = shift;

    my $dbItem =
      RPS::DB::Item::ArtistContractLicenseIncome->Lookup( artist_contract_license_income_id => $self->ArtistContractLicenseIncomeID() );
    $dbItem->inactive(1);
    $dbItem->save();
}

###
1;    #
###