package RPS::Import::AbsoluteDistribution::v3;

use strict;
use warnings;
use POSIX qw(floor);

use lib '/app/tools/common/lib';
use Common::Assert;
use Common::UTF8;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use base qw/RPS::Import::MapFaceBase RPS::Import::Importer/;


sub _fieldMap {
    my $self = shift;

    my %map = (
        3 => {
            labelName       => 'C',
            serviceID       => 'A',
            countryCode     => 'O',
            dateBegin       => 'AA',
            dateEnd         => 'AA',
            formatType      => 'P',
            clientProductID => 'F',
            upc             => 'AC',
            albumName       => 'H',
            isrc            => 'E',
            trackName       => 'J',
            currencyCode    => 'Y',
            price           => 'W',
            units           => 'T',
            mediaType       => 'N',
        },
        4 => {
            labelName       => 'C',
            serviceID       => 'A',
            countryCode     => 'P',
            dateBegin       => 'AB',
            dateEnd         => 'AB',
            formatType      => 'Q',
            clientProductID => 'F',
            upc             => 'AD',
            albumName       => 'H',
            isrc            => 'E',
            trackName       => 'J',
            currencyCode    => 'Z',
            price           => 'X',
            units           => 'U',
            mediaType       => 'N',
        },
    );

    return $map{ $self->_version };
}

sub _unverifiedFieldMap {
    my $self = shift;

    my %map = (
        3 => {
            _channel        => 'Q',
            _track_artis    => 'I',
            _release_artist => 'G',
        },
        4 => {
            _channel        => 'R',
            _track_artis    => 'I',
            _release_artist => 'G',
        },
    );

    return $map{ $self->_version };
}

sub _headerIdentifier { dateBegin => 'month_sold' }

sub serviceID {
    my $self = shift;

    my $service = $self->_getByFieldName('serviceID') || '';
    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc($service) };
    return $serviceID if $serviceID;

    $self->handleError( "Unknown service: '$service'", RPS::DB::Item::SaleImportError::kErrorService );
}

sub countryCode {
    my $self  = shift;

    my $cname = $self->_getByFieldName('countryCode') || '';
    $self->fail("Country code value can't be empty.") unless $cname;

    my $o = Common::Country->Get($cname);
    return $o->alpha2() if $o;

    $self->handleError( "Unknown country code: '$cname'", RPS::DB::Item::SaleImportError::kErrorCountry );

    return $cname;
}

sub saleDates {
    my $self = shift;

    my $dt = $self->_getByFieldName('dateBegin') || '';

    # MM/DD/YYY
    if ( $dt =~ /^(\d{1,2})[\/-](\d{1,2})[\/-](\d{4})$/ ) {
        $dt = sprintf  "%04d-%02d-%02d", $3, $1, $2;
        return $self->_getDates( date_begin => $dt );
    }
    # YYYY-MM-DD
    if ( $dt =~ /^\d{4}-\d{2}-\d{2}$/ ) {
        return $self->_getDates( date_begin => $dt );
    }
    # Excel format
    if ( $dt =~ /^\d{5}(?:\.\d*)?$/ ) {
        my $date = Spreadsheet::ParseExcel::Utility::ExcelFmt( "yyyy-mm-dd", $dt );
        return $self->_getDates( date_begin => $date );
    }

    $self->fail("Unable to determine dateBegin from: '$dt'");
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType') || '';
    my $isrc = $self->_getByFieldName('isrc')      || '';

    return $isrc
        ? RPS::File::Sale::TYPE_TRACK
        : RPS::File::Sale::TYPE_ALBUM;
}

sub formatType {
    my $self = shift;

    my $channel = $self->_getByFieldName('_channel')   || '';
    my $service = $self->_getByFieldName('serviceID')  || '';
    my $product = $self->_getByFieldName('formatType') || '';

    return RPS::File::Sale::FORMAT_STREAM if $channel =~ /^(?:
        iTunes\sMatch|
        Stream|
        breakage|
        SHUFFLE|
        NON\-STATION|
        STATION|
        ON_DEMAND|
        Streaming\s\-\sHard\sBundle\(VAS\)|
        Streaming\s\-\sMonthly|
        Streaming\s\-\sFamily|
        Streaming\s\-\sAnnual|
        Subscription\sStream|
        subscription|
        advertisment|
        Streaming\s-\sStudent|
        Streaming\s-\sHiResMonthly|
        Streaming\s-\sHiResHard\sBundle\(VAS\)|
        Streaming|
        audio\sstream|
        adjustment|
        Stream_semi
    )$/ix;

    return RPS::File::Sale::FORMAT_DOWNLOAD if $channel =~ /^Download$/i;
    return RPS::File::Sale::FORMAT_TETHERED if $channel =~ /^Tethered Download$/i;

    if ( $channel =~ /^Ad\-Supported$/i && $product =~ /^Tethered download$/i) {
        return RPS::File::Sale::FORMAT_TETHERED;
    }

    if ( $channel =~ /^Web$/i && $service =~ /^Soundtrack Your Brand$/i ) {
        return RPS::File::Sale::FORMAT_PERFORMANCE;
    } elsif ( $channel =~ /^Web$/i && $service =~ /^Music Island$/i  ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $channel =~ /^JioBundle Stream$/i && $service =~ /^Saavn$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $channel =~ /^Capcut$/i && $service =~ /^TikTok$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    }

    if ( !$channel ) {
        return RPS::File::Sale::FORMAT_STREAM if $service =~ /^(?:
            Vevo|
            Amazon\sMusic|
            Netease|
            Deezer|
            Tidal|
            Resso|
            TikTok|
            Audiomack|
            Saavn|
            Nuuday
        )$/ix;
    }

    $self->fail("Could not parse format type from '$channel' & '$service' & '$product' ");
}

sub artistName {
    my $self = shift;

    my $trackArtist   = $self->_getByFieldName('_track_artis')    || '';
    my $releaseArtist = $self->_getByFieldName('_release_artist') || '';

    return $trackArtist ? $trackArtist : $releaseArtist;
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType') || '';

    return RPS::DB::Item::MediaType::kMediaTypeAudio if $type =~ /^(?:track|format|album)$/i;
    return RPS::DB::Item::MediaType::kMediaTypeVideo if $type =~ /^video$/i;

    $self->fail("Could not parse media type from '$type'");
}

sub price     {
    my $self = shift;

    my $price = $self->_getByFieldName('price') || 0;
    return sprintf "%.8f", abs($price);
}

sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;
    $units = floor($units + 0.5);

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub _mapFaceProductType { }
sub _mapFaceServiceID   { 'serviceID' }
sub _mapFaceCountryCode { 'countryCode' }
sub _mapFaceFormatType  {  }
sub _mapFaceMediaType   {  }


1;