package RPS::Import::BelieveDigital::v14;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use RPS::DB::Item::SaleImportError;

use parent qw/RPS::Import::MapFaceBase RPS::Import::Importer/;


sub _fieldMap {
    {
        labelName       => 'F',
        serviceID       => 'C',
        countryCode     => 'D',
        dateBegin       => 'B',
        dateEnd         => 'B',
        productType     => 'I',
        formatType      => 'N',
        clientProductID => 'L',
        artistName      => 'G',
        upc             => 'J',
        albumName       => 'H',
        isrc            => 'K',
        trackName       => 'I',
        units           => 'Q',
        currencyCode    => 'R',
        price           => 'X',
        mediaType       => 'M',
    };
}

sub _headerIdentifier { isrc => 'ISRC' }

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    return Client::Service::DSP_ANGHAMI      if $service =~ /^Anghami/i;
    return Client::Service::DSP_UMA          if $service =~ /^UMA/i;
    return Client::Service::DSP_YOUTUBE      if $service =~ /^YouTube Music/i;
    return Client::Service::DSP_EBEATS       if $service =~ /^Ebeats/i;
    return Client::Service::DSP_KUWO_BEIJING if $service =~ /\bKuwo\b/i;
    return Client::Service::DSP_BEATPORT     if $service =~ /\bBeatport\b/i;
    return Client::Service::DSP_KUGOU        if $service =~ /\bKuGou\b/i;
    return Client::Service::DSP_QQ           if $service =~ /\bQQ\b/i;
    return Client::Service::DSP_TENCENT      if $service =~ /^Tencent/i;

    return $self->handleError( "Can't determine service: '$service'", RPS::DB::Item::SaleImportError::kErrorService );
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';
    if ( $type ) {
        return $self->isrc ? RPS::File::Sale::TYPE_TRACK : RPS::File::Sale::TYPE_ALBUM;
    }

    return $self->handleError( "Can't determine product type: $type", RPS::DB::Item::SaleImportError::kErrorProductType );
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';
    return RPS::File::Sale::FORMAT_DOWNLOAD if $type =~ /^Download$/i;
    return RPS::File::Sale::FORMAT_STREAM   if $type =~ /^Stream/i;

    return $self->handleError( "Can't determine format type: $type", RPS::DB::Item::SaleImportError::kErrorFormatType );
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType') || '';
    return RPS::DB::Item::MediaType::kMediaTypeAudio if $type =~ /^Music (?:compilation|release)$/i;
    return RPS::DB::Item::MediaType::kMediaTypeVideo if $type =~ /^(?:Entertainment|Music) Video$/i;

    return $self->handleError( "Can't determine media type: $type", RPS::DB::Item::SaleImportError::kErrorMediaType );
}

sub countryCode {
    my $self = shift;

    my $name = $self->_getByFieldName('countryCode') || '';
    if ( $name ) {
        my $oCountry = Common::Country->Get($name);
        return $oCountry->alpha2() if $oCountry;
    }

    $self->handleError( "Can't determine country code: '$name'.", RPS::DB::Item::SaleImportError::kErrorCountry );
    return $name;
}

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
        $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

# mapFace
sub _mapFaceServiceID   { 'serviceID' }
sub _mapFaceCountryCode { 'countryCode' }
sub _mapFaceProductType { 'productType' }
sub _mapFaceFormatType  { 'formatType' }
sub _mapFaceMediaType   { 'mediaType' }


1;