package RPS::Import::CoolSounds;

use strict;

use Date::Calc qw(Decode_Month Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Util;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use base 'RPS::Import::Importer';

use constant COUNTRY_CODE  => 'JP';
use constant CURRENCY_CODE => 'JPY';

use constant LINE_DATE  => 7;
use constant FIELD_DATE => 3;

use constant FIELD_SVC_PROD_ID => 2;
use constant FIELD_TRACK       => 3;
use constant FIELD_ARTIST      => 4;
use constant FIELD_CLI_PROD_ID => 5;
use constant FIELD_ALBUM       => 6;
use constant FIELD_UNITS       => 9;
use constant FIELD_PRICE       => 10;

sub _importLines {
    my $self  = shift;
    my %args  = @_;
    my $lines = $args{lines};

    return undef unless $lines;

    my ( $dateBegin, $dateEnd ) = _get_dates( $lines->[LINE_DATE][FIELD_DATE] );
    unless ( $dateBegin && $dateEnd ) {
        $self->errstr("can't get dates from '$lines->[LINE_DATE][FIELD_DATE]'");
        return undef;
    }
    print STDERR "using dates: $dateBegin $dateEnd\n";

    my $linenum = 1;
    foreach my $line (@$lines) {
        my $prodtype = RPS::File::Sale::TYPE_TRACK;
        my $format   = RPS::File::Sale::FORMAT_DOWNLOAD;
        my $country  = COUNTRY_CODE;
        my $currency = CURRENCY_CODE;

        my $svc_prod_id = $line->[FIELD_SVC_PROD_ID];
        my $cli_prod_id = $line->[FIELD_CLI_PROD_ID];
        my $artist      = $line->[FIELD_ARTIST];
        my $album       = $line->[FIELD_ALBUM];
        my $track       = $line->[FIELD_TRACK];
        my $units       = $line->[FIELD_UNITS];
        my $price       = $line->[FIELD_PRICE];

        if ( $artist && $track && $units > 0 && $price > 0 ) {
            $price /= $units;

            my $sale = RPS::Import::SaleRec->new();

            $sale->productType($prodtype);
            $sale->formatType($format);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->serviceProductID($svc_prod_id);
            $sale->clientProductID($cli_prod_id);
            $sale->artistName($artist);
            $sale->albumName($album);
            $sale->trackName($track);
            $sale->units($units);
            $sale->price($price);
            $sale->currencyCode($currency);
            $sale->countryCode($country);
            $sale->lineNum($linenum);

            #$args{dumper}($sale);
            $self->_insertSale( sale => $sale );
        }
        $linenum++;
    }
    return $linenum;
}

#
## Private methods
#

sub _get_dates {
    my $date_range = shift;
    return undef unless ( $date_range =~ /\d+\sto\s\w+/ );

    my ( $start_date, $end_date ) = split /\sto\s/, $date_range;

    $start_date =~ m/^(\w+)\s.+\s(\d{4})$/;
    my $start_year  = $2;
    my $start_month = Decode_Month($1);

    $end_date =~ m/^(\w+)\s.+\s(\d{4})$/;
    my $end_year  = $2;
    my $end_month = Decode_Month($1);

    return ( sprintf( "%04d-%02d-01", $start_year, $start_month ),
        sprintf( "%04d-%02d-%02d", $end_year, $end_month, Days_in_Month( $end_year, $end_month ) ) );
}

###
1;    # Play nicely.
###