package RPS::Import::BMGCHouse;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Util;
use Common::Consts;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

use constant DATE_ROW => 1;
use constant DATE_COL => 3;

use constant FIELD_VENDORID => 2;
use constant FIELD_ALBUM    => 3;
use constant FIELD_UPC      => 4;
use constant FIELD_RETAIL   => 5;
use constant FIELD_SALES    => 8;
use constant FIELD_PRICE    => 9;
use constant FIELD_TOTAL    => 12;

#public methods

sub _importLines {
    my $self = shift;
    my %args = @_;

    my $retval = undef;
    my $lines  = $args{lines};

    my $linenum = 1;

    my ( $dateBegin, $dateEnd ) = $self->_getDates( $lines->[DATE_ROW]->[DATE_COL] );
    unless ( $dateBegin && $dateEnd ) {
        $self->errstr( "couldn't get dates from " . $lines->[DATE_ROW]->[DATE_COL] );
        return undef;
    }

    foreach my $line (@$lines) {
        my $price_level  = RPS::File::Sale::PLEVEL_UNKNOWN;
        my $channel      = RPS::File::Sale::CHANNEL_CLUB;
        my $upc          = $line->[FIELD_UPC];
        my $retail_price = $line->[FIELD_RETAIL];
        my $vendorid     = $line->[FIELD_VENDORID];
        my $release      = $line->[FIELD_ALBUM];
        my ( $album, $artist );
        if ( $release =~ m/^(.*[^ ])  +\: *([^ ].*)$/ ) {
            $album  = $1;
            $artist = $2;
        }

        my $prodtype = RPS::File::Sale::TYPE_CD;

        my ($sales) = $line->[FIELD_SALES] =~ m/^\s*(-?[0-9\,]+)\s*$/;
        my ($total) = $line->[FIELD_TOTAL] =~ m/^\s*(-?[0-9\,]*\.?[0-9\,]*)\s*$/;

        my $price = $total / $sales if ($sales);    # FB12836

        if ( $upc && $total && $sales ) {
            my $sale = RPS::Import::SaleRec->new();

            $sale->productType($prodtype);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->upc($upc);
            $sale->artistName($artist);
            $sale->albumName($album);
            $sale->serviceProductID($vendorid);
            $sale->sales($sales);
            $sale->salesRevenue( $price * $sales );
            $sale->totalRevenue($total);
            $sale->priceLevel($price_level);
            $sale->retailPrice($retail_price);
            $sale->channel($channel);
            $sale->countryCode('US');
            $sale->lineNum($linenum);

            #$args{dumper}($sale);  ## for cmd-line testing
            $self->_insertSale( sale => $sale );
        }
        $linenum++;
    }

    return $linenum;
}

#
# Private methods
#

sub _getDates {
    my $self = shift;
    my $date = shift;

    my ( $startDate, $endDate );
    if ( $date =~ m/^(\d+)-(\d+)-(\d+)/ ) {
        my $year  = $1;
        my $month = $2;
        my $day   = $3;
        $startDate = sprintf( "%04d-%02d-%02d", $year, $month - 5, 1 );
        $endDate   = sprintf( "%04d-%02d-%02d", $year, $month,     $day );
    } else {
        return undef;
    }

    return ( $startDate, $endDate );
}

###
1;    # Play nicely.
###