#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2014 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::DDS::v1;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Assert;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

sub _fieldMap {
    my $self    = shift;
    my $version = $self->_version;

    # This importer supports two tabs, each with their own header mappings
    # The index here is the tab name.
    #
    my $sheetname = lc $self->{sheetname};

    my %field_map = (
        'itunes' => {
            labelName    => 'N',
            countryCode  => 'P',
            dateBegin    => 'A',
            dateEnd      => 'B',
            artistName   => 'L',
            upc          => 'C',
            albumName    => 'M',    # can be album _or_ track name
            currencyCode => 'I',
            isrc         => 'D',
            units        => 'F',
            price        => 'H',
            productType  => 'O',
        },
        'all other' => {
            labelName       => 'F',
            serviceID       => 'B',
            countryCode     => 'C',
            dateBegin       => 'A',
            dateEnd         => 'A',
            artistName      => 'G',
            upc             => 'D',
            albumName       => 'H',
            clientProductID => 'E',
            trackName       => 'I',
            trackNum        => 'L',
            isrc            => 'J',
            units           => 'M',
            price           => 'O',
            productType     => 'P',
        },
    );
    return $field_map{$sheetname};
}

sub _headerIdentifier { ( labelName => 'Label' ) }    # same for both tabs

sub saleDates {
    my $self      = shift;
    my $dateBegin = $self->_getByFieldName('dateBegin');
    my $dateEnd   = $self->_getByFieldName('dateEnd');

    if ( $dateBegin =~ /^(\d{4})M(\d{1,2})$/ ) {
        $dateBegin = sprintf( "%04d-%02d-%02d", $1, $2, 1 );
        return $self->_getDates( date_begin => $dateBegin );
    }

    return $self->_getDates( date_begin => $dateBegin, date_end => $dateEnd );
}

sub clientProductID {
    my $self = shift;
    return $self->_getByFieldName('clientProductID') if ( exists $self->_fieldMap->{'clientProductID'} );
}

sub trackNum {
    my $self = shift;
    return $self->_getByFieldName('trackNum') if ( exists $self->_fieldMap->{'trackNum'} );
}

sub currencyCode {
    my $self = shift;

    my $sheetname = lc $self->{sheetname};

    if ( $self->sheetname =~ /^itunes$/i ) {
        return $self->_getByFieldName('currencyCode');
    } elsif ( $self->sheetname =~ /^all other$/i ) {
        return 'USD';
    }
}

sub serviceID {
    my $self = shift;

    my $sheetname = lc $self->{sheetname};

    if ( $self->sheetname =~ /^itunes$/i ) {
        return Client::Service::DSP_ITUNES;
    } elsif ( $self->sheetname =~ /^all other$/i ) {
        my $service = $self->_getByFieldName('serviceID');
        $service =~ s/ \(Reporting Only\)//;
        my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };
        return $serviceID if ($serviceID);
        $self->fail("Unknown service '$service'");
    }
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType') || return;

    my $sheetname = lc $self->{sheetname};

    if ( $sheetname =~ /^itunes$/i ) {
        if ( $type =~ /^h$/i ) {
            return RPS::File::Sale::TYPE_TRACK;
        } elsif ( $type =~ /^i$/i ) {
            return RPS::File::Sale::TYPE_ALBUM;
        } else {
            $self->fail("Unable to determine product type from '$type'");
        }
    } elsif ( $sheetname =~ /^all other$/i ) {
        if ( $type =~ /^(as|dt|s|td|cl)$/i ) {
            return RPS::File::Sale::TYPE_TRACK;
        } elsif ( $type =~ /^(da|ta)$/i ) {
            return RPS::File::Sale::TYPE_ALBUM;
        } else {
            $self->fail("Unable to determine product type from '$type'");
        }
    }
}

sub formatType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');

    my $sheetname = lc $self->{sheetname};

    if ( $sheetname =~ /itunes/i ) {
        if ( $type =~ /^(h|i)$/i ) {
            return RPS::File::Sale::FORMAT_DOWNLOADPREMIUM;
        } else {
            $self->fail("Unable to determine format type from '$type'");
        }
    } elsif ( $sheetname =~ /^all other$/i ) {
        if ( $type =~ /^(as|s|cl)$/i ) {
            return RPS::File::Sale::FORMAT_STREAM;
        } elsif ( $type =~ /^(da|dt)$/i ) {
            return RPS::File::Sale::FORMAT_DOWNLOAD;
        } elsif ( $type =~ /^(td|ta)$/i ) {
            return RPS::File::Sale::FORMAT_TETHERED;
        } else {
            $self->fail("Unable to determine format type from '$type'");
        }
    }
}

sub mediaType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');

    my $sheetname = lc $self->{sheetname};

    if ( $sheetname =~ /itunes/i ) {
        if ( $type =~ /^(h|i)$/i ) {
            return RPS::DB::Item::MediaType::kMediaTypeAudio;
        } else {
            $self->fail("Unable to determine media type from '$type'");
        }
    } elsif ( $sheetname =~ /^all other$/i ) {
        if ( $type =~ /^(as|dt|s|td|cl|da|ta)$/i ) {
            return RPS::DB::Item::MediaType::kMediaTypeAudio;
        } else {
            $self->fail("Unable to determine product type from '$type'");
        }
    }
}

sub albumName {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');

    my $sheetname = lc $self->{sheetname};

    if ( $sheetname =~ /itunes/i ) {
        return $self->_getByFieldName('albumName') if ( $type =~ /^i$/i );
    } elsif ( $sheetname =~ /^all other$/i ) {
        return $self->_getByFieldName('albumName');
    }
}

sub trackName {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');

    my $sheetname = lc $self->{sheetname};

    if ( $sheetname =~ /itunes/i ) {
        return $self->_getByFieldName('albumName') if ( $type =~ /^h$/i );
    } elsif ( $sheetname =~ /^all other$/i ) {
        return $self->_getByFieldName('trackName') if ( $self->productType eq RPS::File::Sale::TYPE_TRACK );
    }
}

sub isrc {
    my $self = shift;
    return $self->_getByFieldName('isrc') if ( $self->productType eq RPS::File::Sale::TYPE_TRACK );
}

sub countryCode {
    my $self    = shift;
    my $country = $self->_getByFieldName('countryCode');
    my $obj     = Common::Country->Get($country);

    return $obj ? $obj->alpha2 : undef;
}

sub units {
    my $self  = shift;
    my $units = $self->SUPER::units();
    my $price = $self->SUPER::price();

    # The 'sign' of the units is driven by the price.
    # If the price is negative, we'll store negative units,
    # regardless of whether the units were positive or negative
    # in the sale file.  Accordingly, the price is always
    # positive.  This ensures that returns are recorded correctly.
    #
    if ( defined($price) ) {
        return $price < 0 ? abs($units) * -1 : $units;
    } else {
        return $units;
    }
}

sub unitPrice {
    return abs( shift->SUPER::unitPrice() );
}

###
1;    # Play nicely.
###