package RPS::Import::ADA::v19;

use strict;
use warnings;

use lib '/app/tools/common/lib';
use Common::Assert;
use Common::UTF8;
use Common::Date;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::MapFaceBase';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        labelName   => 'L',
        dateBegin   => 'S',
        productType => 'F',
        artistName  => 'G',
        upc         => 'D',
        trackName   => 'H',

        isrc        => 'E',
        price       => 'J',
        units       => 'I',
        countryCode => 'M',
        serviceID   => 'C',
    };
}

sub _unverifiedFieldMap {
    { mediaCode => 'B', };
}

sub _headerIdentifier { ( dateBegin => 'TRANSACTION_DATE' ) }

sub currencyCode { 'USD' }

sub serviceID {
    my $self = shift;

    my $service   = $self->_getByFieldName('serviceID') || return;
    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };

    if ( !$serviceID ) {

        # Check for ADA-specific service mappings
        #
        if (   $service =~ /digital breakage adj/i
            || $service =~ /audit recovery/i ) {
            $serviceID = Client::Service::DSP_ADA;
        }

        # There are endless variations of things tacked on to these service names.
        # I'm just going to call it a match if it starts with the service name.
        if ( $service =~ /^apple icloud/i ) {
            $serviceID = Client::Service::DSP_ITUNES;
        } elsif ( $service =~ /^apple music/i ) {
            $serviceID = Client::Service::DSP_APPLE_MUSIC;
        } elsif ( $service =~ /^beatport/i ) {
            $serviceID = Client::Service::DSP_BEATPORT;
        } elsif ( $service =~ /^deezer/i ) {
            $serviceID = Client::Service::DSP_DEEZER;
        } elsif ( $service =~ /^fresh\s?planet/i ) {
            $serviceID = Client::Service::DSP_FRESHPLANET;
        } elsif ( $service =~ /^google/i ) {
            $serviceID = Client::Service::DSP_GOOGLE;
        } elsif ( $service =~ /^imusica/i ) {
            $serviceID = Client::Service::DSP_IMUSICA;
        } elsif ( $service =~ /^icloud/i ) {
            $serviceID = Client::Service::DSP_ITUNES;
        } elsif ( $service =~ /^itunes/i ) {
            $serviceID = Client::Service::DSP_ITUNES;
        } elsif ( $service =~ /^juno digital/i ) {
            $serviceID = Client::Service::DSP_JUNO;
        } elsif ( $service =~ /^rhapsody/i ) {
            $serviceID = Client::Service::DSP_REAL;
        } elsif ( $service =~ /^spotify/i ) {
            $serviceID = Client::Service::DSP_SPOTIFY;
        } elsif ( $service =~ /^tencent/i ) {
            $serviceID = Client::Service::DSP_TENCENT_TECHNOLOGY;
        } elsif ( $service =~ /^wimp/i ) {
            $serviceID = Client::Service::DSP_WIMP;
        } elsif ( $service =~ /^you\s?tube[\s_]nonugc/i ) {
            $serviceID = Client::Service::DSP_YOUTUBE;
        } elsif ( $service =~ /^you\s?tube[\s_]red/i ) {
            $serviceID = Client::Service::DSP_YOUTUBE_RED;
        } elsif ( $service =~ /^you\s?tube[\s_]ugc/i ) {
            $serviceID = Client::Service::DSP_YOUTUBE;
        }
    }

    if ( !$serviceID ) {
        return $self->handleError( "Unknown service: $service", RPS::DB::Item::SaleImportError::kErrorService );
    } else {
        return $serviceID;
    }
}

sub _normalizeValue {
    my $self  = shift;
    my $value = shift;
    $value =~ s/=//;
    $value =~ s/"//g;
    return $value;
}

sub upc {
    my $self = shift;
    my $upc = $self->_getByFieldName('upc') || return;
    return $self->_normalizeValue($upc);
}

sub isrc {
    my $self = shift;
    my $isrc = $self->_getByFieldName('isrc');

    return "" if ( $self->productType() eq 'A' );
    $isrc = $self->_normalizeValue($isrc);

    # Just making sure that we actually have an ISRC, and not a UPC.
    if ( $isrc && $isrc =~ /^\w/ ) {
        return $isrc;
    }
}

sub trackName {
    my $self = shift;
    my $name = $self->_getByFieldName('trackName');

    return ( $self->productType() eq 'T' ) ? $name : "";
}

sub saleDates {
    my $self = shift;

    my $dateBegin;
    my $dateEnd;

    my $startDate = $self->_getDateBegin();
    my $_startDate;

    if ( $startDate =~ m/^\d+$/ ) {
        $_startDate = new Common::Date( date => $startDate, type => 'excel' );
    } else {
        my %months = (
            jan => 1,
            feb => 2,
            mar => 3,
            apr => 4,
            may => 5,
            jun => 6,
            jul => 7,
            aug => 8,
            sep => 9,
            oct => 10,
            nov => 11,
            dec => 12
        );

        my ( $day, $monthName, $year ) = $startDate =~ m/(\d{1,2})-(Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec)-(\d{2})/i;
        my $month = $months{ lc $monthName };

        if ( $monthName && $year ) {
            $_startDate = sprintf( "%04d-%02d-%02d", $year + 2000, $month, 1 );

        }
    }

    if ($_startDate) {
        ( $dateBegin, $dateEnd ) = $self->_getDates( date_begin => $_startDate );
    } else {
        ( $dateBegin, $dateEnd ) = $self->_getDates( date_begin => $startDate );
    }

    return ( $dateBegin, $dateEnd );
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType') || return;

    if ( $type =~ /^isrc$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    } elsif ( $type =~ /^upc$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } else {
        return $type;
    }
}

sub formatType {
    my $self      = shift;
    my $mediaCode = $self->_getByFieldName('mediaCode');
    if ( $mediaCode =~ /^(emdtrackstreaming|emdalbumstreaming|evdstreaming|usergenmastertonestreaming|eringbackstreaming)$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $mediaCode =~ /^(emdalbum|emdtrack|evd)$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    } elsif ( $mediaCode =~ /^(eringback|emastertone)$/i ) {
        return RPS::File::Sale::FORMAT_RINGTONE;
    } else {
        return $mediaCode;
    }
}

sub mediaType {
    my $self      = shift;
    my $mediaCode = $self->_getByFieldName('mediaCode');
    if ( $mediaCode =~
        /^(emdtrackstreaming|emdalbumstreaming|usergenmastertonestreaming|eringbackstreaming|emdalbum|emdtrack|eringback|emastertone)$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    } elsif ( $mediaCode =~ /^(evdstreaming|evd)$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    } else {
        return $mediaCode;
    }
}

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub unitPrice {
    return abs( shift->SUPER::unitPrice() );
}

sub rPrice { shift->SUPER::price }
sub rUnits { shift->SUPER::units }

sub _isValidSaleRecord {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    return !$units && !$price ? 0 : 1;
}

# mapface
sub _mapFaceCompatibleVersions {
    return ( 17, 18, 19, 23, 24, 25, 26, 27, 28, 33 );
}

sub _mapFaceServiceID {
    return ( 'serviceID', 'countryCode' );
}

sub _mapFaceCountryCode {
    return ('countryCode');
}

sub _mapFaceProductType {
    return ('productType');
}

sub _mapFaceFormatType {
    return ('mediaCode');
}

sub _mapFaceMediaType {
    return ('mediaCode');
}


1;