#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2013 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::ADA::v18;

use strict;

use lib '/app/tools/common/lib';
use Common::Assert;
use Common::UTF8;
use Common::Date;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::MapFaceBase';
use base 'RPS::Import::ADA::ADACommon';

sub _fieldMap {
    {
        labelName   => 'P',
        dateBegin   => 'T',
        productType => 'F',
        artistName  => 'G',
        upc         => 'D',
        isrc        => 'E',
        price       => 'K',
        units       => 'J',
        countryCode => 'M',
        serviceID   => 'C',
    };
}

sub _unverifiedFieldMap {
    {
        mediaCode => 'B',
        title     => 'H',
    };
}

sub _headerIdentifier { ( dateBegin => 'TRANSACTION_DATE' ) }

sub currencyCode { 'USD' }

sub serviceID {
    my $self = shift;

    my $service = $self->_getByFieldName('serviceID') || return;
    my $serviceID = $self->getServiceID( lc($service) );

    if ( !$serviceID ) {
        return $self->handleError( "Unknown service: $service", RPS::DB::Item::SaleImportError::kErrorService );
    } else {
        return $serviceID;
    }
}

sub upc {
    my $self = shift;
    my $upc = $self->_getByFieldName('upc') || return;
    return $self->_normalizeValue($upc);
}

sub isrc {
    my $self = shift;
    my $isrc = $self->_getByFieldName('isrc');
    $isrc = $self->_normalizeValue($isrc);

    # Just making sure that we actually have an ISRC, and not a UPC.
    if ( $isrc && $isrc =~ /^\w/ ) {
        return $isrc;
    }
}

sub saleDates {
    my $self = shift;

    my $dateBegin;
    my $dateEnd;

    my $startDate = $self->_getDateBegin();
    my $_startDate;

    if ( $startDate =~ m/^\d+$/ ) {
        $_startDate = new Common::Date( date => $startDate, type => 'excel' );
    } else {
        my %months = (
            jan => 1,
            feb => 2,
            mar => 3,
            apr => 4,
            may => 5,
            jun => 6,
            jul => 7,
            aug => 8,
            sep => 9,
            oct => 10,
            nov => 11,
            dec => 12
        );

        my ( $day, $monthName, $year ) = $startDate =~ m/(\d{1,2})-(Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec)-(\d{2})/i;
        my $month = $months{ lc $monthName };

        if ( $monthName && $year ) {
            $_startDate = sprintf( "%04d-%02d-%02d", $year + 2000, $month, 1 );

        }
    }

    if ($_startDate) {
        ( $dateBegin, $dateEnd ) = $self->_getDates( date_begin => $_startDate );
    }

    return ( $dateBegin, $dateEnd );
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType') || return;

    if ( $type =~ /^isrc$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    } elsif ( $type =~ /^upc$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } else {
        return $type;
    }
}

sub albumName {
    my $self = shift;
    my $name = $self->_getByFieldName('title');
    my $isrc = $self->_getByFieldName('isrc');
    $isrc = $self->_normalizeValue($isrc);

    # If the value in the ISRC column is actually a UPC,
    # then we know this is an album.
    if ( $isrc && $isrc =~ /^\d/ ) {
        return $name;
    }
}

sub trackName {
    my $self = shift;
    my $name = $self->_getByFieldName('title');
    my $isrc = $self->_getByFieldName('isrc');
    $isrc = $self->_normalizeValue($isrc);

    # If the value in the ISRC column is actually an ISRC (and not a UPC),
    # then we know this is a track.
    if ( $isrc && $isrc =~ /^\w/ ) {
        return $name;
    }
}

sub formatType {
    my $self      = shift;
    my $mediaCode = $self->_getByFieldName('mediaCode');
    if ( $mediaCode =~ /^(emdtrack|emdalbum|evd)$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    } elsif ( $mediaCode =~ /^(eringback|emastertone|usergenmastertone)$/i ) {
        return RPS::File::Sale::FORMAT_RINGTONE;
    } else {
        return $mediaCode;
    }
}

sub mediaType {
    my $self      = shift;
    my $mediaCode = $self->_getByFieldName('mediaCode');
    if (   $mediaCode =~ /^(emdtrack|emdalbum)$/i
        || $mediaCode =~ /^(eringback|emastertone|usergenmastertone)$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    } elsif ( $mediaCode =~ /^evd$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    } else {
        return $mediaCode;
    }
}

sub _normalizeValue {
    my $self  = shift;
    my $value = shift;
    $value =~ s/=//;
    $value =~ s/"//g;
    return $value;
}

## MapFace Stuff
sub _mapFaceCompatibleVersions {
    return ( 17, 18, 19, 23, 24, 25, 26, 27, 28 );
}

sub _mapFaceServiceID {
    return ( 'serviceID', 'countryCode' );
}

sub _mapFaceCountryCode {
    return ('countryCode');
}

sub _mapFaceProductType {
    return ('productType');
}

sub _mapFaceFormatType {
    return ('mediaCode');
}

sub _mapFaceMediaType {
    return ('mediaCode');
}

###
1;    # Play nicely.
###