#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2013 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::ADA::v26;

use strict;
use warnings;

use lib '/app/tools/common/lib';
use Common::Assert;
use Common::UTF8;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::MapFaceBase';
use base 'RPS::Import::ADA::ADACommon';

sub _fieldMap {
    {
        dateBegin  => 'B',
        dateEnd    => 'C',
        artistName => 'D',
        upc        => 'F',
        isrc       => 'F',
        albumName  => 'E',
        trackName  => 'E',
        price      => 'X',
        units      => 'V',
        serviceID  => 'A',
    };
}

sub _unverifiedFieldMap {
    {
        formatCode => 'H',
        mediaCode  => 'G',
        modelType  => 'S',
    };
}

sub _headerIdentifier { ( dateBegin => 'Start Date' ) }

sub currencyCode { 'USD' }

sub countryCode { 'US' }

my %gMediaCodeMap = (
    'emd' => {
        'payasyougo' => {
            format => RPS::File::Sale::FORMAT_DOWNLOAD,
            media  => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
        'streaming-subscription' => {
            format => RPS::File::Sale::FORMAT_STREAM,
            media  => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
        'streaming-adsupported' => {
            format => RPS::File::Sale::FORMAT_STREAM,
            media  => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
        'streaming-adsupporteddirect' => {
            format => RPS::File::Sale::FORMAT_STREAM,
            media  => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
    },
    'emastertone' => {
        'payasyougo' => {
            format => RPS::File::Sale::FORMAT_RINGTONE,
            media  => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
    },
    'eringback' => {
        'payasyougo' => {
            format => RPS::File::Sale::FORMAT_RINGTONE,
            media  => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
    },
    'evd' => {
        'payasyougo' => {
            format => RPS::File::Sale::FORMAT_DOWNLOAD,
            media  => RPS::DB::Item::MediaType::kMediaTypeVideo,
        },
        'streaming-adsupported' => {
            format => RPS::File::Sale::FORMAT_STREAM,
            media  => RPS::DB::Item::MediaType::kMediaTypeVideo,
        },
        'streaming-subscription' => {
            format => RPS::File::Sale::FORMAT_STREAM,
            media  => RPS::DB::Item::MediaType::kMediaTypeVideo,
        },
    },
);

sub unitPrice { abs( shift->SUPER::unitPrice ) }
sub price     { abs( shift->SUPER::price ) }

sub serviceID {
    my $self = shift;

    my $service = $self->_getByFieldName('serviceID') || return;
    my $serviceID = $self->getServiceID( lc($service) );

    if ( !$serviceID ) {
        return $self->handleError( "Unknown service: $service", RPS::DB::Item::SaleImportError::kErrorService );
    } else {
        return $serviceID;
    }
}

sub units {
    my $self = shift;

    # Implementing https://royaltyshare.fogbugz.com/default.asp?W21
    if ( $self->rPrice < 0 ) { return 0 - abs( $self->rUnits ); }
    return abs( $self->rUnits );
}

sub saleDates {
    my $self = shift;

    my $startDate = $self->_getByFieldName('dateBegin');
    my $endDate   = $self->_getByFieldName('dateEnd');

    $startDate = Spreadsheet::ParseExcel::Utility::ExcelFmt( "yyyy-mm-dd", $1 ) if ( $startDate =~ /^(\d{5})$/ );
    $endDate   = Spreadsheet::ParseExcel::Utility::ExcelFmt( "yyyy-mm-dd", $1 ) if ( $endDate =~ /^(\d{5})$/ );

    return $self->_getDates( date_begin => $startDate, date_end => $endDate );
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatCode') || '';
    if ( $type =~ /^(T|D|P)$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    } elsif ( $type =~ /^(A|EP)$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    }

    return $self->handleError( "Unknown productType: '$type'", RPS::DB::Item::SaleImportError::kErrorProductType );
}

sub albumName {
    my $self = shift;
    my $name = $self->_getByFieldName('albumName');

    return ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) ? $name : '';
}

sub upc {
    my $self = shift;
    my $upc = $self->_getByFieldName('upc') || return;
    return ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) ? $upc : '';
}

sub trackName {
    my $self = shift;
    my $name = $self->_getByFieldName('trackName');
    return ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) ? $name : '';
}

sub isrc {
    my $self = shift;
    my $isrc = $self->_getByFieldName('isrc') || return;
    return ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) ? $isrc : '';
}

sub _getMediaCodeMap {
    my $self = shift;

    my $mediaCode  = lc($self->_getByFieldName('mediaCode') || '');
    my $modelType  = lc($self->_getByFieldName('modelType') || '');

    if ( exists $gMediaCodeMap{$mediaCode}{$modelType} ) {
        my $_formatID  = $gMediaCodeMap{$mediaCode}{$modelType}{format};
        my $_mediaType = $gMediaCodeMap{$mediaCode}{$modelType}{media};
        return ( $_formatID, $_mediaType );
    }

    return;
}

sub formatType {
    my $self = shift;
    my ( $_formatID, $_mediaType ) = $self->_getMediaCodeMap();
    return $_formatID if $_formatID;

    return $self->handleError( "Unknown formatType", RPS::DB::Item::SaleImportError::kErrorFormatType );
}

sub mediaType {
    my $self = shift;
    my ( $_formatID, $_mediaType ) = $self->_getMediaCodeMap();
    return $_mediaType if $_mediaType;

    return $self->handleError( "Unknown formatType", RPS::DB::Item::SaleImportError::kErrorMediaType );
}

## MapFace Stuff
sub _mapFaceCompatibleVersions {
    return ( 17, 18, 19, 23, 24, 25, 26, 27, 28, 34 );
}

sub _mapFaceServiceID {
    return ( 'serviceID' );
}

sub _mapFaceCountryCode {
    return ('countryCode');
}

sub _mapFaceProductType {
    return ('productType');
}

sub _mapFaceFormatType {
    return ('formatType');
}

sub _mapFaceMediaType {
    return ('mediaType');
}


1;