package RPS::Import::DDS::v3;

use strict;

use lib '/app/tools/common/lib';
use Common::Assert;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::DDS::v2';

sub _fieldMap {
    {
        labelName   => 'E',
        serviceID   => 'C',
        countryCode => 'D',
        dateBegin   => 'A',
        dateEnd     => 'B',
        productType => 'H',
        formatType  => 'P',
        artistName  => 'F',
        upc         => 'I',
        albumName   => 'G',
        isrc        => 'J',
        trackName   => 'H',
        units       => 'K',
        price       => 'M',
        mediaType   => 'P',
    }
}

sub _unverifiedFieldMap {
    {
        unitPrice => 'L',
    },
}

sub _headerIdentifier { ( labelName => 'Label' ) }
sub currencyCode { 'USD' }

sub serviceID {
    my $self    = shift;
    my $service = $self->_getByFieldName('serviceID');

    if ( $service =~ /^gaana/i ) {
        return Client::Service::DSP_GAANA;
    }

    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };

    return $serviceID if ($serviceID);

    $self->fail("Unknown service: $service");
}

sub productType {
    my $self      = shift;
    my $trackName = $self->_getByFieldName('trackName');
    my $upc       = $self->_getByFieldName('upc');
    my $isrc      = $self->_getByFieldName('isrc');

    if ( $trackName eq '' || lc($trackName) eq 'full album' ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } elsif ( $upc && !$isrc ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } else {
        return RPS::File::Sale::TYPE_TRACK;
    }
}

sub saleDates {
    my $self      = shift;
    my $dateBegin = $self->_getByFieldName('dateBegin') || "";
    my $dateEnd   = $self->_getByFieldName('dateEnd') || "";

    $dateBegin = Spreadsheet::ParseExcel::Utility::ExcelFmt( "yyyy-mm-dd", $dateBegin ) if ($dateBegin =~ /^\d{5}$/);
    $dateEnd = Spreadsheet::ParseExcel::Utility::ExcelFmt( "yyyy-mm-dd", $dateEnd ) if ($dateEnd =~ /^\d{5}$/);

    if ( $dateBegin =~ /^(\d{4})[\/\-](\d{1,2})[\/\-](\d{1,2})$/ ) {
        my $monthDateBegin = $2;
        $dateBegin = sprintf( "%04d-%02d-%02d", $1, $2, 1 );

        if ($dateEnd =~ /^(\d{4})[\/\-](\d{1,2})[\/\-](\d{1,2})$/){
            my $year = $1;
            my $prevMonth = $monthDateBegin != $2 ? $2 - 1 : $2;
            if ($prevMonth < 1){
                $prevMonth = 12;
                $year--;
            }
            $dateEnd = sprintf("%04d-%02d-%02d", $year, $prevMonth, Days_in_Month($year, $prevMonth));
        }
        return $self->_getDates( date_begin => $dateBegin, date_end => $dateEnd );
    }

    # if dateBegin is blank
    elsif ( ! $dateBegin ) {

        #use dateEnd for date
        # MM/DD/YYYY
        if ( $dateEnd =~ /^(\d{1,2})\/(\d{1,2})\/(\d{4})$/ ) {
            $dateEnd = sprintf( "%04d-%02d-%02d", $3, $1, 1 );
            return $self->_getDates( date_begin => $dateEnd );
        }
        # YYYY-MM-DD
        elsif ( $dateEnd =~ /^(\d{4})-(\d{1,2})-(\d{1,2})$/ ) {
            $dateEnd = sprintf( "%04d-%02d-%02d", $1, $2, 1 );
            return $self->_getDates( date_begin => $dateEnd );
        }

        # YYYY'M'MM, like 2015M11 for November 2015
        elsif ( $dateEnd =~ /^(\d{4})M(\d{1,2})$/ ) {
            $dateEnd = sprintf( "%04d-%02d-%02d", $1, $2, 1 );
            return $self->_getDates( date_begin => $dateEnd );
        }
        else {
            $self->fail("Could not find date in '$dateEnd'");
        }
    }
    else {
        $self->fail("Could not find date in '$dateBegin'");
    }
}

sub units {
    my $self = shift;
    my $units = $self->_getByFieldName('units');
    my $price = $self->_getByFieldName('price');
    return $units if ($price == 0);
    (($units < 0 && $price < 0) || ($units > 0 && $price > 0 )) ? return $units : return ($units * -1);
}

sub unitPrice {
    my $self = shift;

    my $unitPrice = $self->_getByFieldName('unitPrice') || 0;

    return abs($unitPrice);
}

sub formatType {
    my $self   = shift;
    my $format = $self->_getByFieldName('formatType');

    if (   $format =~ /^(as|s|cl|mt|sb|sv|nr|av|streaming radio|streaming|stream|radio|cloud|st)$/i
        || $format =~ /^apple radio$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $format =~ /^(da|dt|download)$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    } elsif ( $format =~ /^(td|ta)$/i ) {
        return RPS::File::Sale::FORMAT_TETHERED;
    } else {
        $self->fail("Unable to determine format type from '$format'");
    }
}

sub mediaType {
    my $self   = shift;
    my $format = $self->_getByFieldName('formatType');

    if (   $format =~ /^(?:as|dt|s|td|mt|cl|ta|sb|da|ta|nr|download|streaming radio|streaming|stream|radio|cloud|st)$/i
        || $format =~ /^apple radio$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }
    if ( $format =~ /^av|sv$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    } else {
        $self->fail("Unable to determine media type from '$format'");
    }
}

1;