#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::ChristianBook::v1;

use strict;

use lib '/app/tools/common/lib';
use Common::Assert;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        upc       => 'C',
        albumName => 'B',
        isrc      => 'C',
        trackName => 'B',
        units     => 'E',
        price     => 'F',
    };
}

sub _headerIdentifier { ( albumName => 'Title' ) }

sub productType {
    my $self  = shift;
    my $value = $self->_getByFieldName('upc');

    # If all digits assume it's a upc == album
    if ( $value && $value =~ /^\d+$/ ) {
        return RPS::File::Sale::TYPE_ALBUM;

        # Otherwise assume it's an ISRC == track
    } else {
        return RPS::File::Sale::TYPE_TRACK;
    }
}

sub formatType { RPS::File::Sale::FORMAT_DOWNLOAD }
sub mediaType  { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub albumName {
    my $self  = shift;
    my $value = $self->_getByFieldName('albumName');

    return $self->upc ? $value : undef;
}

sub trackName {
    my $self  = shift;
    my $value = $self->_getByFieldName('trackName');

    return $self->isrc ? $value : undef;
}

sub isrc {
    my $self  = shift;
    my $value = $self->_getByFieldName('isrc');

    unless ( $value && $value =~ /^\d+$/ ) {
        return $value;
    }

    return;
}

sub upc {
    my $self  = shift;
    my $value = $self->_getByFieldName('upc');

    if ( $value && $value =~ /^\d+$/ ) {
        return $value;
    }

    return;
}

sub countryCode  { 'US' }
sub currencyCode { 'USD' }

sub saleDates {
    my $self = shift;

    assert( $self->filename, "Unknown filename" );

    unless ( $self->{_startDate} ) {
        die "Could not determine period from filename, " . $self->filename
          unless ( $self->filename() =~ /(\d{4})(\d{2})(\d{2})_(\d{4})(\d{2})(\d{2})/ );

        my $startDate = sprintf( "%04d-%02d-%02d", $1, $2, $3 );
        my $endDate   = sprintf( "%04d-%02d-%02d", $4, $5, $6 );

        ( $self->{_startDate}, $self->{_endDate} ) = $self->_getDates( date_begin => $startDate, date_end => $endDate );
    }

    return ( $self->{_startDate}, $self->{_endDate} );
}

###
1;    # Play nicely.
###