#------------------------------------------------------------
# Copyright (C) 2006 RoyaltyShare, Inc.   All Rights Reserved
# $Id$
#------------------------------------------------------------
package RPS::ArtistRoyalty::Command::DistributeStatements;
use strict;
use warnings;

use Data::Dumper;

use lib '/app/tools/rps/lib';
use RPS::ArtistRoyalty::Command::Show;
use RPS::Command;
use RPS::Payor::Payor;
use RPS::ArtistRoyalty::DistributeStatementsForm;
use RPS::DB::Item::PortalEmailCustomText;
use base 'RPS::Command';

use lib '/app/tools/common/lib';
use RSApache::Response::XSLT;

sub cmd  { return 'distribute'; }
sub area { return 'artist_royalty'; }

use constant kTemplate => "/app/tools/rps/templates/artist_royalty/distribute.xsl";

use constant MAX_PAGE_SIZE => 1_000_000_000;
use constant STICKY_PREFIX => 'pe_' . __PACKAGE__->area() . '_';
use constant STICKY_PARAMS => {
    pageSize => 100,
};

sub _maxPageSize       { MAX_PAGE_SIZE }
sub _stickyParamPrefix { STICKY_PREFIX }
sub _stickyParams      { STICKY_PARAMS }

sub execute {
    my ($self) = @_;

    my $response = $self->SUPER::execute();
    return $response if $response;

    my $hParams  = $self->_preprocessStickyParams( $self->_stickyParamPrefix, $self->_stickyParams );
    my $runID        = $hParams->{RoyaltyRunID};
    my $payorID      = $hParams->{PayorID};
    my $filterBy     = $hParams->{filterBy};
    my $statementIDs = $hParams->{'statementID'};
    my $sendAll      = $hParams->{'sendAll'};
    my $page         = $hParams->{page} || 1;
    my $pageSize     = $hParams->{pageSize};

    $pageSize = $self->_maxPageSize if $pageSize eq 'all';

    my $form = RPS::ArtistRoyalty::DistributeStatementsForm->new(
        runID        => $runID,
        payorID      => $payorID,
        filterBy     => $filterBy,
        statementIDs => $statementIDs,
        sendAll      => $sendAll,
        page         => $page,
        pageSize     => $pageSize
    );

    if ( $self->getParam('formSubmit') ) {

        if ( $form->assignCGIParams( 'Form', $self->getParams() ) ) {
            my $distributedCount = $form->save( $self->getParams() );

            # on a 'regular' save, we will refresh back to the Detail page.
            # on a 'save and new', we refresh back to a blank Edit screen (with a success message).
            my $successMessage = RPS::Message->new( type => "success", code => Common::FormObject::kSuccessFormSubmit );

            my $command = RPS::ArtistRoyalty::Command::DistributeStatements->new(
                msg          => $successMessage->toString,
                RoyaltyRunID => $runID,
                PayorID      => $payorID,
                filterBy     => $filterBy,
                distributed  => $distributedCount,
                page         => $page
            );

            my $redirectResponse = RSApache::Response::Redirect->new( $command->getRedirect() );
            return $redirectResponse;
        } else {
            # We stay on the same page, and display our errors.
            $form->setError(Common::FormObject::kErrFormSubmit);
            $self->addMessageXML( type => "error", code => Common::FormObject::kErrFormSubmit );
        }
    }

    $self->{xml}{Form} = $form;

    my $customNotificationText = RPS::DB::Item::PortalEmailCustomText->GetCustomNotificationText();
    $self->{xml}{PortalEmailCustomText}{NotificationText} = $customNotificationText;

    $response = RSApache::Response::XSLT->new( $self->{xml}, kTemplate );
    return $response;
}


1;