#------------------------------------------------------------
# Copyright (C) 2006 RoyaltyShare, Inc.   All Rights Reserved
# $Id$
#------------------------------------------------------------
package RPS::Contract::Command::Main;
use strict;
use warnings;
use Data::Dumper;

use lib '/app/tools/appuser/lib';
use AppUser::User::User;

use lib '/app/tools/rps/lib';
use RPS::LabelList;
use RPS::Contract::RecentlyViewedContractList;
use RPS::Payor::PayorList;
use RPS::DB::Item::Contract;
use RPS::ArtistContract::ArtistContract;
use RPS::LabelContract::LabelContract;
use RPS::Pagination;

use RPS::Command;
use base 'RPS::Command';

use lib '/app/tools/common/lib';
use Common::Client;
use RSApache::Response::XSLT;

sub cmd  { return 'main'; }
sub area { return 'contract'; }

use constant kTemplate => "/app/tools/rps/templates/contract/index.xsl";

sub execute {
    my ($self) = @_;

    my $response = $self->SUPER::execute();
    return $response if $response;

    my %getArgs;
    $getArgs{payor_id} = $self->getParam("payor");

    # Check for the filter param.
    my $contractType = $self->getParam("contractType");
    my $page         = $self->getParam("page") || 1;
    my $pageSize     = $self->getParam("pageSize") || 10;

    my $client = Common::Client::Current();

    # Include artist contracts if client does artist royalties
    if ( $client->isClientType(Common::Client::kArtist) && ( !$contractType || $contractType eq 'artist' ) ) {
        $getArgs{artistContract} = 1;
    }

    # Include label contracts if client does label royalties
    if ( $client->isClientType(Common::Client::kLabel) && ( !$contractType || $contractType eq 'label' ) ) {
        $getArgs{labelContract} = 1;
    }

    my $collection = RPS::DB::Item::Contract->Get(%getArgs);

    $collection->setPagination( pageIndex => $page, pageSize => $pageSize );

    $self->{xml}{Pagination} = RPS::Pagination->new(
        total     => $collection->totalSize(),
        recordNum => $collection->{_record},
        pageSize  => $pageSize
    );

    $self->{xml}{ContractList}   = $self->_getContractList($collection);
    $self->{xml}{RecentlyViewed} = RPS::Contract::RecentlyViewedContractList->new( user_id => $self->_getUser()->UserID() );
    $self->{xml}{PayorList}      = RPS::Payor::PayorList->new();

    $response = RSApache::Response::XSLT->new( $self->{xml}, kTemplate );
    return $response;
}

sub _getContractList {
    my ( $self, $collection ) = @_;

    my $list->{Item} = [];

    while ( $collection->hasNext() ) {
        my $obj = $collection->next();
        my $contractItem;

        if ( $obj->artist_contract_id ) {
            $contractItem->{ArtistContract} =
              RPS::ArtistContract::ArtistContract->new( artistContractID => $obj->artist_contract_id, loadSubs => 0 );
        } else {
            $contractItem->{LabelContract} =
              RPS::LabelContract::LabelContract->new( labelContractID => $obj->label_contract_id, loadSubs => 0 );
        }

        push @{ $list->{Item} }, $contractItem;
    }

    return $list;
}

1;