package RPS::Import::CINQ::v1;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use parent qw/RPS::Import::MapFaceBase RPS::Import::Importer/;

sub _headerIdentifier { isrc => 'Asset ID' }

sub _fieldMap {
    {
        labelName   => 'I',
        serviceID   => 'B',
        countryCode => 'G',
        productType => 'N',
        formatType  => 'H',
        artistName  => 'P',
        upc         => 'J',
        albumName   => 'L',
        isrc        => 'N',
        trackName   => 'Q',
        units       => 'R',
        price       => 'W',
        mediaType   => 'H',
    };
}

sub _unverifiedFieldMap {
    {
        _sourceYear  => 'C',
        _sourceMonth => 'D',
    }
}

sub currencyCode { 'USD' }

sub saleDates {
    my $self = shift;

    my $srcYear  = $self->_getByFieldName('_sourceYear')  || '';
    my $srcMonth = $self->_getByFieldName('_sourceMonth') || '';

    (my $year) = $srcYear =~ /^(\d{4})$/;
    (my $month) = $srcMonth =~ /^(\d{1,2})$/;
    if ( $year && $month ) {
        return $self->_getDates( date_begin => sprintf("%04d-%02d-%02d", $year, $month, 1) );
    }

    $self->fail("Unable to determine sale dates from: '$srcYear' and '$srcMonth'");
}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    return $self->handleError( "Unknown service: '$service'", RPS::DB::Item::SaleImportError::kErrorService );
}

sub countryCode {
    my $self = shift;

    my $country = $self->_getByFieldName('countryCode') || '';
    my $oCountry = Common::Country->Get($country) if $country;
    return $oCountry->alpha2 if $oCountry;

    $self->handleError( "Unknown country: '$country'.", RPS::DB::Item::SaleImportError::kErrorCountry );
    return $country;
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';
    return RPS::File::Sale::TYPE_TRACK if $type;

    $self->fail("Unable to determina product type from: '$type'");
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';
    if ( $type =~ /^(?:DCT|PMV|SAS|SAV|SSS|SSV|UGC|TDT|PSY)$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $type =~ /^(?:NDR|NSR|NTR)$/i ) {
        return RPS::File::Sale::FORMAT_PERFORMANCE;
    } elsif ( $type =~ /^(?:DAL|DTR)$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    } elsif ( $type =~ /^(?:DRT)$/i ) {
        return RPS::File::Sale::FORMAT_RINGTONE;
    }

    $self->fail("Unable to determine format type from: '$type'");
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType') || '';
    if ( $type =~ /^(?:DAL|DCT|DRT|DTR|NDR|NSR|NTR|SAS|SSS|UGC|TDT|PSY)$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    } elsif ( $type =~ /^(?:PMV|SAV|SSV)$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    }

    $self->fail("Unable to determine media type from: '$type'");
}

sub price {
    my $self = shift;

    my $price = $self->_getByFieldName('price') || 0;
    $price =~ s/,//g;

    return sprintf "%.8f", abs($price);
}

sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    $units = sprintf("%.0f", $units);

    my $price = $self->_getByFieldName('price') || 0;
    $price =~ s/,//g;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

# mapFace
sub _mapFaceServiceID   { 'serviceID' }
sub _mapFaceCountryCode { 'countryCode' }
sub _mapFaceProductType { }
sub _mapFaceFormatType  { }
sub _mapFaceMediaType   { }


1;