package RPS::Import::Caroline;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Util;
use Common::Consts;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

use constant DATE_COL  => 1;
use constant MONTH_ROW => 3;
use constant YEAR_ROW  => 4;

use constant FIELD_LABEL    => 0;
use constant FIELD_CATNO    => 1;
use constant FIELD_TITLE    => 2;
use constant FIELD_UPC      => 3;
use constant FIELD_SALES    => 4;
use constant FIELD_PSALES   => 5;
use constant FIELD_RETURNS  => 6;
use constant FIELD_PRETURNS => 7;
use constant FIELD_TOTAL    => 9;

#public methods

sub _importLines {
    my $self = shift;
    my %args = @_;

    my $retval  = undef;
    my $lines   = $args{lines};
    my $fileObj = $args{file};

    my ( $dateBegin, $dateEnd ) = $self->_getDates( $lines->[MONTH_ROW]->[DATE_COL], $lines->[YEAR_ROW]->[DATE_COL] );

    unless ( $dateBegin && $dateEnd ) {
        $self->errstr( "couldn't get dates from " . $lines->[MONTH_ROW]->[DATE_COL] . " , " . $lines->[YEAR_ROW]->[DATE_COL] );
        return undef;
    }

    my $linenum = 1;
    foreach my $line (@$lines) {
        my $prodtype    = RPS::File::Sale::TYPE_CD;
        my $price_level = RPS::File::Sale::PLEVEL_FULL;
        my $channel     = RPS::File::Sale::CHANNEL_RETAIL;
        my $label       = $line->[FIELD_LABEL];
        my $upc         = $line->[FIELD_UPC];
        my $catno       = $line->[FIELD_CATNO];

        my ( $album, $artist );
        if ( $line->[FIELD_TITLE] =~ m/^([^\/]+)\/(.+)$/ ) {
            $artist = $1;
            $album  = $2;
        } else {
            $album = $line->[FIELD_TITLE];
        }

        my ($sales)    = $line->[FIELD_SALES] =~ m/^(-?\d+)$/;
        my ($psales)   = $line->[FIELD_PSALES] =~ m/^(-?\d*\.?\d*)$/;
        my ($returns)  = $line->[FIELD_RETURNS] =~ m/^(-?\d+)$/;
        my ($preturns) = $line->[FIELD_PRETURNS] =~ m/^(-?\d*\.?\d*)$/;
        my ($total)    = $line->[FIELD_TOTAL] =~ m/^(-?\d*\.?\d*)$/;

        $returns  = $returns * -1;
        $preturns = $preturns * -1;

        if ( ( $sales || $returns ) && $album && defined $total ) {
            my $sale = RPS::Import::SaleRec->new();

            $sale->free(1) if ( $total == 0 && ( $sales != 0 || $returns != 0 ) );
            $sale->productType($prodtype);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->labelName($label);
            $sale->artistName($artist);
            $sale->albumName($album);
            $sale->upc($upc);
            $sale->clientProductID($catno);
            $sale->sales($sales);
            $sale->returns($returns);
            $sale->salesRevenue($psales);
            $sale->returnsRevenue($preturns);
            $sale->totalRevenue($total);
            $sale->priceLevel($price_level);
            $sale->channel($channel);
            $sale->countryCode('US');
            $sale->currencyCode('USD');
            $sale->lineNum($linenum);

            ##$args{dumper}($sale);  ## for cmd-line testing
            $self->_insertSale( sale => $sale );
        }
        $linenum++;
    }

    $fileObj->Physical(1);
    $fileObj->Save();

    return $linenum;
}

#
# Private methods
#

sub _getDates {
    my $self  = shift;
    my $month = shift;
    my $year  = shift;

    $month = Decode_Month($month);
    return undef unless ( $month && $year );

    my $dateBegin = sprintf( "%04d-%02d-%02d", $year, $month, 1 );
    my $dateEnd = sprintf( "%04d-%02d-%02d", $year, $month, Days_in_Month( $year, $month ) );

    return ( $dateBegin, $dateEnd );
}

###
1;    # Play nicely.
###