package RPS::Import::AmazonPrime::v2;

use strict;

use lib '/app/tools/common/lib';
use Common::CurrencyFormat;

use Common::Util qw(normalize_date normalize_isrc);

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        # header
        dateBegin => 'A2',

        # detail
        albumName   => 'J',
        labelName   => 'L',
        artistName  => 'I',
        isrc        => 'E',
        trackName   => 'K',
        units       => 'F',
        countryCode => 'M',
        price       => 'N',
        upc         => 'C',
    };
}

sub _headerIdentifier { ( albumName => 'ALBUM_NAME' ) }

sub productType { RPS::File::Sale::TYPE_TRACK }

sub formatType { return RPS::File::Sale::FORMAT_STREAM; }

sub mediaType { return RPS::DB::Item::MediaType::kMediaTypeAudio; }

sub saleDates {
    my $self = shift;
    if ( !exists $self->{_startDate} ) {
        my $d = $self->_getByFieldName('dateBegin');
        if ( $d =~ /(\d{1,2})\/(\d{1,2})\/(\d{4})\s*-\s*(\d{1,2})\/(\d{1,2})\/(\d{4})/ )    #   MM/DD/YYYY - MM/DD/YYYY
        {
            my ( $sMonth, $sDay, $sYear, $eMonth, $eDay, $eYear ) = ( $1, $2, $3, $4, $5, $6 );
            $self->{_startDate} = sprintf( "%04d-%02d-%02d", $sYear, $sMonth, $sDay );
            $self->{_endDate}   = sprintf( "%04d-%02d-%02d", $eYear, $eMonth, $eDay );
        }
    }
    return ( $self->{_startDate}, $self->{_endDate} );
}

sub currencyCode {
    my $self           = shift;
    my $countryCode    = $self->_getByFieldName('countryCode');
    my $currencyFormat = Common::CurrencyFormat->new( countryCode => $countryCode );
    return $currencyFormat->currencyCode() if ($currencyFormat);
    $self->fail("Unable to determine country code from '$countryCode'");
}

sub isrc {
    my $self = shift;
    my $isrc = $self->_getByFieldName('isrc');
    return normalize_isrc($isrc) if ($isrc);
}

sub price {
    my $self      = shift;
    my $units     = $self->_getByFieldName('units');
    my $unitPrice = $self->_getByFieldName('price');
    return $units * $unitPrice;
}

###
1;    # Play nicely.
###