package RPS::Import::AmazonMinimal;
use strict;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use base 'RPS::Import::Importer';

my %field_map = (
    3 => {
        date_row => 0,
        date_col => 0,
        album    => 1,
        track    => 2,
        product  => 3,
        units    => 4,
        price    => 6,
    },
);

sub _importLines {
    my $self    = shift;
    my %args    = @_;
    my $lines   = $args{lines};
    my $version = $self->_version();
    my $offsets = $field_map{$version};

    return 0 unless $lines;

    my ( $dateBegin, $dateEnd ) = _getDates( $lines->[ $offsets->{date_row} ]->[ $offsets->{date_col} ] );
    unless ( $dateBegin && $dateEnd ) {
        $self->errstr("couldn't get dates");
        print STDERR "can't get dates from: $lines->[$offsets->{date_row}]->[$offsets->{date_col}]\n";
        return undef;
    }

    my $linenum = 1;
    foreach my $line (@$lines) {
        my $album   = $line->[ $offsets->{album} ];
        my $track   = $line->[ $offsets->{track} ];
        my $price   = $self->numeric( $line->[ $offsets->{price} ] );
        my $units   = $line->[ $offsets->{units} ];
        my $product = uc( $line->[ $offsets->{product} ] );

        if ( $price && $units && ( $track or $album ) ) {
            unless ( $product =~ /^(A|T)$/ ) {
                $self->errstr('Unknown Product Type');
                print STDERR "unknown prod type: $product\n";
                return undef;
            }

            $price /= $units;

            my $sale = RPS::Import::SaleRec->new();

            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->albumName($album);
            $sale->trackName($track) if $track;
            $sale->lineNum($linenum);
            $sale->productType($product);
            $sale->formatType(RPS::File::Sale::FORMAT_DOWNLOAD);
            $sale->units($units);
            $sale->price($price);
            $sale->countryCode('US');

            $self->_insertSale( sale => $sale );
        }

        #else { print STDERR "skip: ($linenum) p: $price u: $units t: $track a: $album\n"; }
        $linenum++;
    }
    return $linenum;
}

#
# Private methods
#

sub _getDates {
    my $date = shift;
    return undef unless ( $date =~ m/(\d+)\D\d+\D(\d{4})\-(\d+)\D\d+\D(\d{4})/ );
    my ( $m1, $y1, $m2, $y2 ) = ( $1, $2, $3, $4 );

    return ( sprintf( "%04d-%02d-01", $y1, $m1 ), sprintf( "%04d-%02d-%02d", $y2, $m2, Days_in_Month( $y2, $m2 ) ) );
}

###
1;    # Play nicely.
###