package RPS::Import::Bandcamp::v25;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use parent 'RPS::Import::ImporterMixed';

sub physical { 2 }

sub _fieldMapExtended {
    {
        mixed => {
            option1 => {
                countryCode     => 'AV',
                dateBegin       => 'A',
                dateEnd         => 'A',
                formatType      => 'Z',
                clientProductID => 'AD',
                artistName      => 'E',
                upc             => 'AE',
                albumName       => 'D',
                isrc            => 'AF',
                trackName       => 'D',
                units           => 'H',
                currencyCode    => 'F',
                retail          => 'G',
                totalRevenue    => 'Y',
                price           => 'Y',
                mediaType       => 'C',
            },
        },
    };
}

sub _unverifiedFieldMapExtended {
    {
        mixed => {
            option1 => {
                _productTypePhys => 'Z',
                _productTypeDig  => 'C',
                _netUnits        => 'H',
            },
        }
    };
}

sub _headerIdentifierExtended {
    {
        mixed => {
            option1 => {
                upc => 'upc',
            },
        },
    };
}

sub serviceID   { Client::Service::DSP_BANDCAMP }

sub countryCode {
    my $self = shift;

    my $name = $self->_getByFieldName('countryCode') || 'US';

    my $oCountry = Common::Country->Get($name);
    return $oCountry->alpha2() if $oCountry;

    $self->fail( "Unable to determine country from: '$name'." );
}

sub saleDates {
    my $self = shift;

    # MM/DD/YYYY HH:MM:SS or M/D/YY H:MM
    my $dateBegin = $self->_getByFieldName('dateBegin') || '';

    my ($year, $month, $day);
    if ( $dateBegin =~ /^(\d{4})[ -\/](\d{2})[ -\/](\d{2})$/ ) {
        ($year, $month, $day) = ($1, $2, $3);
    } elsif ( $dateBegin =~ /^(\d{1,2})\/(\d{1,2})\/(\d{2,4})/ ) {
        ($year, $month, $day) = ($3, $1, $2);
    } else {
        $self->fail( "Unable to determine date from: '$dateBegin'." );
    }

    $dateBegin = sprintf "%04d-%02d-%02d", length $year == 2 ? "20$year" : $year , $month, $day;
    return $self->_getDates( date_begin => $dateBegin );
}

sub productType {
    my $self = shift;

    my $typeDig  = $self->_getByFieldName('_productTypeDig')  || '';
    my $typePhys = $self->_getByFieldName('_productTypePhys') || '';

    # order is important
    # digital
    if ( $typeDig =~ /^track$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    }
    elsif ( $typeDig =~ /^album|refund|bundle$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    }
    elsif ( $typeDig =~ /^reversal$/i ) {
        return $self->_getByFieldName('isrc')
            ? RPS::File::Sale::TYPE_TRACK
            : RPS::File::Sale::TYPE_ALBUM;
    }
    # physical
    elsif ( $typePhys =~ /12''\sVinyl\sLP | \(Vinyl\) | \(?LP\)? $/xi ) {
        return RPS::File::Sale::TYPE_LP;
    }

    # all other cases except $typeDig = 'payout' see in _isValidSaleRecord
    return RPS::File::Sale::TYPE_CD;
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';
    return RPS::File::Sale::FORMAT_DOWNLOAD if $type =~ /^digital (?:download|bundle)$/i;

    $self->fail( "Unable to determine format_type from: '$type'." );
}

sub upc {
    my $self = shift;

    my $upc = $self->_getByFieldName('upc') || '';
    $upc =~ s/\s//g;

    return $upc;
}

sub isrc {
    my $self = shift;

    my $isrc = $self->_getByFieldName('isrc') || '';
    $isrc =~ s/-//g;

    return $isrc;
}

sub albumName {
    my $self = shift;

    my $name = $self->_getByFieldName('albumName') || '';
    return $self->productType ne RPS::File::Sale::TYPE_TRACK
        ? $name
        : undef;
}

sub trackName {
    my $self = shift;

    my $name = $self->_getByFieldName('trackName') || '';
    return $self->productType eq RPS::File::Sale::TYPE_TRACK
        ? $name
        : undef;
}

sub mediaType  {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType') || '';
    if ( $type =~ /^album|track|refund|bundle|reversal|Package$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }

    $self->fail( "Unable to determine media_type from: '$type'." );
}

# digital
sub price     { abs( shift->_getByFieldName('price') || 0 ) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
        $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

# physical
sub channel        { RPS::File::Sale::CHANNEL_RETAIL }
sub priceLevel     { RPS::File::Sale::PLEVEL_UNKNOWN }
sub netUnits       { shift->_getByFieldName('_netUnits')    || 0 }
sub totalRevenue   { shift->_getByFieldName('totalRevenue') || 0 }
sub sales          { $_[0]->netUnits     > 0 ? $_[0]->netUnits         : 0 }
sub salesRevenue   { $_[0]->totalRevenue > 0 ? $_[0]->totalRevenue     : 0 }
sub returns        { $_[0]->netUnits     < 0 ? abs $_[0]->netUnits     : 0 }
sub returnsRevenue { $_[0]->totalRevenue < 0 ? abs $_[0]->totalRevenue : 0 }
sub _isValidSaleRecord {
    my $self = shift;

    my $typeDig = $self->_getByFieldName('_productTypeDig')  || '' ;
    return if $typeDig =~ /^payout$/i;

    return ( $self->_getByFieldName('trackName') || $self->_getByFieldName('albumName') )
           && defined $self->netUnits
}


1;