#------------------------------------------------------------
# Copyright (C) 2006 RoyaltyShare, Inc.   All Rights Reserved
# $Id$
#------------------------------------------------------------
package RPS::ArtistContract::UnitEscalationList;

use strict;
use warnings;
use Data::Dumper;

use lib '/app/tools/rps/lib';
use RPS::ArtistContract::UnitEscalation;
use RPS::DB::Item::ArtistContractUnitEscalation;

use Common::FormObject;
use base 'Common::FormObject';

sub _init {
    my ( $self, %args ) = @_;

    $self->SUPER::_init(%args);

    $self->{UnitEscalation} = [];

    if ( $args{contractID} && $args{contractMode} ) {
        $self->{_contractID}   = $args{contractID};
        $self->{_contractMode} = $args{contractMode};

        # jpk - I am relying on this list coming back sorted by units.
        #
        my $collection = RPS::DB::Item::ArtistContractUnitEscalation->GetByContractID( $args{contractID}, $args{contractMode} );
        while ( $collection->hasNext() ) {
            my $obj = $collection->next();
            push @{ $self->{UnitEscalation} }, RPS::ArtistContract::UnitEscalation->new( _dbItem => $obj );
        }
    }

    return $self;
}

sub validate {
    my ($self) = @_;

    my $valid  = $self->SUPER::validate();
    my %unique = ();
    foreach my $item ( @{ $self->{UnitEscalation} } ) {
        next if ( !defined $item || $item->Delete() );

        if ( defined $item->Units() ) {
            if ( $unique{ $item->Units() } ) {
                $self->setError(Common::FormObject::kErrDuplicate);
                $valid = 0;
            } else {
                $unique{ $item->Units() } = 1;
            }
        }

        if ( !$item->validate() ) {
            $valid = 0;
        }
    }

    return $valid;
}

sub save {
    my ( $self, %args ) = @_;

    foreach my $item ( @{ $self->{UnitEscalation} } ) {
        if ( $item->Amount() && $item->Units() ) {
            $item->save();
        }
    }
}

sub _listProperties {
    return { UnitEscalation => 1 };
}

# This is the special sort of list accessor.
#
sub UnitEscalation {
    my ( $self, $index, $methodAddressList, $newValue ) = @_;

    if ( 0 == scalar @$methodAddressList ) {
        if ( defined $newValue ) {
            $self->{UnitEscalation}[$index] = $newValue;
        }
        return 1;
    }

    # May need to dynamically add objects to the list...
    #
    if ( !defined $self->{UnitEscalation}[$index] ) {
        $self->{UnitEscalation}[$index] =
          RPS::ArtistContract::UnitEscalation->new( contractID => $self->{_contractID}, contractMode => $self->{_contractMode} );
    }

    return $self->{UnitEscalation}[$index]->_accessProperty( $methodAddressList, $newValue );
}

sub getList {
    my ($self) = @_;

    return $self->{UnitEscalation};
}

###
1;    #
###