#------------------------------------------------------------
# Copyright (C) 2006 RoyaltyShare, Inc.   All Rights Reserved
# $Id$
#------------------------------------------------------------
package RPS::Catalog::Command::Main;
use strict;
use warnings;

use lib '/app/tools/appuser/lib';
use AppUser::User::User;

use lib '/app/tools/rps/lib';
use RPS::Pagination;
use RPS::LabelList;
use RPS::Catalog::RecentlyViewedAlbumList;
use RPS::Catalog::AlbumAdditionalArtistHash;
use RPS::Catalog::AlbumList;
use RPS::DB::Item::AlbumListData;

use RPS::Command;
use base 'RPS::Command';

use lib '/app/tools/common/lib';
use RSApache::Response::XSLT;

sub cmd  { return 'main'; }
sub area { return 'catalog'; }

use constant kTemplate => "/app/tools/rps/templates/catalog/index.xsl";

sub execute {
    my ($self) = @_;

    my $response = $self->SUPER::execute();
    return $response if $response;

    my $labelID  = $self->getParam("label");
    my $page     = $self->getParam("page") || 1;
    my $pageSize = $self->getParam("pageSize") || 10;

    my $collection = RPS::DB::Item::AlbumListData->GetList($labelID);

    $collection->setPagination( pageIndex => $page, pageSize => $pageSize );

    $self->{xml}{Pagination} = RPS::Pagination->new(
        total     => $collection->totalSize(),
        recordNum => $collection->{_record},
        pageSize  => $pageSize
    );

    $self->{xml}{AlbumList}      = $self->_getAlbumList($collection);
    $self->{xml}{RecentlyViewed} = RPS::Catalog::RecentlyViewedAlbumList->new( user_id => $self->_getUser()->UserID() );
    $self->{xml}{LabelList}      = RPS::LabelList->new();

    $response = RSApache::Response::XSLT->new( $self->{xml}, kTemplate );
    return $response;
}

sub _getAlbumList {
    my ( $self, $collection ) = @_;

    my $list->{Item} = [];

    while ( $collection->hasNext() ) {
        my $obj = $collection->next();
        my $albumItem->{Album} = $self->_getObj($obj);

        push @{ $list->{Item} }, $albumItem;
    }

    return $list;
}

sub _getObj {
    my ( $self, $dbItem ) = @_;

    # Just return a hash. It will work.
    #
    return {
        AlbumID              => $dbItem->album_id(),
        Title                => $dbItem->album_title(),
        CatalogNumber        => $dbItem->catalog_number(),
        LabelID              => $dbItem->label_id(),
        Status               => $dbItem->status(),
        ArtistName           => $dbItem->artist_name(),
        AdditionalArtistList => RPS::Catalog::AlbumAdditionalArtistHash->new( albumID => $dbItem->album_id() ),
    };
}

1;