package RPS::Import::Bandcamp::v41;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use parent 'RPS::Import::ImporterMixed';

sub physical { 2 }

sub _fieldMapExtended {
    {
        mixed => {
            option1 => {
                labelName       => 'J',
                countryCode     => 'K',
                dateBegin       => 'V',
                dateEnd         => 'W',
                formatType      => 'E',
                clientProductID => 'A',
                artistName      => 'I',
                upc             => 'B',
                albumName       => 'G',
                isrc            => 'C',
                trackName       => 'F',
                units           => 'L',
                currencyCode    => 'M',
                sales           => 'N',
                totalRevenue    => 'T',
                price           => 'T',
            },
        },
    };
}

sub _unverifiedFieldMapExtended {
    {
        mixed => {
            option1 => {
                _productTypePhys => 'H',
                _productTypeDig  => 'E',
                _netUnits        => 'L',
            },
        }
    };
}

sub _headerIdentifierExtended {
    {
        mixed => {
            option1 => {
                upc => 'UPC',
            },
        },
    };
}

sub serviceID   { Client::Service::DSP_BANDCAMP }

sub countryCode {
    my $self = shift;

    my $name = $self->_getByFieldName('countryCode') || "";
    if ($name && $name =~ /^worldwide$/i)  {
        my $currencyCode = $self->_getByFieldName('currencyCode') || "";
        $name = "US" if $currencyCode eq "USD";
    }

    my $country = Common::Country->Get($name);
    return $country->alpha2() if $country;

    $self->fail( "Unable to determine country from: '$name'." );
}

sub saleDates {
    my $self = shift;

    # YYYY-MM-DD or MM/DD/YYYY or M/D/YY
    my $dateBegin = $self->_getByFieldName('dateBegin') || '';
    my $dateEnd = $self->_getByFieldName('dateEnd') || '';

    my ($year, $month, $day);
    if ( $dateBegin =~ /^(\d{4})[ -\/](\d{2})[ -\/](\d{2})$/ ) {
        ($year, $month, $day) = ($1, $2, $3);
    } elsif ( $dateBegin =~ /^(\d{1,2})\/(\d{1,2})\/(\d{2,4})/ ) {
        ($year, $month, $day) = ($3, $1, $2);
    } else {
        $self->fail( "Unable to determine date from: '$dateBegin'." );
    }

    $dateBegin = sprintf "%04d-%02d-%02d", length $year == 2 ? "20$year" : $year , $month, $day;

    if ( $dateEnd =~ /^(\d{4})[ -\/](\d{2})[ -\/](\d{2})$/ ) {
        ($year, $month, $day) = ($1, $2, $3);
    } elsif ( $dateEnd =~ /^(\d{1,2})\/(\d{1,2})\/(\d{2,4})/ ) {
        ($year, $month, $day) = ($3, $1, $2);
    } else {
        $self->fail( "Unable to determine date from: '$dateEnd'." );
    }

    $dateEnd = sprintf "%04d-%02d-%02d", length $year == 2 ? "20$year" : $year , $month, $day;
    return ($dateBegin, $dateEnd);
}

sub productType {
    my $self = shift;

    my $typeDig  = $self->_getByFieldName('_productTypeDig')  || '';
    my $typePhys = $self->_getByFieldName('_productTypePhys') || '';

    # order is important
    # digital
    if ( $typeDig =~ /^track$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    }
    elsif ( $typeDig =~ /^(?:album|bundle)$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    }

    # physical
    elsif ( $typePhys =~ /(?:Vinyl|Other)/i ) {
        return RPS::File::Sale::TYPE_LP;
    }
    elsif ( $typePhys =~ /^Cassette$/i ) {
        return RPS::File::Sale::TYPE_CASS;
    }
    elsif ( $typePhys =~ /^Compact Disc \(CD\)$/i ) {
        return RPS::File::Sale::TYPE_CD;
    }

    $self->fail( "Unable to determine product_type from: '$typePhys'." );
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';
    return RPS::File::Sale::FORMAT_DOWNLOAD if $type =~ /^(track|album|bundle)$/i;

    $self->fail( "Unable to determine format_type from: '$type'." );
}

sub upc {
    my $self = shift;

    my $upc = $self->_getByFieldName('upc') || '';
    $upc =~ s/\s//g;

    return $upc;
}

sub isrc {
    my $self = shift;

    my $isrc = $self->_getByFieldName('isrc') || '';
    $isrc =~ s/-//g;

    return $isrc;
}

sub trackName {
    my $self = shift;

    my $name = $self->_getByFieldName('trackName') || '';

    return $name if ($self->productType() eq RPS::File::Sale::TYPE_TRACK);
}

sub mediaType  { RPS::DB::Item::MediaType::kMediaTypeAudio }

# digital
sub price     { abs( shift->_getByFieldName('price') || 0 ) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;
    return $price < 0 ? abs($units) * -1 : $units;
}

# physical
sub channel        { RPS::File::Sale::CHANNEL_RETAIL }
sub priceLevel     { RPS::File::Sale::PLEVEL_UNKNOWN }
sub netUnits       { shift->_getByFieldName('_netUnits')    || 0 }
sub totalRevenue   { shift->_getByFieldName('totalRevenue') || 0 }
sub sales          { $_[0]->netUnits     > 0 ? $_[0]->netUnits         : 0 }
sub salesRevenue   { $_[0]->totalRevenue > 0 ? $_[0]->totalRevenue     : 0 }
sub returns        { $_[0]->netUnits     < 0 ? abs $_[0]->netUnits     : 0 }
sub returnsRevenue { $_[0]->totalRevenue < 0 ? abs $_[0]->totalRevenue : 0 }

sub _isValidSaleRecord {
    my $self = shift;

    return ( $self->_getByFieldName('trackName') || $self->_getByFieldName('albumName') )
           && ($self->netUnits || $self->totalRevenue);
}

1;