#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2012 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::ArtistRoyalty::Fast::Script::AssembleStatements;

use strict;
use Data::Dumper;
use File::Path;

use lib '/app/tools/common/lib';
use lib '/app/tools/rps/lib';
use lib '/app/tools/raptor/lib';

use DB_File;

use Common::Util;
use Common::Log;
use Common::Parser;
use Common::WriteXML;

use RPS::DB::Item::Label;
use RPS::DB::Item::Artist;
use RPS::DB::Item::Album;
use RPS::DB::Item::Product;
use RPS::DB::Item::Song;
use RPS::DB::Item::Master;
use RPS::DB::Item::Track;
use RPS::DB::Item::ProductTrack;
use RPS::DB::Item::Price;
use RPS::DB::Item::ProductPrice;
use RPS::DB::Item::PriceLevel;
use RPS::DB::Item::IncomeSource;

use RPS::DB::Item::ArtistRoyaltyStatement;
use RPS::DB::Item::ArtistRoyaltyAlbum;
use RPS::DB::Item::ArtistRoyaltyRun;
use RPS::DB::Item::ArtistRoyaltyIncomeItem;
use RPS::DB::Item::SaleRunMap;

use RPS::ArtistRoyalty::Fast::Mapped::Data;
use RPS::ArtistRoyalty::Fast::Static::Terms;
use RPS::ArtistRoyalty::Fast::TermType;

use RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyTransaction;
use RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyLicenseIncomeItem;
use RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyIncomeItem;
use RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyExpenseItem;
use RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyAlbum;
use RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyStatement;

#use ArtistRoyaltyPaidSales;
use RPS::ArtistRoyalty::Fast::Final::SaleRunMap;

use base 'Common::Script';

sub _options {
    {
        client_id => {
            short       => 'c',
            required    => 1,
            description => 'Limit to this client id',
            parameter   => 'i'
        },
        data_path => {
            short       => 'd',
            required    => 1,
            description => 'path to directory containing static data',
            parameter   => 's'
        },
        output_path => {
            short       => 'o',
            required    => 1,
            description => 'path to directory to write output files',
            parameter   => 's'
        },
        run_id => {
            short       => 'r',
            required    => 1,
            description => 'The artist_royalty_run_id we are creating statements for.',
            parameter   => 'i',
        },
        index_range => {
            short       => 'i',
            required    => 0,
            description => 'First,Last data indexes to process.  Ex: -s0,10000',
            parameter   => 's',
        },
    };
}

sub _process {
    my ($self) = @_;

    my $dataPath        = $self->param('data_path');
    my $outputDirectory = $self->param('output_path');
    my $runID           = $self->param('run_id');

    # Read in the run record, so we can get the correct payor_id.
    #
    my $runData = RPS::DB::Item::ArtistRoyaltyRun->Lookup( artist_royalty_run_id => $runID );
    my $payorID = $runData->payor_id();

    my $inData = RPS::ArtistRoyalty::Fast::Mapped::Data->GetMappedItems($outputDirectory);

    my $contractTermData = RPS::ArtistRoyalty::Fast::Static::Terms->GetContractTermData($dataPath);

    RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyStatement->Init( $outputDirectory, $dataPath );
    RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyAlbum->Init( $outputDirectory, $dataPath );
    RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyIncomeItem->Init( $outputDirectory, $dataPath, $runID );
    RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyExpenseItem->Init($outputDirectory);
    RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyLicenseIncomeItem->Init($outputDirectory);
    RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyTransaction->Init($outputDirectory);

    my $statement;
    my $album;
    my $lineItem;

    while ( my $data = $inData->nextLine() ) {
        Log->info( "\n\nDATA:", $data );

        # !!! Going to need to jam the Expense Items in here.
        # !!!

        # Note that we always destroy the objects opposite of how we build them.
        # This is because objects do stuff when they are destroyed:
        # - They write their accumulated values to their output files.
        # - They call methods in their container objects to update summary data.
        #
        # So we need to make sure the summary data is updated before the containers
        # are themselves destroyed.
        #
        if ( !$statement || !$statement->process($data) ) {
            $lineItem = undef;
            $album    = undef;

            # We will skip statements with min payment but no activity
            $statement = RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyStatement->new( $data, $runID, $payorID ) || next;
            $album = RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyAlbum->new( $data, $statement );

            $lineItem = $self->_newLineItem( $data, $album, $contractTermData );
        } elsif ( !$album->process($data) ) {
            $lineItem = undef;

            $album = RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyAlbum->new( $data, $statement );
            $lineItem = $self->_newLineItem( $data, $album, $contractTermData );
        } elsif ( !defined $lineItem || !$lineItem->process($data) ) {
            $lineItem = $self->_newLineItem( $data, $album, $contractTermData );
        }
    }

    # Explicitly release these references, so they write out immediately.
    #
    $lineItem  = undef;
    $album     = undef;
    $statement = undef;

}

sub _newLineItem {
    my ( $self, $data, $album, $contractTermData ) = @_;

    my $type = $data->[RPS::ArtistRoyalty::Fast::Mapped::Data::kType];

    return RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyIncomeItem->new( $data, $album,
        $self->_getNewTermType( $data, $contractTermData ) )
      if ( RPS::ArtistRoyalty::Fast::Mapped::Data::kTypeSale == $type || RPS::ArtistRoyalty::Fast::Mapped::Data::kTypeReserve == $type );

    return RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyExpenseItem->new( $data, $album )
      if ( RPS::ArtistRoyalty::Fast::Mapped::Data::kTypeExpense == $type );

    return RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyLicenseIncomeItem->new( $data, $album )
      if ( RPS::ArtistRoyalty::Fast::Mapped::Data::kTypeLicenseIncome == $type );

    return RPS::ArtistRoyalty::Fast::Final::ArtistRoyaltyTransaction->new( $data, $album )
      if ( RPS::ArtistRoyalty::Fast::Mapped::Data::kTypeTransaction == $type );

    # Return undef if we don't recognize the type.  This sort of 'no-op' is not actually an error, and
    # we're going to take advantage of this to allow us to create Statements for payees with no activity.
    #
    return undef;
}

sub _getNewTermType {
    my ( $self, $data, $termData ) = @_;
    my $termID = int( $data->[RPS::ArtistRoyalty::Fast::Mapped::Data::kTermID] );
    return RPS::ArtistRoyalty::Fast::TermType->GetTermObj( $termID, $termData );
}

1;