package RPS::Import::DMX06;

use strict;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Util qw(normalize_date);

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use base 'RPS::Import::Importer';

# detail records
use constant FIELD_LABEL  => 1;
use constant FIELD_TRACK  => 2;
use constant FIELD_ARTIST => 3;
use constant FIELD_PRICE  => 4;

#
# Private methods
#

sub _importLines {
    my $self = shift;
    my %args = @_;

    my $lines    = $args{lines};
    my $fileObj  = $args{file};
    my $fileName = $fileObj->OrigFileName;

    #my $fileName = $args{OrigFileName}; ## for cmd-line testing

    return undef unless ($lines);

    my ( $dateBegin, $dateEnd ) = _getDates($fileName);
    unless ( $dateBegin && $dateEnd ) {
        $self->errstr("couldn't get dates from $fileName");
        return undef;
    }

    my $lineNum = 0;

    my ( $label, $artist, $track );

    foreach my $line (@$lines) {
        $label  = $line->[FIELD_LABEL]  unless ( $line->[FIELD_LABEL] eq "" );
        $artist = $line->[FIELD_ARTIST] unless ( $line->[FIELD_ARTIST] eq "" );
        $track  = $line->[FIELD_TRACK]  unless ( $line->[FIELD_TRACK] eq "" );
        my ($price) = $line->[FIELD_PRICE] =~ /^(\d+[\.]?\d*)/;

        last if ( $price > 20 );    ## otherwise can't identify grand total from indiv sales.

        if ( $price && $artist && $track ) {
            my $sale = RPS::Import::SaleRec->new();

            $sale->productType(RPS::File::Sale::TYPE_TRACK);
            $sale->formatType(RPS::File::Sale::FORMAT_BACKGROUNDMUSIC);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->labelName($artist);
            $sale->artistName($artist);
            $sale->trackName($track);
            $sale->units(1);
            $sale->price($price);
            $sale->lineNum($lineNum);

            $self->_insertSale( sale => $sale );

            #$args{dumper}($sale); ## for cmd-line testing
        }
        $lineNum++;
    }

    return $lineNum;
}

sub _getDates {
    my $date = shift || return undef;

    if ( $date =~ m/(\d\d) (20\d\d)/ ) {
        return ( sprintf( "%d-%02d-01", $2, $1 ), sprintf( "%d-%02d-%d", $2, $1, Days_in_Month( $2, $1 ) ), );
    }

    return undef;
}

###
1;    # Play nicely.
###